[gentoo-commits] gentoo-x86 commit in dev-lang/path64: ChangeLog path64-1.0.0_pre20110924.ebuild path64-1.0.0_pre20110729.ebuild

["Kacper Kowalik (xarthisius)" <xarthisius@gentoo.org>]

xarthisius    11/09/24 10:04:21

  Modified:             ChangeLog
  Added:                path64-1.0.0_pre20110924.ebuild
  Removed:              path64-1.0.0_pre20110729.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  dev-lang/path64/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/path64/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/path64/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/path64/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/path64/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	29 Aug 2011 06:22:33 -0000	1.4
+++ ChangeLog	24 Sep 2011 10:04:20 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/path64
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/path64/ChangeLog,v 1.4 2011/08/29 06:22:33 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/path64/ChangeLog,v 1.5 2011/09/24 10:04:20 xarthisius Exp $
+
+*path64-1.0.0_pre20110924 (24 Sep 2011)
+
+  24 Sep 2011; Kacper Kowalik <xarthisius@gentoo.org>
+  -path64-1.0.0_pre20110729.ebuild, +path64-1.0.0_pre20110924.ebuild:
+  Version bump, drop old
 
   29 Aug 2011; Kacper Kowalik <xarthisius@gentoo.org>
   path64-1.0.0_pre20110729.ebuild, path64-1.0.0_pre20110821.ebuild:



1.1                  dev-lang/path64/path64-1.0.0_pre20110924.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/path64/path64-1.0.0_pre20110924.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/path64/path64-1.0.0_pre20110924.ebuild?rev=1.1&content-type=text/plain

Index: path64-1.0.0_pre20110924.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/path64/path64-1.0.0_pre20110924.ebuild,v 1.1 2011/09/24 10:04:20 xarthisius Exp $

EAPI=4
CMAKE_VERBOSE=1
MY_MIRROR=http://dev.gentoo.org/~xarthisius/distfiles

inherit cmake-utils multilib toolchain-funcs

DESCRIPTION="Path64 Compiler Suite Community Edition"
HOMEPAGE="http://www.pathscale.com/ekopath-compiler-suite"
SRC_URI="${MY_MIRROR}/${PN}-suite-${PV}.tbz2
	${MY_MIRROR}/${PN}-compiler-${PV}.tbz2
	assembler? ( ${MY_MIRROR}/${PN}-assembler-${PV}.tbz2 )
	debugger? ( ${MY_MIRROR}/${PN}-debugger-${PV}.tbz2 )"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="assembler custom-cflags debugger fortran +native +openmp valgrind"

DEPEND="!native? ( sys-devel/gcc[vanilla] )
	native? ( || ( dev-lang/ekopath dev-lang/path64 ) )
	valgrind? ( dev-util/valgrind )"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${PN}

pkg_setup() {
	if use custom-cflags ; then
		ewarn "You are trying to build ${PN} with custom-cflags"
		ewarn "There is a high chance that you will utterly fail!"
		ewarn "Unless you know what you are doing you'd better stop now"
		ewarn "Should you decide to proceed, you are on your own..."
	fi
}

src_prepare() {
	local ver=$(grep 'SET(PSC_FULL_VERSION' CMakeLists.txt | cut -d'"' -f2)
	cat > "98${PN}" <<-EOF
		PATH=/usr/$(get_libdir)/${PN}/bin
		ROOTPATH=/usr/$(get_libdir)/${PN}/bin
		LDPATH=/usr/$(get_libdir)/${PN}/lib:/usr/$(get_libdir)/${PN}/lib/${ver}/x8664/64
	EOF
	sed -i -e "s/-Wl,-s //" CMakeLists.txt || die #strip
}

src_configure() {
	local linker=$($(tc-getCC) --help -v 2>&1 >/dev/null | \
		sed -n -e '/dynamic-linker/s:.* -dynamic-linker \([^ ]\+\) .*:\1:p')
	local libgcc=$($(tc-getCC) -print-libgcc-file-name)
	use custom-cflags && flags=(
			-DCMAKE_C_FLAGS="${CFLAGS}"
			-DCMAKE_CXX_FLAGS="${CXXFLAGS}"
		)

	# Yup, I know how bad it is, but I'd rather have a working compiler
	unset FC F90 F77 FCFLAGS F90FLAGS FFLAGS CFLAGS CXXFLAGS

	if use native ; then
		export CMAKE_BUILD_TYPE=Release
		export CC=pathcc
		export CXX=pathCC
		export MYCMAKEARGS="-UCMAKE_USER_MAKE_RULES_OVERRIDE"
	else
		export CMAKE_BUILD_TYPE=Debug
	fi
	mycmakeargs=(
		-DCMAKE_INSTALL_PREFIX=/usr/$(get_libdir)/${PN}
		-DPATH64_ENABLE_TARGETS="x86_64"
		-DPATH64_ENABLE_PROFILING=ON
		-DPATH64_ENABLE_MATHLIBS=ON
		-DPATH64_ENABLE_PATHOPT2=OFF
		$(cmake-utils_use assembler PATH64_ENABLE_PATHAS)
		$(cmake-utils_use assembler PATH64_ENABLE_DEFAULT_PATHAS)
		$(cmake-utils_use fortran PATH64_ENABLE_FORTRAN)
		$(cmake-utils_use openmp PATH64_ENABLE_OPENMP)
		$(cmake-utils_use debugger PATH64_ENABLE_PATHDB)
		$(cmake-utils_use valgrind PATH64_ENABLE_VALGRIND)
		-DPSC_CRT_PATH_x86_64=/usr/$(get_libdir)
		-DPSC_CRTBEGIN_PATH=$(dirname ${libgcc})
		-DPSC_DYNAMIC_LINKER_x86_64=${linker}
		-DCMAKE_C_COMPILER="$(tc-getCC)"
		-DCMAKE_CXX_COMPILER="$(tc-getCXX)"
		"${flags[@]}"
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	doenvd "98${PN}"
}