* [gentoo-commits] gentoo-x86 commit in sys-devel/libtool: ChangeLog libtool-2.4-r2.ebuild libtool-9999.ebuild
@ 2011-09-23 4:17 Mike Frysinger (vapier)
0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2011-09-23 4:17 UTC (permalink / raw
To: gentoo-commits
vapier 11/09/23 04:17:36
Modified: ChangeLog libtool-9999.ebuild
Added: libtool-2.4-r2.ebuild
Log:
Unify live/release ebuilds again. Add patch from upstream for openmp when linking #349078 by Justin Lecher. Add USE=static-libs support #379047 by Agostino Sarubbo.
(Portage version: 2.2.0_alpha59/cvs/Linux x86_64)
Revision Changes Path
1.192 sys-devel/libtool/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?rev=1.192&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?rev=1.192&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?r1=1.191&r2=1.192
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v
retrieving revision 1.191
retrieving revision 1.192
diff -u -r1.191 -r1.192
--- ChangeLog 21 Sep 2011 08:35:59 -0000 1.191
+++ ChangeLog 23 Sep 2011 04:17:36 -0000 1.192
@@ -1,6 +1,14 @@
# ChangeLog for sys-devel/libtool
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v 1.191 2011/09/21 08:35:59 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v 1.192 2011/09/23 04:17:36 vapier Exp $
+
+*libtool-2.4-r2 (23 Sep 2011)
+
+ 23 Sep 2011; Mike Frysinger <vapier@gentoo.org> +libtool-2.4-r2.ebuild,
+ +files/libtool-2.4-openmp.patch, libtool-9999.ebuild:
+ Unify live/release ebuilds again. Add patch from upstream for openmp when
+ linking #349078 by Justin Lecher. Add USE=static-libs support #379047 by
+ Agostino Sarubbo.
21 Sep 2011; Michał Górny <mgorny@gentoo.org> libtool-9999.ebuild:
Migrate to git-2.
1.7 sys-devel/libtool/libtool-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild?r1=1.6&r2=1.7
Index: libtool-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- libtool-9999.ebuild 21 Sep 2011 08:35:59 -0000 1.6
+++ libtool-9999.ebuild 23 Sep 2011 04:17:36 -0000 1.7
@@ -1,33 +1,36 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild,v 1.6 2011/09/21 08:35:59 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-9999.ebuild,v 1.7 2011/09/23 04:17:36 vapier Exp $
-inherit eutils
+EAPI="2" #356089
+
+LIBTOOLIZE="true" #225559
+WANT_LIBTOOL="none"
+inherit eutils autotools multilib
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
http://git.savannah.gnu.org/r/${PN}.git"
-
inherit git-2
else
- SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+ SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
fi
DESCRIPTION="A shared library tool for developers"
HOMEPAGE="http://www.gnu.org/software/libtool/"
LICENSE="GPL-2"
-SLOT="1.5"
-KEYWORDS=""
-IUSE="vanilla"
+SLOT="2"
+IUSE="static-libs vanilla"
RDEPEND="sys-devel/gnuconfig
>=sys-devel/autoconf-2.65
>=sys-devel/automake-1.11.1"
DEPEND="${RDEPEND}
- sys-apps/help2man"
-
-S=${WORKDIR}/${ECVS_MODULE}
+ >=sys-devel/binutils-2.20
+ app-arch/xz-utils"
+[[ ${PV} == "9999" ]] && DEPEND+=" sys-apps/help2man"
src_unpack() {
if [[ ${PV} == "9999" ]] ; then
@@ -35,28 +38,47 @@
cd "${S}"
./bootstrap || die
else
- unpack ${A}
- cd "${S}"
+ xz -dc "${DISTDIR}"/${A} > ${P}.tar #356089
+ unpack ./${P}.tar
fi
+}
+src_prepare() {
use vanilla && return 0
epunt_cxx
cd libltdl/m4
epatch "${FILESDIR}"/1.5.20/${PN}-1.5.20-use-linux-version-in-fbsd.patch #109105
+ cd ..
+ AT_NOELIBTOOLIZE=yes eautoreconf
+ cd ..
+ AT_NOELIBTOOLIZE=yes eautoreconf
+}
+
+src_configure() {
+ # the libtool script uses bash code in it and at configure time, tries
+ # to find a bash shell. if /bin/sh is bash, it uses that. this can
+ # cause problems for people who switch /bin/sh on the fly to other
+ # shells, so just force libtool to use /bin/bash all the time.
+ export CONFIG_SHELL=/bin/bash
+
+ econf $(use_enable static-libs static)
}
src_install() {
emake DESTDIR="${D}" install || die
+ use static-libs || find "${D}" -name libltdl.la -delete
dodoc AUTHORS ChangeLog* NEWS README THANKS TODO doc/PLATFORMS
- local x
- for x in libtool libtoolize ; do
- help2man ${x} > ${x}.1
- doman ${x}.1 || die
- done
-
for x in $(find "${D}" -name config.guess -o -name config.sub) ; do
rm -f "${x}" ; ln -sf /usr/share/gnuconfig/${x##*/} "${x}"
done
}
+
+pkg_preinst() {
+ preserve_old_lib /usr/$(get_libdir)/libltdl.so.3
+}
+
+pkg_postinst() {
+ preserve_old_lib_notify /usr/$(get_libdir)/libltdl.so.3
+}
1.1 sys-devel/libtool/libtool-2.4-r2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-2.4-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-2.4-r2.ebuild?rev=1.1&content-type=text/plain
Index: libtool-2.4-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-2.4-r2.ebuild,v 1.1 2011/09/23 04:17:36 vapier Exp $
EAPI="2" #356089
LIBTOOLIZE="true" #225559
WANT_LIBTOOL="none"
inherit eutils autotools multilib
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
http://git.savannah.gnu.org/r/${PN}.git"
inherit git-2
else
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
fi
DESCRIPTION="A shared library tool for developers"
HOMEPAGE="http://www.gnu.org/software/libtool/"
LICENSE="GPL-2"
SLOT="2"
IUSE="static-libs vanilla"
RDEPEND="sys-devel/gnuconfig
!<sys-devel/autoconf-2.62:2.5
!<sys-devel/automake-1.11.1:1.11
!=sys-devel/libtool-2*:1.5"
DEPEND="${RDEPEND}
>=sys-devel/binutils-2.20
app-arch/xz-utils"
[[ ${PV} == "9999" ]] && DEPEND+=" sys-apps/help2man"
src_unpack() {
if [[ ${PV} == "9999" ]] ; then
git-2_src_unpack
cd "${S}"
./bootstrap || die
else
xz -dc "${DISTDIR}"/${A} > ${P}.tar #356089
unpack ./${P}.tar
fi
}
src_prepare() {
use vanilla && return 0
epatch "${FILESDIR}"/${P}-openmp.patch #349078
epunt_cxx
cd libltdl/m4
epatch "${FILESDIR}"/1.5.20/${PN}-1.5.20-use-linux-version-in-fbsd.patch #109105
cd ..
AT_NOELIBTOOLIZE=yes eautoreconf
cd ..
AT_NOELIBTOOLIZE=yes eautoreconf
}
src_configure() {
# the libtool script uses bash code in it and at configure time, tries
# to find a bash shell. if /bin/sh is bash, it uses that. this can
# cause problems for people who switch /bin/sh on the fly to other
# shells, so just force libtool to use /bin/bash all the time.
export CONFIG_SHELL=/bin/bash
econf $(use_enable static-libs static)
}
src_install() {
emake DESTDIR="${D}" install || die
use static-libs || find "${D}" -name libltdl.la -delete
dodoc AUTHORS ChangeLog* NEWS README THANKS TODO doc/PLATFORMS
for x in $(find "${D}" -name config.guess -o -name config.sub) ; do
rm -f "${x}" ; ln -sf /usr/share/gnuconfig/${x##*/} "${x}"
done
}
pkg_preinst() {
preserve_old_lib /usr/$(get_libdir)/libltdl.so.3
}
pkg_postinst() {
preserve_old_lib_notify /usr/$(get_libdir)/libltdl.so.3
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-09-23 4:17 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-09-23 4:17 [gentoo-commits] gentoo-x86 commit in sys-devel/libtool: ChangeLog libtool-2.4-r2.ebuild libtool-9999.ebuild Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox