[gentoo-commits] gentoo-x86 commit in media-libs/libcanberra: ChangeLog libcanberra-0.28-r5.ebuild libcanberra-0.28-r4.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/libcanberra: ChangeLog libcanberra-0.28-r5.ebuild libcanberra-0.28-r4.ebuild

[Pacho Ramos (pacho)]

pacho       11/09/12 10:16:37

  Modified:             ChangeLog
  Added:                libcanberra-0.28-r5.ebuild
  Removed:              libcanberra-0.28-r4.ebuild
  Log:
  Apply fedora patch to workaround hangs when pulseaudio has problems, RDEPEND on gnome-base/gsettings-desktop-schemas to work ok with gnome-session-2.32.1-r3, remove all .la files (bug #366071 by Stephan Friedrichs, thanks a lot to Jonathan Callen for his explanation. Remove old.
  
  (Portage version: 2.1.10.14/cvs/Linux x86_64)

Revision  Changes    Path
1.72                 media-libs/libcanberra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	21 Jul 2011 17:26:29 -0000	1.71
+++ ChangeLog	12 Sep 2011 10:16:37 -0000	1.72
@@ -1,6 +1,15 @@
 # ChangeLog for media-libs/libcanberra
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.71 2011/07/21 17:26:29 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.72 2011/09/12 10:16:37 pacho Exp $
+
+*libcanberra-0.28-r5 (12 Sep 2011)
+
+  12 Sep 2011; Pacho Ramos <pacho@gentoo.org> -libcanberra-0.28-r4.ebuild,
+  +libcanberra-0.28-r5.ebuild, +files/libcanberra-0.28-workaround-hang.patch:
+  Apply fedora patch to workaround hangs when pulseaudio has problems, RDEPEND
+  on gnome-base/gsettings-desktop-schemas to work ok with
+  gnome-session-2.32.1-r3, remove all .la files (bug #366071 by Stephan
+  Friedrichs, thanks a lot to Jonathan Callen for his explanation. Remove old.
 
 *libcanberra-0.28-r4 (21 Jul 2011)
 *libcanberra-0.28-r3 (21 Jul 2011)



1.1                  media-libs/libcanberra/libcanberra-0.28-r5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/libcanberra-0.28-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/libcanberra-0.28-r5.ebuild?rev=1.1&content-type=text/plain

Index: libcanberra-0.28-r5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/libcanberra-0.28-r5.ebuild,v 1.1 2011/09/12 10:16:37 pacho Exp $

EAPI="4"

inherit gnome2-utils libtool systemd autotools eutils

DESCRIPTION="Portable Sound Event Library"
HOMEPAGE="http://0pointer.de/lennart/projects/libcanberra/"
SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="alsa gnome gstreamer +gtk +gtk3 oss pulseaudio +sound tdb udev"

COMMON_DEPEND="media-libs/libvorbis
	>=sys-devel/libtool-2.2.6b
	alsa? (
		media-libs/alsa-lib
		udev? ( >=sys-fs/udev-160 ) )
	gstreamer? ( >=media-libs/gstreamer-0.10.15 )
	gtk? ( >=x11-libs/gtk+-2.20.0:2
		gnome-base/gconf:2 )
	gtk3? ( x11-libs/gtk+:3
		gnome-base/gconf:2 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
	tdb? ( sys-libs/tdb )
"
RDEPEND="${COMMON_DEPEND}
	gnome? ( gnome-base/gsettings-desktop-schemas )
	sound? ( x11-themes/sound-theme-freedesktop )" # Required for index.theme wrt #323379
DEPEND="${COMMON_DEPEND}
	>=dev-util/pkgconfig-0.17"

REQUIRED_USE="udev? ( alsa )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-underlinking.patch

	# https://bugs.freedesktop.org/show_bug.cgi?id=35024
	epatch "${FILESDIR}/${PN}-0.28-workaround-hang.patch"

	# gconf-2.m4 is needed for autoconf, bug #374561
	if ! use gtk && ! use gtk3 ; then
		cp "${FILESDIR}/gconf-2.m4" m4/ || die "Copying gconf-2.m4 failed!"
	fi

	eautoreconf
	elibtoolize
}

src_configure() {
	econf \
		--docdir=/usr/share/doc/${PF} \
		--disable-dependency-tracking \
		$(use_enable alsa) \
		$(use_enable oss) \
		$(use_enable pulseaudio pulse) \
		$(use_enable gstreamer) \
		$(use_enable gtk) \
		$(use_enable gtk3) \
		$(use_enable tdb) \
		$(use_enable udev) \
		$(systemd_with_unitdir) \
		--disable-lynx \
		--disable-gtk-doc \
		--with-html-dir=/usr/share/doc/${PF}/html
}

src_install() {
	# Disable parallel installation until bug #253862 is solved
	emake -j1 DESTDIR="${D}" install

	# Remove useless .la files:
	# libcanberra uses lt_dlopenext instead of ld_dlopen to load the modules,
	# which means that it will first try appending ".la" to the given filename
	# prefix; if that fails, it will append the module extension for the
	# current system and try that (".so" on Linux, ".bundle" on Darwin, ".dll"
	# on Windows, etc.).  Only if both fail will it return an error.
	find "${D}" -name '*.la' -exec rm -f {} + || die "la file removal failed"
}

pkg_preinst() { gnome2_gconf_savelist; }
pkg_postinst() { gnome2_gconf_install; }