[gentoo-commits] gentoo-x86 commit in net-news/liferea: ChangeLog liferea-1.7.6-r1.ebuild liferea-1.7.6.ebuild

[gentoo-commits] gentoo-x86 commit in net-news/liferea: ChangeLog liferea-1.7.6-r1.ebuild liferea-1.7.6.ebuild

[Victor Ostorga (vostorga)]

vostorga    11/09/11 13:36:08

  Modified:             ChangeLog
  Added:                liferea-1.7.6-r1.ebuild
  Removed:              liferea-1.7.6.ebuild
  Log:
  Reverting upstream commit 640eff3e418b786468208643d2f93718f7fa9da0 to avoid always unread feeds, bug #381117
  
  (Portage version: 2.1.10.3/cvs/Linux i686)

Revision  Changes    Path
1.211                net-news/liferea/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	9 Sep 2011 20:29:27 -0000	1.210
+++ ChangeLog	11 Sep 2011 13:36:08 -0000	1.211
@@ -1,6 +1,13 @@
 # ChangeLog for net-news/liferea
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.210 2011/09/09 20:29:27 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.211 2011/09/11 13:36:08 vostorga Exp $
+
+*liferea-1.7.6-r1 (11 Sep 2011)
+
+  11 Sep 2011; <vostorga@gentoo.org> -liferea-1.7.6.ebuild,
+  +liferea-1.7.6-r1.ebuild, +files/liferea-1.7.6-unread-feeds.patch:
+  Reverting upstream commit 640eff3e418b786468208643d2f93718f7fa9da0 to avoid
+  always unread feeds, bug #381117
 
   09 Sep 2011; Víctor Ostorga <vostorga@gentoo.org>
   files/liferea-1.6.6b-libnotify-0.7.patch:



1.1                  net-news/liferea/liferea-1.7.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/liferea-1.7.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/liferea-1.7.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: liferea-1.7.6-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.7.6-r1.ebuild,v 1.1 2011/09/11 13:36:08 vostorga Exp $

EAPI=4

GCONF_DEBUG=no

inherit eutils gnome2 pax-utils

MY_P=${P/_/-}

DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo/etc feeds"
HOMEPAGE="http://liferea.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="ayatana libnotify"

RDEPEND=">=x11-libs/gtk+-2.18.0:2
	>=dev-libs/glib-2.24.0:2
	>=x11-libs/pango-1.4.0
	>=gnome-base/gconf-1.1.9:2
	dev-libs/json-glib
	dev-libs/libunique:1
	>=dev-libs/libxml2-2.6.27:2
	>=dev-libs/libxslt-1.1.19
	>=dev-db/sqlite-3.6.10:3
	>=net-libs/libsoup-2.28.2:2.4
	>=net-libs/webkit-gtk-1.2.2:2
	ayatana? ( dev-libs/libindicate[gtk] )
	libnotify? ( >=x11-libs/libnotify-0.3.2 )"
DEPEND="${RDEPEND}
	dev-util/intltool
	dev-util/pkgconfig"

DOCS="AUTHORS ChangeLog README"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	G2CONF="${G2CONF}
		--enable-sm
		--disable-schemas-install
		$(use_enable ayatana libindicate)
		$(use_enable libnotify)"
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-unread-feeds.patch
	gnome2_src_prepare
}

src_install() {
	gnome2_src_install
	# bug #338213
	# Uses webkit's JIT. Needs mmap('rwx') to generate code in runtime.
	# MPROTECT policy violation. Will sit here until webkit will
	# get optional JIT.
	pax-mark m "${D}"/usr/bin/liferea

	einfo "If you want to enhance funcitonality of this package"
	einfo "You should consider installing these packages:"
	einfo "    dev-libs/dbus-glib"
	einfo "    net-misc/networkmanager"
}