* [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: metadata.xml ChangeLog lightdm-0.9.7.ebuild
@ 2011-09-17 13:47 Markos Chandras (hwoarang)
0 siblings, 0 replies; only message in thread
From: Markos Chandras (hwoarang) @ 2011-09-17 13:47 UTC (permalink / raw
To: gentoo-commits
hwoarang 11/09/17 13:47:00
Added: metadata.xml ChangeLog lightdm-0.9.7.ebuild
Log:
Re-introduce lightdm package. Bug #365311. Thanks to Christoph Junghans <ottxor@gentoo.org>
(Portage version: 2.2.0_alpha55/cvs/Linux x86_64)
Revision Changes Path
1.6 x11-misc/lightdm/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/metadata.xml?r1=1.5&r2=1.6
1.8 x11-misc/lightdm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?r1=1.7&r2=1.8
1.1 x11-misc/lightdm/lightdm-0.9.7.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-0.9.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-0.9.7.ebuild?rev=1.1&content-type=text/plain
Index: lightdm-0.9.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-0.9.7.ebuild,v 1.1 2011/09/17 13:47:00 hwoarang Exp $
EAPI=4
inherit autotools eutils pam
DESCRIPTION="A lightweight display manager"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz
gtk? ( http://dev.gentoo.org/~hwoarang/distfiles/${PN}-gentoo-patch.tar.gz )"
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="branding +gtk +introspection qt4"
RDEPEND="dev-libs/glib:2
virtual/pam
x11-libs/libxklavier
x11-libs/libX11
dev-libs/libxml2
gtk? ( x11-libs/gtk+:3
x11-themes/gnome-themes-standard
x11-themes/gnome-icon-theme )
qt4? ( x11-libs/qt-core:4
x11-libs/qt-dbus:4 )
sys-apps/accountsservice"
DEPEND="${RDEPEND}
dev-lang/vala:0.12
dev-util/intltool
dev-util/pkgconfig
sys-devel/gettext
introspection? ( dev-libs/gobject-introspection )"
REQUIRED_USE="branding? ( gtk )"
DOCS=( NEWS )
pkg_setup() {
if ! use gtk && ! use qt4; then
eerror
eerror "You have neither 'gtk' nor 'qt4' useflags enabled."
eerror "Please enable at least one of the two available greeter"
eerror "options"
die "Neither gtk nor qt4 useflag is enabled"
fi
}
src_prepare() {
# Make gtk greeter optional
epatch "${FILESDIR}/${P}-gtk.patch"
# remove GNOME_COMPILE_WARNING reference which requires
# gnome-base/gnome-common dependency.
sed -i -e "/GNOME_COMPILE_WARNING/d" "${S}"/configure.ac || die
# Hide users with uid < 1000
sed -i -e "/minimum-uid/s:500:1000:" "${S}"/data/users.conf || die
eautoreconf
}
src_configure() {
# Maybe in the future, we can support some automatic session and user
# recognition. Until then, use default values
local default=gnome greeter= user=root
# gtk has higher priority because Qt4 interface sucks :)
use qt4 && greeter=lightdm-qt-greeter
use gtk && greeter=lightdm-gtk-greeter
# Let user know how lightdm is configured
einfo "Gentoo configuration"
einfo "Default greeter: ${greeter}"
einfo "Default session: ${default}"
einfo "Greeter user: ${user}"
# do the actual configuration
econf --localstatedir=/var \
--disable-static \
$(use_enable introspection) \
$(use_enable qt4 liblightdm-qt) \
$(use_enable gtk liblightdm-gtk) \
--with-user-session=${default} \
--with-greeter-session=${greeter} \
--with-greeter-user=${user} \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}
src_install() {
default
# Install missing files
insinto /etc/${PN}/
doins "${S}"/data/{users,keys}.conf
# remove .la files
find "${ED}" -name "*.la" -exec rm -rf {} +
rm -Rf "${ED}"/etc/init || die
if use gtk; then
insinto /etc/${PN}/
doins "${WORKDIR}"/${PN}-gtk-greeter.conf
if use branding; then
insinto /usr/share/${PN}/backgrounds/
doins "${WORKDIR}"/gentoo1024x768.png
sed -i -e "/background/s:=.*:=/usr/share/${PN}/backgrounds/gentoo1024x768.png:" \
"${D}"/etc/${PN}/${PN}-gtk-greeter.conf || die
fi
fi
pamd_mimic system-local-login lightdm auth account session
}
pkg_postinst() {
elog
elog "Even though the default /etc/${PN}/${PN}.conf will work for"
elog "most users, make sure you configure it to suit your needs"
elog "before using ${PN} for the first time."
elog "You can test the configuration file using the following"
elog "command: ${PN} --test-mode -c /etc/${PN}/${PN}.conf. This"
elog "requires xorg-server to be built with the 'kdrive' useflag."
elog
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-09-17 13:47 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-09-17 13:47 [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: metadata.xml ChangeLog lightdm-0.9.7.ebuild Markos Chandras (hwoarang)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox