[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-session: gnome-session-2.32.1-r3.ebuild ChangeLog gnome-session-2.32.1.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-session: gnome-session-2.32.1-r3.ebuild ChangeLog gnome-session-2.32.1.ebuild

[Pacho Ramos (pacho)]

pacho       11/09/12 10:01:54

  Modified:             ChangeLog
  Added:                gnome-session-2.32.1-r3.ebuild
  Removed:              gnome-session-2.32.1.ebuild
  Log:
  Also support Gsettings conditions to work with latest libcanberra, fix race condition in idle monitor, fix dialog size, pull in x11-misc/xdg-user-dirs stuff as done in gnome-session-3. Remove old.
  
  (Portage version: 2.1.10.14/cvs/Linux x86_64)

Revision  Changes    Path
1.296                gnome-base/gnome-session/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-session/ChangeLog?rev=1.296&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-session/ChangeLog?rev=1.296&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-session/ChangeLog?r1=1.295&r2=1.296

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v
retrieving revision 1.295
retrieving revision 1.296
diff -u -r1.295 -r1.296
--- ChangeLog	19 Aug 2011 12:07:06 -0000	1.295
+++ ChangeLog	12 Sep 2011 10:01:54 -0000	1.296
@@ -1,6 +1,18 @@
 # ChangeLog for gnome-base/gnome-session
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v 1.295 2011/08/19 12:07:06 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v 1.296 2011/09/12 10:01:54 pacho Exp $
+
+*gnome-session-2.32.1-r3 (12 Sep 2011)
+
+  12 Sep 2011; Pacho Ramos <pacho@gentoo.org> -gnome-session-2.32.1.ebuild,
+  +gnome-session-2.32.1-r3.ebuild,
+  +files/gnome-session-2.32.1-dialog-size.patch,
+  +files/gnome-session-2.32.1-dialog-size2.patch,
+  +files/gnome-session-2.32.1-gsettings-conditions.patch,
+  +files/gnome-session-2.32.1-idle-transition.patch:
+  Also support Gsettings conditions to work with latest libcanberra, fix race
+  condition in idle monitor, fix dialog size, pull in x11-misc/xdg-user-dirs
+  stuff as done in gnome-session-3. Remove old.
 
   19 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
   gnome-session-3.0.2.ebuild:



1.1                  gnome-base/gnome-session/gnome-session-2.32.1-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-session/gnome-session-2.32.1-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-session/gnome-session-2.32.1-r3.ebuild?rev=1.1&content-type=text/plain

Index: gnome-session-2.32.1-r3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/gnome-session-2.32.1-r3.ebuild,v 1.1 2011/09/12 10:01:54 pacho Exp $

EAPI="4"
GCONF_DEBUG="yes"
GNOME_TARBALL_SUFFIX="bz2"

inherit autotools eutils gnome2

DESCRIPTION="Gnome session manager"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"

IUSE="doc ipv6 elibc_FreeBSD"

# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
# xdg-user-dirs-update is run during login (see 10-user-dirs-update below).
RDEPEND=">=dev-libs/glib-2.16:2
	>=x11-libs/gtk+-2.22.0:2
	>=dev-libs/dbus-glib-0.76
	>=gnome-base/gconf-2:2
	>=sys-power/upower-0.9.0
	elibc_FreeBSD? ( dev-libs/libexecinfo )

	x11-libs/libSM
	x11-libs/libICE
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXtst
	x11-apps/xdpyinfo

	x11-misc/xdg-user-dirs
	x11-misc/xdg-user-dirs-gtk"
DEPEND="${RDEPEND}
	>=dev-lang/perl-5
	>=sys-devel/gettext-0.10.40
	>=dev-util/pkgconfig-0.17
	>=dev-util/intltool-0.40
	gnome-base/gnome-common
	!<gnome-base/gdm-2.20.4
	doc? (
		app-text/xmlto
		dev-libs/libxslt )"
# gnome-common needed for eautoreconf
# gnome-base/gdm does not provide gnome.desktop anymore

pkg_setup() {
	# TODO: convert libnotify to a configure option
	G2CONF="${G2CONF}
		--docdir="${EPREFIX}/usr/share/doc/${PF}"
		--with-default-wm=gnome-wm
		--with-gtk=2.0
		$(use_enable doc docbook-docs)
		$(use_enable ipv6)"
	DOCS="AUTHORS ChangeLog NEWS README"
}

src_prepare() {
	gnome2_src_prepare

	# Add "session saving" button back, upstream bug #575544
	epatch "${FILESDIR}/${PN}-2.32.0-session-saving-button.patch"

	# Fix support for GNOME3 conditions, bug #XXXXXX
	epatch "${FILESDIR}/${PN}-2.32.1-gnome3-conditions.patch"

	# Also support Gsettings conditions to work with libcanberra
	epatch "${FILESDIR}/${PN}-2.32.1-gsettings-conditions.patch"

	# gsm: Fix race condition in idle monitor
	epatch "${FILESDIR}/${PN}-2.32.1-idle-transition.patch"

	# Fix dialog size
	epatch "${FILESDIR}/${PN}-2.32.1-dialog-size.patch"
	epatch "${FILESDIR}/${PN}-2.32.1-dialog-size2.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf
}

src_install() {
	gnome2_src_install

	dodir /etc/X11/Sessions
	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}/Gnome"

	dodir /usr/share/gnome/applications/
	insinto /usr/share/gnome/applications/
	doins "${FILESDIR}/defaults.list"

	dodir /etc/X11/xinit/xinitrc.d/
	exeinto /etc/X11/xinit/xinitrc.d/
	doexe "${FILESDIR}/15-xdg-data-gnome"

	# FIXME: this should be done by x11-misc/xdg-user-dirs
	doexe "${FILESDIR}/10-user-dirs-update"
}