[gentoo-commits] gentoo-x86 commit in sys-auth/sssd: ChangeLog sssd-1.5.12-r1.ebuild sssd-1.5.12.ebuild

[gentoo-commits] gentoo-x86 commit in sys-auth/sssd: ChangeLog sssd-1.5.12-r1.ebuild sssd-1.5.12.ebuild

[Maxim Koltsov (maksbotan)]

maksbotan    11/08/20 13:00:20

  Modified:             ChangeLog
  Added:                sssd-1.5.12-r1.ebuild
  Removed:              sssd-1.5.12.ebuild
  Log:
  sys-auth/sssd revision bump
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  sys-auth/sssd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/sssd/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/sssd/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/sssd/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/sssd/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	14 Aug 2011 21:31:24 -0000	1.1
+++ ChangeLog	20 Aug 2011 13:00:20 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/sssd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/ChangeLog,v 1.1 2011/08/14 21:31:24 maksbotan Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/ChangeLog,v 1.2 2011/08/20 13:00:20 maksbotan Exp $
+
+*sssd-1.5.12-r1 (20 Aug 2011)
+
+  20 Aug 2011; Maxim Koltsov <maksbotan@gentoo.org> +sssd-1.5.12-r1.ebuild:
+  Revision bump: fixed LDB library path and .la files, thanks to slepnoga. Old
+  revision dropped cause it can't work due to wrong LDB search path.
 
 *sssd-1.5.12 (14 Aug 2011)
 



1.1                  sys-auth/sssd/sssd-1.5.12-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/sssd/sssd-1.5.12-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/sssd/sssd-1.5.12-r1.ebuild?rev=1.1&content-type=text/plain

Index: sssd-1.5.12-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/sssd-1.5.12-r1.ebuild,v 1.1 2011/08/20 13:00:20 maksbotan Exp $

EAPI=3

PYTHON_DEPEND="python? 2:2.6"
#RESTRICT="userpriv"

inherit python multilib pam linux-info autotools-utils

DESCRIPTION="System Security Services Daemon provides access to identity and authentication"
HOMEPAGE="http://fedorahosted.org/sssd/"
SRC_URI="http://fedorahosted.org/released/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc +locator logrotate nls openssl python selinux static-libs test"

COMMON_DEP="virtual/pam
	dev-libs/popt
	>=dev-libs/libunistring-0.9.3
	>=dev-libs/ding-libs-0.1.2
	>=sys-libs/talloc-2.0
	sys-libs/tdb
	sys-libs/tevent
	sys-libs/ldb
	>=net-nds/openldap-2.4.19
	dev-libs/libpcre
	>=app-crypt/mit-krb5-1.9.1
	>=net-dns/c-ares-1.7.4
	openssl? ( dev-libs/openssl )
	!openssl? ( >=dev-libs/nss-3.12.9 )
	selinux? ( >=sys-libs/libselinux-2.0.94 >=sys-libs/libsemanage-2.0.45 )
	net-dns/bind-tools
	dev-libs/cyrus-sasl
	sys-apps/dbus
	>=sys-devel/gettext-0.17
	virtual/libintl
	dev-libs/libnl"

RDEPEND="${COMMON_DEP}"
DEPEND="${COMMON_DEP}
	test? ( dev-libs/check )
	>=dev-libs/libxslt-1.1.26
	app-text/docbook-xml-dtd:4.4
	doc? ( app-doc/doxygen )"

CONFIG_CHECK="~KEYS"
AUTOTOOLS_IN_SOURCE_BUILD=1

pkg_setup(){
	python_set_active_version 2
	python_need_rebuild
	linux-info_pkg_setup
}

src_configure(){
	local myeconfargs=(
		--localstatedir="${EPREFIX}"/var
		--enable-nsslibdir="${EPREFIX}"/$(get_libdir)
		--enable-pammoddir="${EPREFIX}"/$(getpam_mod_dir)
		$(use_with selinux)
		$(use_with selinux semanage)
		--with-libnl
		--with-ldb-lib-dir="${EPREFIX}"/usr/$(get_libdir)/ldb/modules/
		$(use_with python python-bindings)
		--without-nscd
		$(use_enable locator krb5-locator-plugin)
		$(use_enable openssl crypto)
		$(use_enable nls ) )

	autotools-utils_src_configure
}

src_install(){
	autotools-utils_src_install

	rm "${ED}/$(get_libdir)/"libnss_sss.la || die
	rm "${ED}/usr/$(get_libdir)/ldb/modules/ldb/"*.la || die

	insinto /etc/sssd
	insopts -m600
	doins "${S}"/src/examples/sssd.conf

	if use logrotate; then
		insinto /etc/logrotate.d
		insopts -m644
		newins "${S}"/src/examples/logrotate sssd
	fi

	if use python; then
		python_clean_installation_image
		python_convert_shebangs 2 "${ED}$(python_get_sitedir)/"*.py
	fi
}

src_test() {
	autotools-utils_src_test
}

pkg_postinst(){
	elog "You must set up sssd.conf (default installed into /etc/sssd)"
	elog "and (optionally) configuration in /etc/pam.d in order to use SSSD"
	elog "features. Please see howto in	http://fedorahosted.org/sssd/wiki/HOWTO_Configure_1_0_2"

	use python && python_need_rebuild
	use python && python_mod_optimize SSSDConfig.py ipachangeconf.py
}

pkg_postrm() {
	use python && python_mod_cleanup SSSDConfig.py ipachangeconf.py
}