[gentoo-commits] gentoo-x86 commit in dev-lang/tk: metadata.xml ChangeLog tk-8.5.10.ebuild

[gentoo-commits] gentoo-x86 commit in dev-lang/tk: metadata.xml ChangeLog tk-8.5.10.ebuild

[Justin Lecher (jlec)]

jlec        11/10/04 17:08:05

  Modified:             metadata.xml ChangeLog
  Added:                tk-8.5.10.ebuild
  Log:
  Version Bump
  
  (Portage version: 2.2.0_alpha60/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  dev-lang/tk/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/tk/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	7 Aug 2004 06:59:08 -0000	1.1
+++ metadata.xml	4 Oct 2011 17:08:05 -0000	1.2
@@ -1,6 +1,5 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>tcltk</herd>
+	<herd>tcltk</herd>
 </pkgmetadata>
-



1.155                dev-lang/tk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/ChangeLog?rev=1.155&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/ChangeLog?rev=1.155&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/ChangeLog?r1=1.154&r2=1.155

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v
retrieving revision 1.154
retrieving revision 1.155
diff -u -r1.154 -r1.155
--- ChangeLog	23 Mar 2011 19:05:54 -0000	1.154
+++ ChangeLog	4 Oct 2011 17:08:05 -0000	1.155
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/tk
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.154 2011/03/23 19:05:54 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/ChangeLog,v 1.155 2011/10/04 17:08:05 jlec Exp $
+
+*tk-8.5.10 (04 Oct 2011)
+
+  04 Oct 2011; Justin Lecher <jlec@gentoo.org> +tk-8.5.10.ebuild, metadata.xml:
+  Version Bump
 
   23 Mar 2011; Kacper Kowalik <xarthisius@gentoo.org> tk-8.5.9-r1.ebuild:
   ppc64 stable wrt #353854



1.1                  dev-lang/tk/tk-8.5.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/tk-8.5.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/tk/tk-8.5.10.ebuild?rev=1.1&content-type=text/plain

Index: tk-8.5.10.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/tk/tk-8.5.10.ebuild,v 1.1 2011/10/04 17:08:05 jlec Exp $

EAPI="3"

inherit autotools eutils multilib toolchain-funcs prefix

MY_P="${PN}${PV/_beta/b}"

DESCRIPTION="Tk Widget Set"
HOMEPAGE="http://www.tcl.tk/"
SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug threads truetype aqua xscreensaver"

RDEPEND="
	!aqua? (
		x11-libs/libX11
		x11-libs/libXt
		truetype? ( x11-libs/libXft )
		xscreensaver? ( x11-libs/libXScrnSaver ) )
	~dev-lang/tcl-${PV}"
DEPEND="${RDEPEND}
	!aqua? ( x11-proto/xproto )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-8.4.11-multilib.patch

	epatch "${FILESDIR}"/${PN}-8.4.15-aqua.patch
	eprefixify unix/Makefile.in

	# Bug 125971
	epatch "${FILESDIR}"/${PN}-8.5_alpha6-tclm4-soname.patch

	sed -i 's/FT_New_Face/XftFontOpen/g' unix/configure.in || die

	cd "${S}"/unix
	eautoreconf
}

src_configure() {
	tc-export CC
	cd "${S}"/unix

	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}

	econf \
		--with-tcl="${EPREFIX}/usr/${mylibdir}" \
		$(use_enable threads) \
		$(use_enable aqua) \
		$(use_enable truetype xft) \
		$(use_enable xscreensaver xss) \
		$(use_enable debug symbols)
}

src_compile() {
	cd "${S}"/unix
	emake || die
}

src_install() {
	#short version number
	local v1
	v1=${PV%.*}

	cd "${S}"/unix
	S= emake DESTDIR="${D}" install || die

	# normalize $S path, bug #280766 (pkgcore)
	local nS="$(cd "${S}"; pwd)"

	# fix the tkConfig.sh to eliminate refs to the build directory
	local mylibdir=$(get_libdir) ; mylibdir=${mylibdir//\/}
	sed -i \
		-e "s,^\(TK_BUILD_LIB_SPEC='-L\)${nS}/unix,\1${EPREFIX}/usr/${mylibdir}," \
		-e "s,^\(TK_SRC_DIR='\)${nS}',\1${EPREFIX}/usr/${mylibdir}/tk${v1}/include'," \
		-e "s,^\(TK_BUILD_STUB_LIB_SPEC='-L\)${nS}/unix,\1${EPREFIX}/usr/${mylibdir}," \
		-e "s,^\(TK_BUILD_STUB_LIB_PATH='\)${nS}/unix,\1${EPREFIX}/usr/${mylibdir}," \
		"${ED}"/usr/${mylibdir}/tkConfig.sh || die

	if [[ ${CHOST} != *-darwin* ]]; then
		sed -i \
				-e "s,^\(TK_CC_SEARCH_FLAGS='.*\)',\1:${EPREFIX}/usr/${mylibdir}'," \
				-e "s,^\(TK_LD_SEARCH_FLAGS='.*\)',\1:${EPREFIX}/usr/${mylibdir}'," \
				"${ED}"/usr/${mylibdir}/tkConfig.sh || die
	fi

	# install private headers
	insinto /usr/${mylibdir}/tk${v1}/include/unix
	doins "${S}"/unix/*.h || die
	insinto /usr/${mylibdir}/tk${v1}/include/generic
	doins "${S}"/generic/*.h || die
	rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tk.h
	rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tkDecls.h
	rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/tkPlatDecls.h

	# install symlink for libraries
	#dosym libtk${v1}.a /usr/${mylibdir}/libtk.a
	dosym libtk${v1}$(get_libname) /usr/${mylibdir}/libtk$(get_libname) || die
	dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a || die

	dosym wish${v1} /usr/bin/wish || die

	cd "${S}"
	dodoc ChangeLog* README changes || die
}