* [gentoo-commits] gentoo-x86 commit in app-emulation/lxc: lxc-0.7.5.ebuild ChangeLog lxc-0.7.4.1-r1.ebuild
@ 2011-09-05 18:32 Diego Petteno (flameeyes)
0 siblings, 0 replies; only message in thread
From: Diego Petteno (flameeyes) @ 2011-09-05 18:32 UTC (permalink / raw
To: gentoo-commits
flameeyes 11/09/05 18:32:44
Modified: ChangeLog
Added: lxc-0.7.5.ebuild
Removed: lxc-0.7.4.1-r1.ebuild
Log:
Version bump; also includes fixes for the init script, closing bugs #379679 and #379683 by George Georgiev.
(Portage version: 2.2.0_alpha53/cvs/Linux x86_64)
Revision Changes Path
1.26 app-emulation/lxc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/lxc/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/lxc/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/lxc/ChangeLog?r1=1.25&r2=1.26
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/lxc/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog 26 Jul 2011 13:39:28 -0000 1.25
+++ ChangeLog 5 Sep 2011 18:32:44 -0000 1.26
@@ -1,6 +1,13 @@
# ChangeLog for app-emulation/lxc
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/lxc/ChangeLog,v 1.25 2011/07/26 13:39:28 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/lxc/ChangeLog,v 1.26 2011/09/05 18:32:44 flameeyes Exp $
+
+*lxc-0.7.5 (05 Sep 2011)
+
+ 05 Sep 2011; Diego E. Pettenò <flameeyes@gentoo.org> -lxc-0.7.4.1-r1.ebuild,
+ +lxc-0.7.5.ebuild, files/lxc.initd:
+ Version bump; also includes fixes for the init script, closing bugs #379679
+ and #379683 by George Georgiev.
*lxc-0.7.4.2 (26 Jul 2011)
1.1 app-emulation/lxc/lxc-0.7.5.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/lxc/lxc-0.7.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/lxc/lxc-0.7.5.ebuild?rev=1.1&content-type=text/plain
Index: lxc-0.7.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/lxc/lxc-0.7.5.ebuild,v 1.1 2011/09/05 18:32:44 flameeyes Exp $
EAPI="4"
MY_P="${P/_/-}"
inherit eutils linux-info versionator flag-o-matic
DESCRIPTION="LinuX Containers userspace utilities"
HOMEPAGE="http://lxc.sourceforge.net/"
SRC_URI="http://lxc.sourceforge.net/download/lxc/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
KEYWORDS="~amd64 ~ppc64 ~x86"
LICENSE="LGPL-3"
SLOT="0"
IUSE="examples vanilla"
RDEPEND="sys-libs/libcap"
DEPEND="${RDEPEND}
app-text/docbook-sgml-utils
>=sys-kernel/linux-headers-2.6.29"
# For init script, so protect with vanilla, they are not strictly
# needed.
RDEPEND="${RDEPEND}
vanilla? (
sys-apps/util-linux
app-misc/pax-utils
)"
CONFIG_CHECK="~CGROUPS
~CPUSETS ~CGROUP_CPUACCT
~RESOURCE_COUNTERS ~CGROUP_MEM_RES_CTLR
~CGROUP_SCHED
~NAMESPACES
~IPC_NS ~USER_NS ~PID_NS
~DEVPTS_MULTIPLE_INSTANCES
~CGROUP_FREEZER
~UTS_NS ~NET_NS
~VETH ~MACVLAN"
ERROR_DEVPTS_MULTIPLE_INSTANCES="CONFIG_DEVPTS_MULTIPLE_INSTANCES: needed for pts inside container"
ERROR_CGROUP_FREEZER="CONFIG_CGROUP_FREEZER: needed to freeze containers"
ERROR_UTS_NS="CONFIG_UTS_NS: needed to unshare hostnames and uname info"
ERROR_NET_NS="CONFIG_NET_NS: needed for unshared network"
ERROR_VETH="CONFIG_VETH: needed for internal (host-to-container) networking"
ERROR_MACVLAN="CONFIG_MACVLAN: needed for internal (inter-container) networking"
DOCS=(AUTHORS CONTRIBUTING MAINTAINERS NEWS TODO README doc/FAQ.txt)
src_configure() {
append-flags -fno-strict-aliasing
econf \
--localstatedir=/var \
--bindir=/usr/sbin \
--docdir=/usr/share/doc/${PF} \
--with-config-path=/etc/lxc \
--with-rootfs-path=/usr/lib/lxc/rootfs \
--with-linuxdir="${KERNEL_DIR}" \
--enable-doc \
$(use_enable examples)
}
src_install() {
default
rm -r "${D}"/usr/sbin/lxc-{setcap,ls} \
"${D}"/usr/share/man/man1/lxc-ls.1 \
|| die "unable to remove extraenous content"
keepdir /etc/lxc /usr/lib/lxc/rootfs
find "${D}" -name '*.la' -delete
use vanilla && return 0
# Gentoo-specific additions!
newinitd "${FILESDIR}/${PN}.initd" ${PN}
keepdir /var/log/lxc
}
pkg_postinst() {
if ! use vanilla; then
elog "There is an init script provided with the package now; no documentation"
elog "is currently available though, so please check out /etc/init.d/lxc ."
elog "You _should_ only need to symlink it to /etc/init.d/lxc.configname"
elog "to start the container defined into /etc/lxc/configname.conf ."
elog "For further information about LXC development see"
elog "http://blog.flameeyes.eu/tag/lxc" # remove once proper doc is available
elog ""
fi
ewarn "With version 0.7.4, the mountpoint syntax came back to the one used by 0.7.2"
ewarn "and previous versions. This means you'll have to use syntax like the following"
ewarn ""
ewarn " lxc.rootfs = /container"
ewarn " lxc.mount.entry = /usr/portage /container/usr/portage none bind 0 0"
ewarn ""
ewarn "To use the Fedora, Debian and (various) Ubuntu auto-configuration scripts, you"
ewarn "will need sys-apps/yum or dev-util/debootstrap."
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-09-05 18:32 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-09-05 18:32 [gentoo-commits] gentoo-x86 commit in app-emulation/lxc: lxc-0.7.5.ebuild ChangeLog lxc-0.7.4.1-r1.ebuild Diego Petteno (flameeyes)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox