[gentoo-commits] gentoo-x86 commit in app-editors/nano: nano-2.3.1-r1.ebuild ChangeLog

["Fabian Groffen (grobian)" <grobian@gentoo.org>]

grobian     11/08/29 18:08:00

  Modified:             ChangeLog
  Added:                nano-2.3.1-r1.ebuild
  Log:
  Add fixes for Prefix, bug #361251
  
  (Portage version: 2.2.01.19074-prefix/cvs/Darwin i386)

Revision  Changes    Path
1.265                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?rev=1.265&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?rev=1.265&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?r1=1.264&r2=1.265

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.264
retrieving revision 1.265
diff -u -r1.264 -r1.265
--- ChangeLog	11 May 2011 15:04:28 -0000	1.264
+++ ChangeLog	29 Aug 2011 18:08:00 -0000	1.265
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.264 2011/05/11 15:04:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.265 2011/08/29 18:08:00 grobian Exp $
+
+*nano-2.3.1-r1 (29 Aug 2011)
+
+  29 Aug 2011; Fabian Groffen <grobian@gentoo.org> +nano-2.3.1-r1.ebuild:
+  Add fixes for Prefix, bug #361251
 
 *nano-2.3.1 (11 May 2011)
 



1.1                  app-editors/nano/nano-2.3.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/nano-2.3.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/nano-2.3.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.3.1-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.3.1-r1.ebuild,v 1.1 2011/08/29 18:08:00 grobian Exp $

EAPI="3"
inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
	inherit subversion
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug justify minimal ncurses nls slang spell unicode"

DEPEND=">=sys-libs/ncurses-5.2[unicode?]
	nls? ( sys-devel/gettext )
	!ncurses? ( slang? ( sys-libs/slang ) )"

src_prepare() {
	if [[ ! -e configure ]] ; then
		./autogen.sh || die
	fi
	# Prefix fix for odd ncursesw logic, bug #361251
	sed -i -e "s:-I\(/usr/include/ncursesw\):-I${EPREFIX}\1:" configure || die
}

src_configure() {
	local myconf=""
	use ncurses \
		&& myconf="--without-slang" \
		|| myconf="${myconf} $(use_with slang)"

	econf \
		--bindir="${EPREFIX}"/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml doc/faq.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano

	insinto /usr/share/nano
	local f
	for f in "${FILESDIR}"/*.nanorc ; do
		[[ -e ${ED}/usr/share/nano/${f##*/} ]] && continue
		doins "${f}" || die
		echo "# include \"${EPREFIX}/usr/share/nano/${f##*/}\"" >> "${ED}"/etc/nanorc
	done
}

pkg_postinst() {
	einfo "More helpful info about nano, visit the GDP page:"
	einfo "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}