* [gentoo-commits] gentoo-x86 commit in app-arch/zpaq/files: zpaq-3-autotools.patch zpaq-2-autotools.patch 0001-Add-autotools-files.patch
@ 2011-08-25 11:34 Michal Gorny (mgorny)
0 siblings, 0 replies; only message in thread
From: Michal Gorny (mgorny) @ 2011-08-25 11:34 UTC (permalink / raw
To: gentoo-commits
mgorny 11/08/25 11:34:16
Added: zpaq-3-autotools.patch zpaq-2-autotools.patch
Removed: 0001-Add-autotools-files.patch
Log:
Version bump. Add USE=debug. Adjust lib deps. Remove pointless lib check from generated autotools.
(Portage version: 2.2.0_alpha51_p9/cvs/Linux x86_64)
Revision Changes Path
1.1 app-arch/zpaq/files/zpaq-3-autotools.patch
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq/files/zpaq-3-autotools.patch?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq/files/zpaq-3-autotools.patch?rev=1.1&content-type=text/plain
Index: zpaq-3-autotools.patch
===================================================================
From cb14b21eb30e3c78eb475aabab97a89d3d428d91 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 4 Jan 2011 21:04:53 +0100
Subject: [PATCH] Add autotools files.
---
Makefile.am | 28 ++++++
configure.ac | 38 +++++++++
m4/ax_pthread.m4 | 246 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
3 files changed, 312 insertions(+), 0 deletions(-)
create mode 100644 Makefile.am
create mode 100644 configure.ac
create mode 100644 m4/ax_pthread.m4
diff --git a/Makefile.am b/Makefile.am
new file mode 100644
index 0000000..d005d5e
--- /dev/null
+++ b/Makefile.am
@@ -0,0 +1,28 @@
+bin_PROGRAMS = zpaq
+bin_SCRIPTS = zpaqopt
+lib_LIBRARIES = libzpaqstub.a
+
+ACLOCAL_AMFLAGS = -I m4
+
+if HAVE_POD2MAN
+man1_MANS = zpaq.1
+
+zpaq.1: zpaq.1.pod
+ $(POD2MAN) $< > $@
+endif
+
+libzpaqstub_a_SOURCES = zpaq.cpp
+libzpaqstub_a_CPPFLAGS = -DOPT
+
+zpaq_SOURCES = zpaq.cpp divsufsort.c divsufsort.h
+zpaq_CFLAGS = $(OPENMP_CXXFLAGS)
+zpaq_CXXFLAGS = $(OPENMP_CXXFLAGS) $(PTHREAD_CFLAGS)
+zpaq_LDADD = -lzpaq $(PTHREAD_LIBS)
+
+zpaqopt:
+ echo "$(CXX) $(CXXFLAGS) $$1.cpp $(LDFLAGS) @RUNTIME_LDFLAGS@ -o $$1.exe $(LIBS) -lzpaqstub" > $@
+
+.PHONY: zpaqopt
+
+MOSTLYCLEANFILES = zpaq.1 zpaqopt
+EXTRA_DIST = zpaq.1.pod
diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..b7ad2b7
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,38 @@
+AC_PREREQ([2.60])
+AC_INIT([zpaq], [na])
+AC_CONFIG_AUX_DIR([build-aux])
+AM_INIT_AUTOMAKE([1.6 foreign no-dependencies])
+
+AC_LANG([C++])
+AC_PROG_CC
+AC_PROG_CXX
+AC_PROG_RANLIB
+AC_OPENMP
+ACX_PTHREAD
+
+runtime_LDFLAGS='-Wl,--strip-all'
+AC_MSG_CHECKING([whether the linker supports $runtime_LDFLAGS])
+save_LDFLAGS=$LDFLAGS
+LDFLAGS="$LDFLAGS $runtime_LDFLAGS"
+AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM([], [])],
+ [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no])
+runtime_LDFLAGS=])
+LDFLAGS=$save_LDFLAGS
+AC_SUBST([RUNTIME_LDFLAGS], [$runtime_LDFLAGS])
+
+AC_CHECK_PROG([POD2MAN], [pod2man], [pod2man])
+AM_CONDITIONAL([HAVE_POD2MAN], [test x"$POD2MAN" != x""])
+AS_IF([test "x$POD2MAN" = x], [
+ AC_MSG_WARN([Unable to find pod2man, manpage will not be generated])
+])
+
+AC_ARG_ENABLE([debug],
+ [AS_HELP_STRING([--enable-debug],
+ [Enable debug])])
+AS_IF([test x"$enable_debug" != x"yes"], [
+ AC_DEFINE([NDEBUG], [1], [Set this to disable debug])
+])
+
+AC_CONFIG_FILES([Makefile])
+AC_OUTPUT
diff --git a/m4/ax_pthread.m4 b/m4/ax_pthread.m4
new file mode 100644
index 0000000..3d0806d
--- /dev/null
+++ b/m4/ax_pthread.m4
@@ -0,0 +1,246 @@
+# note: dropped PTHREAD_CC, joinable and stuff
+
+# ===========================================================================
+# http://www.gnu.org/software/autoconf-archive/ax_pthread.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+#
+# DESCRIPTION
+#
+# This macro figures out how to build C programs using POSIX threads. It
+# sets the PTHREAD_LIBS output variable to the threads library and linker
+# flags, and the PTHREAD_CFLAGS output variable to any special C compiler
+# flags that are needed. (The user can also force certain compiler
+# flags/libs to be tested by setting these environment variables.)
+#
+# Also sets PTHREAD_CC to any special C compiler that is needed for
+# multi-threaded programs (defaults to the value of CC otherwise). (This
+# is necessary on AIX to use the special cc_r compiler alias.)
+#
+# NOTE: You are assumed to not only compile your program with these flags,
+# but also link it with them as well. e.g. you should link with
+# $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
+#
+# If you are only building threads programs, you may wish to use these
+# variables in your default LIBS, CFLAGS, and CC:
+#
+# LIBS="$PTHREAD_LIBS $LIBS"
+# CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+# CC="$PTHREAD_CC"
+#
+# In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
+# has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to that name
+# (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
+#
+# Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
+# PTHREAD_PRIO_INHERIT symbol is defined when compiling with
+# PTHREAD_CFLAGS.
+#
+# ACTION-IF-FOUND is a list of shell commands to run if a threads library
+# is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
+# is not found. If ACTION-IF-FOUND is not specified, the default action
+# will define HAVE_PTHREAD.
+#
+# Please let the authors know if this macro fails on any platform, or if
+# you have any other suggestions or comments. This macro was based on work
+# by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
+# from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
+# Alejandro Forero Cuervo to the autoconf macro repository. We are also
+# grateful for the helpful feedback of numerous users.
+#
+# Updated for Autoconf 2.68 by Daniel Richard G.
+#
+# LICENSE
+#
+# Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
+# Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
+#
+# This program is free software: you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by the
+# Free Software Foundation, either version 3 of the License, or (at your
+# option) any later version.
+#
+# This program is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+# Public License for more details.
+#
+# You should have received a copy of the GNU General Public License along
+# with this program. If not, see <http://www.gnu.org/licenses/>.
+#
+# As a special exception, the respective Autoconf Macro's copyright owner
+# gives unlimited permission to copy, distribute and modify the configure
+# scripts that are the output of Autoconf when processing the Macro. You
+# need not follow the terms of the GNU General Public License when using
+# or distributing such scripts, even though portions of the text of the
+# Macro appear in them. The GNU General Public License (GPL) does govern
+# all other use of the material that constitutes the Autoconf Macro.
+#
+# This special exception to the GPL applies to versions of the Autoconf
+# Macro released by the Autoconf Archive. When you make and distribute a
+# modified version of the Autoconf Macro, you may extend this special
+# exception to the GPL to apply to your modified version as well.
+
+#serial 16
+
+AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
+AC_DEFUN([AX_PTHREAD], [
+AC_REQUIRE([AC_CANONICAL_HOST])
+AC_LANG_PUSH([C])
+ax_pthread_ok=no
+
+# We used to check for pthread.h first, but this fails if pthread.h
+# requires special compiler flags (e.g. on True64 or Sequent).
+# It gets checked for in the link test anyway.
+
+# First of all, check if the user has set any of the PTHREAD_LIBS,
+# etcetera environment variables, and if threads linking works using
+# them:
+if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
+ save_CFLAGS="$CFLAGS"
+ CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+ save_LIBS="$LIBS"
+ LIBS="$PTHREAD_LIBS $LIBS"
+ AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
+ AC_TRY_LINK_FUNC(pthread_join, ax_pthread_ok=yes)
+ AC_MSG_RESULT($ax_pthread_ok)
+ if test x"$ax_pthread_ok" = xno; then
+ PTHREAD_LIBS=""
+ PTHREAD_CFLAGS=""
+ fi
+ LIBS="$save_LIBS"
+ CFLAGS="$save_CFLAGS"
+fi
+
+# We must check for the threads library under a number of different
+# names; the ordering is very important because some systems
+# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
+# libraries is broken (non-POSIX).
+
+# Create a list of thread flags to try. Items starting with a "-" are
+# C compiler flags, and other items are library names, except for "none"
+# which indicates that we try without any flags at all, and "pthread-config"
+# which is a program returning the flags for the Pth emulation library.
+
+ax_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
+
+# The ordering *is* (sometimes) important. Some notes on the
+# individual items follow:
+
+# pthreads: AIX (must check this before -lpthread)
+# none: in case threads are in libc; should be tried before -Kthread and
+# other compiler flags to prevent continual compiler warnings
+# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
+# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
+# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
+# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
+# -pthreads: Solaris/gcc
+# -mthreads: Mingw32/gcc, Lynx/gcc
+# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
+# doesn't hurt to check since this sometimes defines pthreads too;
+# also defines -D_REENTRANT)
+# ... -mt is also the pthreads flag for HP/aCC
+# pthread: Linux, etcetera
+# --thread-safe: KAI C++
+# pthread-config: use pthread-config program (for GNU Pth library)
+
+case "${host_cpu}-${host_os}" in
+ *solaris*)
+
+ # On Solaris (at least, for some versions), libc contains stubbed
+ # (non-functional) versions of the pthreads routines, so link-based
+ # tests will erroneously succeed. (We need to link with -pthreads/-mt/
+ # -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
+ # a function called by this macro, so we could check for that, but
+ # who knows whether they'll stub that too in a future libc.) So,
+ # we'll just look for -pthreads and -lpthread first:
+
+ ax_pthread_flags="-pthreads pthread -mt -pthread $ax_pthread_flags"
+ ;;
+
+ *-darwin*)
+ ax_pthread_flags="-pthread $ax_pthread_flags"
+ ;;
+esac
+
+if test x"$ax_pthread_ok" = xno; then
+for flag in $ax_pthread_flags; do
+
+ case $flag in
+ none)
+ AC_MSG_CHECKING([whether pthreads work without any flags])
+ ;;
+
+ -*)
+ AC_MSG_CHECKING([whether pthreads work with $flag])
+ PTHREAD_CFLAGS="$flag"
+ ;;
+
+ pthread-config)
+ AC_CHECK_PROG(ax_pthread_config, pthread-config, yes, no)
+ if test x"$ax_pthread_config" = xno; then continue; fi
+ PTHREAD_CFLAGS="`pthread-config --cflags`"
+ PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
+ ;;
+
+ *)
+ AC_MSG_CHECKING([for the pthreads library -l$flag])
+ PTHREAD_LIBS="-l$flag"
+ ;;
+ esac
+
+ save_LIBS="$LIBS"
+ save_CFLAGS="$CFLAGS"
+ LIBS="$PTHREAD_LIBS $LIBS"
+ CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
+
+ # Check for various functions. We must include pthread.h,
+ # since some functions may be macros. (On the Sequent, we
+ # need a special flag -Kthread to make this header compile.)
+ # We check for pthread_join because it is in -lpthread on IRIX
+ # while pthread_create is in libc. We check for pthread_attr_init
+ # due to DEC craziness with -lpthreads. We check for
+ # pthread_cleanup_push because it is one of the few pthread
+ # functions on Solaris that doesn't have a non-functional libc stub.
+ # We try pthread_create on general principles.
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
+ static void routine(void *a) { a = 0; }
+ static void *start_routine(void *a) { return a; }],
+ [pthread_t th; pthread_attr_t attr;
+ pthread_create(&th, 0, start_routine, 0);
+ pthread_join(th, 0);
+ pthread_attr_init(&attr);
+ pthread_cleanup_push(routine, 0);
+ pthread_cleanup_pop(0) /* ; */])],
+ [ax_pthread_ok=yes],
+ [])
+
+ LIBS="$save_LIBS"
+ CFLAGS="$save_CFLAGS"
+
+ AC_MSG_RESULT($ax_pthread_ok)
+ if test "x$ax_pthread_ok" = xyes; then
+ break;
+ fi
+
+ PTHREAD_LIBS=""
+ PTHREAD_CFLAGS=""
+done
+fi
+
+AC_SUBST(PTHREAD_LIBS)
+AC_SUBST(PTHREAD_CFLAGS)
+
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
+if test x"$ax_pthread_ok" = xyes; then
+ ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
+ :
+else
+ ax_pthread_ok=no
+ $2
+fi
+AC_LANG_POP
+])dnl AX_PTHREAD
--
1.7.6.1
1.1 app-arch/zpaq/files/zpaq-2-autotools.patch
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq/files/zpaq-2-autotools.patch?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/zpaq/files/zpaq-2-autotools.patch?rev=1.1&content-type=text/plain
Index: zpaq-2-autotools.patch
===================================================================
From 0c5836166c1d856eb7f20b9cfc3b6f646b1bf587 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 4 Jan 2011 21:04:53 +0100
Subject: [PATCH] Add autotools files.
---
Makefile.am | 18 ++++++++++++++++++
configure.ac | 35 +++++++++++++++++++++++++++++++++++
2 files changed, 53 insertions(+), 0 deletions(-)
create mode 100644 Makefile.am
create mode 100644 configure.ac
diff --git a/Makefile.am b/Makefile.am
new file mode 100644
index 0000000..51275c3
--- /dev/null
+++ b/Makefile.am
@@ -0,0 +1,18 @@
+bin_PROGRAMS = zpaq
+lib_LIBRARIES = libzpaqstub.a
+
+if HAVE_POD2MAN
+man1_MANS = zpaq.1
+
+zpaq.1: zpaq.1.pod
+ $(POD2MAN) $< > $@
+endif
+
+libzpaqstub_a_SOURCES = zpaq.cpp
+
+zpaq_SOURCES = zpaq.cpp libzpaq.h
+zpaq_CPPFLAGS = $(AM_CPPFLAGS) -DOPT='"$(CXX) $(CXXFLAGS) zpaqopt.cpp $(LDFLAGS) @RUNTIME_LDFLAGS@ -o zpaqopt.exe $(LIBS) -lzpaqstub"'
+zpaq_LDADD = -lzpaq
+
+MOSTLYCLEANFILES = zpaq.1
+EXTRA_DIST = zpaq.1.pod
diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..24dddc6
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,35 @@
+AC_PREREQ([2.60])
+AC_INIT([zpaq], [na])
+AC_CONFIG_AUX_DIR([build-aux])
+AM_INIT_AUTOMAKE([1.6 foreign no-dependencies])
+
+AC_LANG([C++])
+AC_PROG_CXX
+AC_PROG_RANLIB
+
+runtime_LDFLAGS='-Wl,--strip-all'
+AC_MSG_CHECKING([whether the linker supports $runtime_LDFLAGS])
+save_LDFLAGS=$LDFLAGS
+LDFLAGS="$LDFLAGS $runtime_LDFLAGS"
+AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM([], [])],
+ [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no])
+runtime_LDFLAGS=])
+LDFLAGS=$save_LDFLAGS
+AC_SUBST([RUNTIME_LDFLAGS], [$runtime_LDFLAGS])
+
+AC_CHECK_PROG([POD2MAN], [pod2man], [pod2man])
+AM_CONDITIONAL([HAVE_POD2MAN], [test x"$POD2MAN" != x""])
+AS_IF([test "x$POD2MAN" = x], [
+ AC_MSG_WARN([Unable to find pod2man, manpage will not be generated])
+])
+
+AC_ARG_ENABLE([debug],
+ [AS_HELP_STRING([--enable-debug],
+ [Enable debug])])
+AS_IF([test x"$enable_debug" != x"yes"], [
+ AC_DEFINE([NDEBUG], [1], [Set this to disable debug])
+])
+
+AC_CONFIG_FILES([Makefile])
+AC_OUTPUT
--
1.7.6.1
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2011-08-25 11:34 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-08-25 11:34 [gentoo-commits] gentoo-x86 commit in app-arch/zpaq/files: zpaq-3-autotools.patch zpaq-2-autotools.patch 0001-Add-autotools-files.patch Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox