[gentoo-commits] gentoo-x86 commit in dev-python/python-debian: python-debian-0.1.21.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/python-debian: python-debian-0.1.21.ebuild metadata.xml ChangeLog

[Mike Gilbert (floppym)]

floppym     11/09/08 01:12:31

  Added:                python-debian-0.1.21.ebuild metadata.xml ChangeLog
  Log:
  New package for bug 356129
  
  (Portage version: 2.2.0_alpha54/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-python/python-debian/python-debian-0.1.21.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-debian/python-debian-0.1.21.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-debian/python-debian-0.1.21.ebuild?rev=1.1&content-type=text/plain

Index: python-debian-0.1.21.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/python-debian/python-debian-0.1.21.ebuild,v 1.1 2011/09/08 01:12:31 floppym Exp $

EAPI="3"

PYTHON_DEPEND="2:2.5"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.4 3.*"

inherit distutils

DESCRIPTION="Python modules to work with Debian-related data formats"
HOMEPAGE="http://packages.debian.org/sid/python-debian"
SRC_URI="mirror://debian/pool/main/${P:0:1}/${PN}/${PN}_${PV}.tar.gz"

LICENSE="GPL-2 GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="examples"

RDEPEND="dev-python/chardet"
DEPEND="${RDEPEND}
	dev-python/setuptools"

PYTHON_MODNAME="deb822.py debian debian_bundle"

src_prepare() {
	sed -e "s/__CHANGELOG_VERSION__/${PV}/" setup.py.in > setup.py || die
	distutils_src_prepare
}

src_test() {
	testing() {
		local t
		for t in test_*.py ; do
			"$(PYTHON)" "${t}" || return
		done
	}
	cd tests || die
	python_execute_function testing
}

src_install() {
	distutils_src_install
	if use examples ; then
		insinto /usr/share/doc/${PF}
		doins -r examples || die
	fi
}



1.1                  dev-python/python-debian/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-debian/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-debian/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>python</herd>
	<maintainer>
		<email>floppym@gentoo.org</email>
		<name>Mike Gilbert</name>
	</maintainer>
</pkgmetadata>



1.1                  dev-python/python-debian/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-debian/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-debian/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-python/python-debian
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/python-debian/ChangeLog,v 1.1 2011/09/08 01:12:31 floppym Exp $

*python-debian-0.1.21 (08 Sep 2011)

  08 Sep 2011; Mike Gilbert <floppym@gentoo.org> +python-debian-0.1.21.ebuild,
  +metadata.xml:
  New package for bug 356129