[gentoo-commits] gentoo-x86 commit in net-dns/unbound: unbound-1.4.12-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-dns/unbound: unbound-1.4.12-r1.ebuild ChangeLog

[Matsuu Takuto (matsuu)]

matsuu      11/09/13 15:14:49

  Modified:             ChangeLog
  Added:                unbound-1.4.12-r1.ebuild
  Log:
  Fixed python modules handling. The patch was submitted by Tom Hendrikx, bug #378395. Removed oknodo from unbound.initd, bug #379947.
  
  (Portage version: 2.1.10.15/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 net-dns/unbound/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	16 Jul 2011 03:52:59 -0000	1.28
+++ ChangeLog	13 Sep 2011 15:14:49 -0000	1.29
@@ -1,6 +1,13 @@
 # ChangeLog for net-dns/unbound
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.28 2011/07/16 03:52:59 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.29 2011/09/13 15:14:49 matsuu Exp $
+
+*unbound-1.4.12-r1 (13 Sep 2011)
+
+  13 Sep 2011; MATSUU Takuto <matsuu@gentoo.org> +unbound-1.4.12-r1.ebuild,
+  files/unbound.initd:
+  Fixed python modules handling. The patch was submitted by Tom Hendrikx, bug
+  #378395. Removed oknodo from unbound.initd, bug #379947.
 
   16 Jul 2011; MATSUU Takuto <matsuu@gentoo.org>
   +files/unbound-1.4.12-gentoo.patch:



1.1                  net-dns/unbound/unbound-1.4.12-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.4.12-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.4.12-r1.ebuild?rev=1.1&content-type=text/plain

Index: unbound-1.4.12-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/unbound-1.4.12-r1.ebuild,v 1.1 2011/09/13 15:14:49 matsuu Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit eutils flag-o-matic python

DESCRIPTION="A validating, recursive and caching DNS resolver"
HOMEPAGE="http://unbound.net/"
SRC_URI="http://unbound.net/downloads/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x64-macos"
IUSE="debug gost python static-libs test threads"

RDEPEND="dev-libs/expat
	dev-libs/libevent
	>=dev-libs/openssl-0.9.8
	>=net-libs/ldns-1.6.5[ssl,gost?]"

DEPEND="${RDEPEND}
	python? ( dev-lang/swig )
	test? (
		net-dns/ldns-utils[examples]
		dev-util/splint
		app-text/wdiff
	)"

# bug #347415
RDEPEND="${RDEPEND}
	net-dns/dnssec-root"

pkg_setup() {
	enewgroup unbound
	enewuser unbound -1 -1 /etc/unbound unbound

	use python && python_pkg_setup
}

src_prepare() {
	# To avoid below error messages, set 'trust-anchor-file' to same value in
	# 'auto-trust-anchor-file'.
	# [23109:0] error: Could not open autotrust file for writing, # /etc/dnssec/root-anchors.txt: Permission denied
	epatch "${FILESDIR}/${P}-gentoo.patch"
}

src_configure() {
	append-ldflags -Wl,-z,noexecstack || die
	econf \
		--with-pidfile="${EPREFIX}"/var/run/unbound.pid \
		--with-ldns="${EPREFIX}"/usr \
		--with-libevent="${EPREFIX}"/usr \
		--with-rootkey-file="${EPREFIX}"/etc/dnssec/root-anchors.txt \
		$(use_enable debug) \
		$(use_enable gost) \
		$(use_enable static-libs static) \
		$(use_with threads pthreads) \
		$(use_with python pyunbound) \
		$(use_with python pythonmodule) \
		--disable-rpath || die

		# http://unbound.nlnetlabs.nl/pipermail/unbound-users/2011-April/001801.html
		# $(use_enable debug lock-checks) \
		# $(use_enable debug alloc-checks) \
		# $(use_enable debug alloc-lite) \
		# $(use_enable debug alloc-nonregional) \
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# bug #299016
	if use python ; then
		find "${ED}" -name '_unbound.{la,a}' -delete || die
	fi
	if ! use static-libs ; then
		find "${ED}" -name "*.la" -type f -delete || die
	fi

	newinitd "${FILESDIR}/unbound.initd" unbound || die "newinitd failed"
	newconfd "${FILESDIR}/unbound.confd" unbound || die "newconfd failed"

	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES} || die "dodoc failed"

	# bug #315519
	#exeinto /usr/libexec/munin/plugins
	#doexe contrib/unbound_munin_ || die "doexe failed"
	dodoc contrib/unbound_munin_ || die "dodoc failed"

	docinto selinux
	dodoc contrib/selinux/* || die "dodoc failed"

	exeinto /usr/share/${PN}
	doexe contrib/update-anchor.sh || die "doexe failed"
}

pkg_postinst() {
	use python && python_mod_optimize unbound.py unboundmodule.py
}

pkg_postrm() {
	use python && python_mod_cleanup unbound.py unboundmodule.py
}