[gentoo-commits] gentoo-x86 commit in dev-cpp/eigen: eigen-2.0.16.ebuild ChangeLog

["Andreas HAttel (dilfridge)" <dilfridge@gentoo.org>]

dilfridge    11/09/03 22:04:07

  Modified:             ChangeLog
  Added:                eigen-2.0.16.ebuild
  Log:
  Version bump with EAPI bump
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.48                 dev-cpp/eigen/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	20 Jul 2011 15:57:07 -0000	1.47
+++ ChangeLog	3 Sep 2011 22:04:07 -0000	1.48
@@ -1,6 +1,11 @@
 # ChangeLog for dev-cpp/eigen
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v 1.47 2011/07/20 15:57:07 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v 1.48 2011/09/03 22:04:07 dilfridge Exp $
+
+*eigen-2.0.16 (03 Sep 2011)
+
+  03 Sep 2011; Andreas K. Huettel <dilfridge@gentoo.org> +eigen-2.0.16.ebuild:
+  Version bump with EAPI bump
 
   20 Jul 2011; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Drop maintainer due retirement, bug #70723



1.1                  dev-cpp/eigen/eigen-2.0.16.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/eigen-2.0.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/eigen/eigen-2.0.16.ebuild?rev=1.1&content-type=text/plain

Index: eigen-2.0.16.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/eigen-2.0.16.ebuild,v 1.1 2011/09/03 22:04:07 dilfridge Exp $

EAPI=4

inherit cmake-utils

DESCRIPTION="C++ template library for linear algebra: vectors, matrices, and related algorithms"
HOMEPAGE="http://eigen.tuxfamily.org/"
SRC_URI="http://bitbucket.org/eigen/eigen/get/${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="GPL-3"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
SLOT="2"
IUSE="debug doc examples"

COMMON_DEPEND="
	examples? (
		x11-libs/qt-gui:4
		x11-libs/qt-opengl:4
	)
"
DEPEND="${COMMON_DEPEND}
	doc? ( app-doc/doxygen )
"
RDEPEND="${COMMON_DEPEND}
	!dev-cpp/eigen:0
"

S=${WORKDIR}/${PN}-${P}

src_configure() {
	# benchmarks (BTL) brings up damn load of external deps including fortran
	# compiler
	# library hangs up complete compilation proccess, test later
	mycmakeargs=(
		-DEIGEN_BUILD_LIB=OFF
		-DEIGEN_BUILD_BTL=OFF
		$(cmake-utils_use examples EIGEN_BUILD_DEMOS)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc; then
		cd "${CMAKE_BUILD_DIR}"
		emake doc
	fi
}

src_install() {
	cmake-utils_src_install
	if use doc; then
		cd "${CMAKE_BUILD_DIR}"/doc
		dohtml -r html/*
	fi
	if use examples; then
		cd "${CMAKE_BUILD_DIR}"/demos
		dobin mandelbrot/mandelbrot opengl/quaternion_demo
	fi
}

src_test() {
	mycmakeargs=(
		-DEIGEN_BUILD_TESTS=ON
		-DEIGEN_TEST_NO_FORTRAN=ON
	)
	cmake-utils_src_configure
	cmake-utils_src_compile
	cmake-utils_src_test
}