[gentoo-commits] gentoo-x86 commit in net-dns/libidn: ChangeLog libidn-1.22-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-dns/libidn: ChangeLog libidn-1.22-r1.ebuild

[Jeroen Roovers (jer)]

jer         11/10/18 20:24:00

  Modified:             ChangeLog
  Added:                libidn-1.22-r1.ebuild
  Log:
  Remove .la file when USE=-static-libs by Hans (bug #386929).
  
  (Portage version: 2.2.0_alpha69/cvs/Linux x86_64)

Revision  Changes    Path
1.146                net-dns/libidn/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/libidn/ChangeLog?rev=1.146&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/libidn/ChangeLog?rev=1.146&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/libidn/ChangeLog?r1=1.145&r2=1.146

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/libidn/ChangeLog,v
retrieving revision 1.145
retrieving revision 1.146
diff -u -r1.145 -r1.146
--- ChangeLog	1 Aug 2011 20:58:28 -0000	1.145
+++ ChangeLog	18 Oct 2011 20:24:00 -0000	1.146
@@ -1,6 +1,11 @@
 # ChangeLog for net-dns/libidn
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/libidn/ChangeLog,v 1.145 2011/08/01 20:58:28 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/libidn/ChangeLog,v 1.146 2011/10/18 20:24:00 jer Exp $
+
+*libidn-1.22-r1 (18 Oct 2011)
+
+  18 Oct 2011; Jeroen Roovers <jer@gentoo.org> +libidn-1.22-r1.ebuild:
+  Remove .la file when USE=-static-libs by Hans (bug #386929).
 
   01 Aug 2011; Jeroen Roovers <jer@gentoo.org> -libidn-1.19.ebuild,
   -libidn-1.20.ebuild, -libidn-1.21.ebuild:



1.1                  net-dns/libidn/libidn-1.22-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/libidn/libidn-1.22-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/libidn/libidn-1.22-r1.ebuild?rev=1.1&content-type=text/plain

Index: libidn-1.22-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/libidn/libidn-1.22-r1.ebuild,v 1.1 2011/10/18 20:24:00 jer Exp $

EAPI="4"

inherit autotools-utils java-pkg-opt-2 mono elisp-common

DESCRIPTION="Internationalized Domain Names (IDN) implementation"
HOMEPAGE="http://www.gnu.org/software/libidn/"
SRC_URI="mirror://gnu/libidn/${P}.tar.gz"

LICENSE="LGPL-2.1 GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="doc emacs java mono nls static-libs"

COMMON_DEPEND="emacs? ( virtual/emacs )
	mono? ( >=dev-lang/mono-0.95 )"
DEPEND="${COMMON_DEPEND}
	nls? ( >=sys-devel/gettext-0.17 )
	java? (
		>=virtual/jdk-1.4
		doc? ( dev-java/gjdoc )
	)"
RDEPEND="${COMMON_DEPEND}
	nls? ( virtual/libintl )
	java? ( >=virtual/jre-1.4 )"

SITEFILE=50${PN}-gentoo.el

src_prepare() {
	# bundled, with wrong bytecode
	rm "${S}/java/${P}.jar" || die
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable java) \
		$(use_enable mono csharp mono) \
		$(use_enable static-libs static) \
		--disable-valgrind-tests \
		--with-lispdir="${SITELISP}/${PN}" \
		--with-packager="Gentoo" \
		--with-packager-version="r${PR}" \
		--with-packager-bug-reports="https://bugs.gentoo.org"
}

src_compile() {
	default

	if use emacs; then
		elisp-compile src/*.el || die
	fi
}

src_install() {
	default
	dodoc AUTHORS ChangeLog FAQ NEWS README THANKS TODO

	if use emacs; then
		# *.el are installed by the build system
		elisp-install ${PN} src/*.elc || die
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	else
		rm -rf "${D}/usr/share/emacs"
	fi

	if use doc ; then
		dohtml -r doc/reference/html/*
	fi

	if use java ; then
		java-pkg_newjar java/${P}.jar ${PN}.jar || die
		rm -rf "${D}"/usr/share/java || die

		if use doc ; then
			java-pkg_dojavadoc doc/java
		fi
	fi
	use static-libs || remove_libtool_files
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}