* [gentoo-commits] gentoo-x86 commit in dev-vcs/veracity: veracity-1.0.0.10517.ebuild ChangeLog metadata.xml
@ 2011-09-12 5:08 Nathan Phillip Brink (binki)
0 siblings, 0 replies; only message in thread
From: Nathan Phillip Brink (binki) @ 2011-09-12 5:08 UTC (permalink / raw
To: gentoo-commits
binki 11/09/12 05:08:05
Added: veracity-1.0.0.10517.ebuild ChangeLog metadata.xml
Log:
Add dev-vcs/veracity-1.0.0.10517, a young DVCS (requested by jdhore).
(Portage version: 2.2.0_alpha50-r1/cvs/Linux x86_64)
Revision Changes Path
1.1 dev-vcs/veracity/veracity-1.0.0.10517.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/veracity/veracity-1.0.0.10517.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/veracity/veracity-1.0.0.10517.ebuild?rev=1.1&content-type=text/plain
Index: veracity-1.0.0.10517.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/veracity/veracity-1.0.0.10517.ebuild,v 1.1 2011/09/12 05:08:05 binki Exp $
EAPI=4
inherit eutils cmake-utils
JS_P=js-1.8.0-rc1
DESCRIPTION="A modern and featureful DVCS (distributed version control system)"
HOMEPAGE="http://veracity-scm.com/"
SRC_URI="http://download.sourcegear.com/Veracity/release/${PV}/${PN}-source-${PV}.tar.gz
ftp://ftp.mozilla.org/pub/mozilla.org/js/${JS_P}.tar.gz
http://ftp.mozilla.org/pub/mozilla.org/js/${JS_P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE="test"
S=${WORKDIR}/${PN}
# Tests fail in 1.0.0.10517.
RESTRICT=test
# Veracity can only use the API from spidermonkey-1.8.0 which isn't
# available in gentoo-x86. It seems that spidermonkey needs to be
# SLOTed... because Veracity needs differing amounts of nontrivial work
# to support spidermonkey-1.8.2 or any newer spidermonkey.
#
# || ( >=dev-lang/spidermonkey-1.8[threadsafe] >=dev-lang/spidermonkey-1.8.5 )
RDEPEND="
dev-libs/icu
net-misc/curl
dev-libs/nspr
sys-apps/util-linux
dev-db/sqlite:3
sys-libs/zlib"
DEPEND="${RDEPEND}
>=dev-util/pkgconfig-0.25
test? ( app-arch/unzip )"
src_prepare() {
epatch "${FILESDIR}"/${P}-werror.patch
epatch "${FILESDIR}"/${P}-system-sqlite.patch
epatch "${FILESDIR}"/${P}-spidermonkey-as-needed.patch
rm -rf src/thirdparty || die
pushd "${WORKDIR}"/js || die
(
EPATCH_OPTS+=" -p8"
epatch "${S}"/thirdparty/patches/js-1.8.0-rc1__{jsapi.c,jscntxt.{c,h}}.patch
)
}
src_configure() {
# Convince cmake scripts that spidermonkey has been prepared.
mkdir -p thirdparty/{include/spidermonkey,lib} || die
local mycmakeargs=(
-DVVTHIRDPARTY="${S}"/thirdparty
-DSPIDERMONKEY_INCDIR="${S}"/thirdparty/include
-DSPIDERMONKEY_LIB="${S}"/thirdparty/lib/libjs.a
)
cmake-utils_src_configure
}
src_compile() {
einfo "Compiling embedded spidermonkey (${JS_P})."
# Based on thirdparty/build_linux.sh.
emake -j1 \
-C "${WORKDIR}"/js/src \
JS_DIST=/usr \
JS_THREADSAFE=1 \
BUILD_OPT=1 \
-f Makefile.ref
cp "${WORKDIR}"/js/src/{*.{h,msg,tbl},Linux_All_OPT.OBJ/*.h} thirdparty/include/spidermonkey/ \
|| die "Preparing embedded spidermonkey."
cp "${WORKDIR}"/js/src/Linux_All_OPT.OBJ/libjs.a thirdparty/lib/ \
|| die "Preparing embedded spidermonkey."
einfo "Compiling ${P}."
cmake-utils_src_compile
}
1.1 dev-vcs/veracity/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/veracity/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/veracity/ChangeLog?rev=1.1&content-type=text/plain
Index: ChangeLog
===================================================================
# ChangeLog for dev-vcs/veracity
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/veracity/ChangeLog,v 1.1 2011/09/12 05:08:05 binki Exp $
*veracity-1.0.0.10517 (12 Sep 2011)
12 Sep 2011; Nathan Phillip Brink <binki@gentoo.org>
+veracity-1.0.0.10517.ebuild,
+files/veracity-1.0.0.10517-spidermonkey-as-needed.patch,
+files/veracity-1.0.0.10517-system-sqlite.patch,
+files/veracity-1.0.0.10517-werror.patch, +metadata.xml:
Add dev-vcs/veracity-1.0.0.10517, a young DVCS (requested by jdhore).
1.1 dev-vcs/veracity/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/veracity/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/veracity/metadata.xml?rev=1.1&content-type=text/plain
Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="utf-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
<email>binki@gentoo.org</email>
<name>Nathan Phillip Brink</name>
</maintainer>
</pkgmetadata>
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-09-12 5:08 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-09-12 5:08 [gentoo-commits] gentoo-x86 commit in dev-vcs/veracity: veracity-1.0.0.10517.ebuild ChangeLog metadata.xml Nathan Phillip Brink (binki)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox