[gentoo-commits] gentoo-x86 commit in dev-util/gtk-doc-am: gtk-doc-am-1.18.ebuild ChangeLog

["Pacho Ramos (pacho)" <pacho@gentoo.org>]

pacho       11/09/15 09:34:48

  Modified:             ChangeLog
  Added:                gtk-doc-am-1.18.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.14/cvs/Linux x86_64)

Revision  Changes    Path
1.70                 dev-util/gtk-doc-am/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gtk-doc-am/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gtk-doc-am/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gtk-doc-am/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/gtk-doc-am/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog	10 Sep 2011 17:05:11 -0000	1.69
+++ ChangeLog	15 Sep 2011 09:34:48 -0000	1.70
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/gtk-doc-am
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc-am/ChangeLog,v 1.69 2011/09/10 17:05:11 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc-am/ChangeLog,v 1.70 2011/09/15 09:34:48 pacho Exp $
+
+*gtk-doc-am-1.18 (15 Sep 2011)
+
+  15 Sep 2011; Pacho Ramos <pacho@gentoo.org> +gtk-doc-am-1.18.ebuild:
+  Version bump.
 
   10 Sep 2011; Pacho Ramos <pacho@gentoo.org> -gtk-doc-am-1.15.ebuild,
   -gtk-doc-am-1.16.ebuild:



1.1                  dev-util/gtk-doc-am/gtk-doc-am-1.18.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gtk-doc-am/gtk-doc-am-1.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gtk-doc-am/gtk-doc-am-1.18.ebuild?rev=1.1&content-type=text/plain

Index: gtk-doc-am-1.18.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc-am/gtk-doc-am-1.18.ebuild,v 1.1 2011/09/15 09:34:48 pacho Exp $

EAPI="4"

inherit versionator

MY_PN="gtk-doc"
MY_P=${MY_PN}-${PV}
MAJ_PV=$(get_version_component_range 1-2)

DESCRIPTION="Automake files from gtk-doc"
HOMEPAGE="http://www.gtk.org/gtk-doc/"
SRC_URI="mirror://gnome/sources/${MY_PN}/${PV}/${MY_P}.tar.xz"

LICENSE="GPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE=""

RDEPEND=">=dev-lang/perl-5.6"
DEPEND="${RDEPEND}
	!<dev-util/gtk-doc-${MAJ_PV}"
# pkg-config is used by gtkdoc-rebase at runtime
# PDEPEND to avoid circular deps, bug 368301
PDEPEND="dev-util/pkgconfig"

# This ebuild doesn't even compile anything, causing tests to fail when updating (bug #316071)
RESTRICT="test"

S=${WORKDIR}/${MY_P}

DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README TODO"

src_configure() {
	# Duplicate autoconf checks so we don't have to call configure
	local PERL=$(type -P perl)

	test -n "${PERL}" || die "Perl not found!"
	"${PERL}" -e "require v5.6.0" || die "perl >= 5.6.0 is required for gtk-doc"

	# Replicate AC_SUBST
	sed -e "s:@PERL@:${PERL}:g" -e "s:@VERSION@:${PV}:g" \
		"${S}/gtkdoc-rebase.in" > "${S}/gtkdoc-rebase" || die "sed failed!"
}

src_compile() {
	:
}

src_install() {
	fperms +x gtkdoc-rebase
	exeinto /usr/bin/
	doexe gtkdoc-rebase

	insinto /usr/share/aclocal
	doins gtk-doc.m4
}