[gentoo-commits] gentoo-x86 commit in sys-cluster/drbd: ChangeLog drbd-8.3.11.ebuild drbd-8.3.9.ebuild

[gentoo-commits] gentoo-x86 commit in sys-cluster/drbd: ChangeLog drbd-8.3.11.ebuild drbd-8.3.9.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    11/10/10 08:42:32

  Modified:             ChangeLog
  Added:                drbd-8.3.11.ebuild
  Removed:              drbd-8.3.9.ebuild
  Log:
  Version bump wrt #379765, drop old unstable
  
  (Portage version: 2.1.10.22/cvs/Linux x86_64)

Revision  Changes    Path
1.112                sys-cluster/drbd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/drbd/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	10 Aug 2011 16:45:24 -0000	1.111
+++ ChangeLog	10 Oct 2011 08:42:32 -0000	1.112
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/drbd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/drbd/ChangeLog,v 1.111 2011/08/10 16:45:24 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/drbd/ChangeLog,v 1.112 2011/10/10 08:42:32 ultrabug Exp $
+
+*drbd-8.3.11 (10 Oct 2011)
+
+  10 Oct 2011; Ultrabug <ultrabug@gentoo.org> -drbd-8.3.9.ebuild,
+  +drbd-8.3.11.ebuild:
+  Version bump wrt #379765, drop old unstable
 
   10 Aug 2011; Markos Chandras <hwoarang@gentoo.org> drbd-8.3.10.ebuild:
   Stable on amd64 wrt bug #377419



1.1                  sys-cluster/drbd/drbd-8.3.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/drbd-8.3.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/drbd/drbd-8.3.11.ebuild?rev=1.1&content-type=text/plain

Index: drbd-8.3.11.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/drbd/drbd-8.3.11.ebuild,v 1.1 2011/10/10 08:42:32 ultrabug Exp $

EAPI="2"

inherit eutils multilib versionator

LICENSE="GPL-2"

DESCRIPTION="mirror/replicate block-devices across a network-connection"
SRC_URI="http://oss.linbit.com/drbd/$(get_version_component_range 1-2 ${PV})/${P}.tar.gz"
HOMEPAGE="http://www.drbd.org"

KEYWORDS="~amd64 ~x86"
IUSE="bash-completion heartbeat pacemaker +udev xen"
SLOT="0"

src_prepare() {
	# respect LDFLAGS
	sed -i -e "s/\$(CC) -o/\$(CC) \$(LDFLAGS) -o/" user/Makefile.in || die
	# respect multilib
	sed -i -e "s:/lib/:/$(get_libdir)/:g" \
		scripts/{Makefile.in,global_common.conf,drbd.conf.example} || die
	# correct install paths
	sed -i -e "s:\$(sysconfdir)/bash_completion.d:/usr/share/bash-completion:" \
		scripts/Makefile.in || die
	# don't participate in user survey bug 360483
	sed -i -e '/usage-count/ s/yes/no/' scripts/drbd.conf.example || die
}

src_configure() {
	econf \
		--localstatedir=/var \
		--with-utils \
		--without-km \
		--without-rgmanager \
		$(use_with udev) \
		$(use_with xen) \
		$(use_with pacemaker) \
		$(use_with heartbeat) \
		$(use_with bash-completion bashcompletion) \
		--with-distro=gentoo
}

src_compile() {
	# only compile the tools
	emake OPTFLAGS="${CFLAGS}" tools || die
}

src_install() {
	# only install the tools
	emake DESTDIR="${D}" install-tools || die
	dodoc README ChangeLog || die

	# install our own init script
	newinitd "${FILESDIR}"/${PN}-8.0.rc ${PN} || die

	dodoc scripts/drbd.conf.example || die
}

pkg_postinst() {
	einfo
	einfo "Please copy and gunzip the configuration file:"
	einfo "from /usr/share/doc/${PF}/${PN}.conf.example.bz2 to /etc/${PN}.conf"
	einfo "and edit it to your needs. Helpful commands:"
	einfo "man 5 drbd.conf"
	einfo "man 8 drbdsetup"
	einfo "man 8 drbdadm"
	einfo "man 8 drbddisk"
	einfo "man 8 drbdmeta"
	einfo

	elog "Remember to enable drbd support in kernel."
}