* [gentoo-commits] gentoo-x86 commit in app-misc/tracker: ChangeLog tracker-9999.ebuild tracker-0.8.17.ebuild tracker-0.10.26.ebuild tracker-0.10.27.ebuild tracker-0.10.24.ebuild
@ 2011-09-15 21:22 Gilles Dartiguelongue (eva)
0 siblings, 0 replies; only message in thread
From: Gilles Dartiguelongue (eva) @ 2011-09-15 21:22 UTC (permalink / raw
To: gentoo-commits
eva 11/09/15 21:22:20
Modified: ChangeLog tracker-9999.ebuild tracker-0.8.17.ebuild
tracker-0.10.26.ebuild
Added: tracker-0.10.27.ebuild
Removed: tracker-0.10.24.ebuild
Log:
Version bump. Pin dependency on libgee to slot 0.
(Portage version: 2.2.0_alpha58/cvs/Linux x86_64)
Revision Changes Path
1.114 app-misc/tracker/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?rev=1.114&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?rev=1.114&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?r1=1.113&r2=1.114
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v
retrieving revision 1.113
retrieving revision 1.114
diff -u -r1.113 -r1.114
--- ChangeLog 9 Sep 2011 21:52:56 -0000 1.113
+++ ChangeLog 15 Sep 2011 21:22:20 -0000 1.114
@@ -1,6 +1,13 @@
# ChangeLog for app-misc/tracker
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.113 2011/09/09 21:52:56 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.114 2011/09/15 21:22:20 eva Exp $
+
+*tracker-0.10.27 (15 Sep 2011)
+
+ 15 Sep 2011; Gilles Dartiguelongue <eva@gentoo.org> tracker-0.8.17.ebuild,
+ -tracker-0.10.24.ebuild, tracker-0.10.26.ebuild, +tracker-0.10.27.ebuild,
+ tracker-9999.ebuild:
+ Version bump. Pin dependency on libgee to slot 0.
09 Sep 2011; Gilles Dartiguelongue <eva@gentoo.org> tracker-0.10.26.ebuild:
Fix a typo in gstreamer backend selection.
1.45 app-misc/tracker/tracker-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?r1=1.44&r2=1.45
Index: tracker-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- tracker-9999.ebuild 8 Sep 2011 21:11:09 -0000 1.44
+++ tracker-9999.ebuild 15 Sep 2011 21:22:20 -0000 1.45
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.44 2011/09/08 21:11:09 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.45 2011/09/15 21:22:20 eva Exp $
EAPI="3"
GCONF_DEBUG="no"
@@ -53,7 +53,7 @@
upnp? ( >=media-libs/gupnp-dlna-0.5 ) )
!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
gtk? (
- >=dev-libs/libgee-0.3
+ >=dev-libs/libgee-0.3:0
>=x11-libs/gtk+-2.18:2 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
iptc? ( media-libs/libiptcdata )
1.14 app-misc/tracker/tracker-0.8.17.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.8.17.ebuild?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.8.17.ebuild?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.8.17.ebuild?r1=1.13&r2=1.14
Index: tracker-0.8.17.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.8.17.ebuild,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- tracker-0.8.17.ebuild 14 Apr 2011 12:28:44 -0000 1.13
+++ tracker-0.8.17.ebuild 15 Sep 2011 21:22:20 -0000 1.14
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.8.17.ebuild,v 1.13 2011/04/14 12:28:44 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.8.17.ebuild,v 1.14 2011/09/15 21:22:20 eva Exp $
EAPI="3"
GCONF_DEBUG="no"
@@ -46,7 +46,7 @@
gstreamer? ( >=media-libs/gstreamer-0.10.12 )
!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
gtk? (
- >=dev-libs/libgee-0.3
+ >=dev-libs/libgee-0.3:0
>=x11-libs/gtk+-2.18:2 )
iptc? ( media-libs/libiptcdata )
jpeg? ( virtual/jpeg:0 )
1.3 app-misc/tracker/tracker-0.10.26.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.10.26.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.10.26.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.10.26.ebuild?r1=1.2&r2=1.3
Index: tracker-0.10.26.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.26.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- tracker-0.10.26.ebuild 9 Sep 2011 21:52:56 -0000 1.2
+++ tracker-0.10.26.ebuild 15 Sep 2011 21:22:20 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.26.ebuild,v 1.2 2011/09/09 21:52:56 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.26.ebuild,v 1.3 2011/09/15 21:22:20 eva Exp $
EAPI="3"
GCONF_DEBUG="no"
@@ -55,7 +55,7 @@
upnp? ( >=media-libs/gupnp-dlna-0.5 ) )
!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
gtk? (
- >=dev-libs/libgee-0.3
+ >=dev-libs/libgee-0.3:0
>=x11-libs/gtk+-2.18:2 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
iptc? ( media-libs/libiptcdata )
1.1 app-misc/tracker/tracker-0.10.27.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.10.27.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.10.27.ebuild?rev=1.1&content-type=text/plain
Index: tracker-0.10.27.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.27.ebuild,v 1.1 2011/09/15 21:22:20 eva Exp $
EAPI="3"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
GNOME_TARBALL_SUFFIX="xz"
PYTHON_DEPEND="2:2.6"
inherit eutils gnome2 linux-info python virtualx
DESCRIPTION="A tagging metadata database, search tool and indexer"
HOMEPAGE="http://www.tracker-project.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# USE="doc" is managed by eclass.
IUSE="applet doc eds exif flac flickr gif gnome-keyring gsf gstreamer gtk +introspection iptc +jpeg laptop mp3 nautilus networkmanager pdf playlist qt4 rss strigi test +tiff upnp +vorbis xine +xml xmp"
# Test suite highly disfunctional, loops forever
# putting aside for now
RESTRICT="test"
# vala is built with debug by default (see VALAFLAGS)
RDEPEND="
>=app-i18n/enca-1.9
>=dev-db/sqlite-3.7[threadsafe]
>=dev-libs/dbus-glib-0.82-r1
>=dev-libs/glib-2.28:2
>=dev-libs/icu-4
|| (
>=media-gfx/imagemagick-5.2.1[png,jpeg=]
media-gfx/graphicsmagick[imagemagick,png,jpeg=] )
>=media-libs/libpng-1.2
>=x11-libs/pango-1
sys-apps/util-linux
applet? (
>=gnome-base/gnome-panel-2.91
>=x11-libs/gtk+-3:3 )
eds? (
>=mail-client/evolution-2.32
>=gnome-extra/evolution-data-server-2.32 )
exif? ( >=media-libs/libexif-0.6 )
flac? ( >=media-libs/flac-1.2.1 )
flickr? ( net-libs/rest:0.7 )
gif? ( media-libs/giflib )
gnome-keyring? ( >=gnome-base/gnome-keyring-2.26 )
gsf? (
app-text/odt2txt
>=gnome-extra/libgsf-1.13 )
gstreamer? (
>=media-libs/gstreamer-0.10.31:0.10
upnp? ( >=media-libs/gupnp-dlna-0.5 ) )
!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
gtk? (
>=dev-libs/libgee-0.3:0
>=x11-libs/gtk+-2.18:2 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
iptc? ( media-libs/libiptcdata )
jpeg? ( virtual/jpeg:0 )
laptop? ( >=sys-power/upower-0.9 )
mp3? (
>=media-libs/taglib-1.6
gtk? ( x11-libs/gdk-pixbuf:2 )
qt4? ( >=x11-libs/qt-gui-4.7.1:4 ) )
nautilus? (
>=gnome-base/nautilus-2
<gnome-base/nautilus-2.90
>=x11-libs/gtk+-2.18:2 )
networkmanager? ( >=net-misc/networkmanager-0.8 )
pdf? (
>=x11-libs/cairo-1
>=app-text/poppler-0.16[cairo,utils]
>=x11-libs/gtk+-2.12:2 )
playlist? ( dev-libs/totem-pl-parser )
rss? ( net-libs/libgrss )
strigi? ( >=app-misc/strigi-0.7 )
tiff? ( media-libs/tiff )
vorbis? ( >=media-libs/libvorbis-0.22 )
xine? ( >=media-libs/xine-lib-1 )
xml? ( >=dev-libs/libxml2-2.6 )
xmp? ( >=media-libs/exempi-2.1 )"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.40
>=sys-devel/gettext-0.17
>=dev-util/pkgconfig-0.20
applet? ( >=dev-lang/vala-0.12:0.12 )
gtk? (
app-office/dia
>=dev-lang/vala-0.12:0.12
>=dev-libs/libgee-0.3 )
doc? (
>=dev-util/gtk-doc-1.8
media-gfx/graphviz )
test? (
>=dev-libs/dbus-glib-0.82-r1
>=sys-apps/dbus-1.3.1[X] )
"
function inotify_enabled() {
if linux_config_exists; then
if ! linux_chkconfig_present INOTIFY_USER; then
ewarn "You should enable the INOTIFY support in your kernel."
ewarn "Check the 'Inotify support for userland' under the 'File systems'"
ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
die 'missing CONFIG_INOTIFY'
fi
else
einfo "Could not check for INOTIFY support in your kernel."
fi
}
pkg_setup() {
linux-info_pkg_setup
inotify_enabled
if use gstreamer ; then
G2CONF="${G2CONF} --enable-generic-media-extractor=gstreamer"
if use upnp; then
G2CONF="${G2CONF} --with-gstreamer-backend=gupnp-dlna"
else
G2CONF="${G2CONF} --with-gstreamer-backend=discoverer"
fi
elif use xine ; then
G2CONF="${G2CONF} --enable-generic-media-extractor=xine"
else
G2CONF="${G2CONF} --enable-generic-media-extractor=external"
fi
if use applet || use gtk; then
G2CONF="${G2CONF} VALAC=$(type -P valac-0.12)"
fi
if use mp3 && (use gtk || use qt4); then
G2CONF="${G2CONF} $(use_enable !qt4 gdkpixbuf) $(use_enable qt4 qt)"
fi
# unicode-support: libunistring, libicu or glib ?
G2CONF="${G2CONF}
--disable-hal
--enable-tracker-fts
--with-enca
--with-unicode-support=libicu
--enable-guarantee-metadata
$(use_enable applet tracker-search-bar)
$(use_enable eds miner-evolution)
$(use_enable exif libexif)
$(use_enable flac libflac)
$(use_enable flickr miner-flickr)
$(use_enable gnome-keyring)
$(use_enable gsf libgsf)
$(use_enable gtk tracker-explorer)
$(use_enable gtk tracker-preferences)
$(use_enable gtk tracker-needle)
$(use_enable introspection)
$(use_enable iptc libiptcdata)
$(use_enable jpeg libjpeg)
$(use_enable laptop upower)
$(use_enable mp3 taglib)
$(use_enable nautilus nautilus-extension)
$(use_enable networkmanager network-manager)
$(use_enable pdf poppler)
$(use_enable playlist)
$(use_enable rss miner-rss)
$(use_enable strigi libstreamanalyzer)
$(use_enable test functional-tests)
$(use_enable test unit-tests)
$(use_enable tiff libtiff)
$(use_enable vorbis libvorbis)
$(use_enable xml libxml2)
$(use_enable xmp exempi)"
DOCS="AUTHORS ChangeLog NEWS README"
python_set_active_version 2
}
src_prepare() {
# Fix build failures with USE=strigi
epatch "${FILESDIR}/${PN}-0.8.0-strigi.patch"
# Fix functional tests scripts
find "${S}" -name "*.pyc" -delete
python_convert_shebangs 2 "${S}"/tests/tracker-writeback/*.py
python_convert_shebangs 2 "${S}"/tests/functional-tests/*.py
python_convert_shebangs 2 "${S}"/utils/data-generators/cc/{*.py,generate}
python_convert_shebangs 2 "${S}"/utils/gtk-sparql/*.py
python_convert_shebangs 2 "${S}"/examples/rss-reader/*.py
# FIXME: report broken tests
sed -e '/\/libtracker-miner\/tracker-password-provider\/setting/,+1 s:^\(.*\)$:/*\1*/:' \
-e '/\/libtracker-miner\/tracker-password-provider\/getting/,+1 s:^\(.*\)$:/*\1*/:' \
-i tests/libtracker-miner/tracker-password-provider-test.c || die
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
Xemake check XDG_DATA_HOME="${T}" XDG_CONFIG_HOME="${T}" || die "tests failed"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-09-15 21:22 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-09-15 21:22 [gentoo-commits] gentoo-x86 commit in app-misc/tracker: ChangeLog tracker-9999.ebuild tracker-0.8.17.ebuild tracker-0.10.26.ebuild tracker-0.10.27.ebuild tracker-0.10.24.ebuild Gilles Dartiguelongue (eva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox