[gentoo-commits] gentoo-x86 commit in sci-chemistry/aria: ChangeLog aria-2.3.2-r2.ebuild

[gentoo-commits] gentoo-x86 commit in sci-chemistry/aria: ChangeLog aria-2.3.2-r2.ebuild

[Justin Lecher (jlec)]

jlec        11/10/11 14:24:22

  Modified:             ChangeLog
  Added:                aria-2.3.2-r2.ebuild
  Log:
  Added fix for python import
  
  (Portage version: 2.2.0_alpha66/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 sci-chemistry/aria/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/aria/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/aria/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/aria/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/aria/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	7 Oct 2011 19:23:04 -0000	1.10
+++ ChangeLog	11 Oct 2011 14:24:22 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/aria
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/ChangeLog,v 1.10 2011/10/07 19:23:04 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/ChangeLog,v 1.11 2011/10/11 14:24:22 jlec Exp $
+
+*aria-2.3.2-r2 (11 Oct 2011)
+
+  11 Oct 2011; Justin Lecher <jlec@gentoo.org> +aria-2.3.2-r2.ebuild,
+  +files/aria-2.3.2-python.patch:
+  Added fix for python import
 
 *aria-2.3.2-r1 (07 Oct 2011)
 



1.1                  sci-chemistry/aria/aria-2.3.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/aria/aria-2.3.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/aria/aria-2.3.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: aria-2.3.2-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/aria-2.3.2-r2.ebuild,v 1.1 2011/10/11 14:24:22 jlec Exp $

EAPI=3

PYTHON_DEPEND="2"
PYTHON_USE_WITH="tk"

inherit base eutils python versionator

MY_P="${PN}$(get_version_component_range 1-2 ${PV})"

DESCRIPTION="Automated NOE assignment and NMR structure calculation"
HOMEPAGE="http://aria.pasteur.fr/"
SRC_URI="http://aria.pasteur.fr/archives/${MY_P}.2.tar.gz"

SLOT="0"
LICENSE="cns"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples"

RDEPEND="
	sci-chemistry/clashlist
	sci-chemistry/procheck
	sci-libs/clashscore-db
	dev-python/numpy
	dev-python/matplotlib[tk]
	>=sci-chemistry/cns-1.2.1-r7[aria,openmp]
	>=dev-lang/tk-8.3
	>=sci-chemistry/ccpn-2.0.5
	>=dev-tcltk/tix-8.1.4"
DEPEND="${RDEPEND}"

RESTRICT="fetch"

S="${WORKDIR}/${MY_P}"

pkg_nofetch(){
	einfo "Go to ${HOMEPAGE}, download ${A}"
	einfo "and place it in ${DISTDIR}"
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-python.patch \
		"${FILESDIR}"/${P}-through-space.patch
}

src_test(){
	export CCPNMR_TOP_DIR="${EPREFIX}"/$(python_get_sitedir)
	export PYTHONPATH=.:${CCPNMR_TOP_DIR}/ccpn/python
	$(PYTHON) check.py || die
}

src_install(){
	insinto "$(python_get_sitedir)/${PN}"
	doins -r src aria2.py || die "failed to install ${PN}"
	insinto "$(python_get_sitedir)/${PN}"/cns
	doins -r cns/{protocols,toppar,src/helplib} || die "failed to install cns part"

	if use examples; then
		insinto /usr/share/${P}/
		doins -r examples || die
	fi

	# ENV
	cat >> "${T}"/20aria <<- EOF
	ARIA2="${EPREFIX}/$(python_get_sitedir)/${PN}"
	EOF

	doenvd "${T}"/20aria

	# Launch Wrapper
	cat >> "${T}"/aria <<- EOF
	#!/bin/sh
	export CCPNMR_TOP_DIR="${EPREFIX}/$(python_get_sitedir)"
	export PYTHONPATH="${EPREFIX}/$(python_get_sitedir)/ccpn/python"
	exec "$(PYTHON)" -O "\${ARIA2}"/aria2.py \$@
	EOF

	dobin "${T}"/aria || die "failed to install wrapper"
	dosym aria /usr/bin/aria2

	dodoc README || die
}

pkg_postinst() {
	python_mod_optimize ${PN}
}

pkg_postrm() {
	python_mod_cleanup ${PN}
}