* [gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-color-manager: gnome-color-manager-3.0.0-r2.ebuild metadata.xml ChangeLog
@ 2011-08-19 11:09 Nirbheek Chauhan (nirbheek)
0 siblings, 0 replies; only message in thread
From: Nirbheek Chauhan (nirbheek) @ 2011-08-19 11:09 UTC (permalink / raw
To: gentoo-commits
nirbheek 11/08/19 11:09:04
Modified: metadata.xml ChangeLog
Added: gnome-color-manager-3.0.0-r2.ebuild
Log:
Bump to 3.0.0, from gnome overlay for GNOME 3
(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)
Revision Changes Path
1.2 gnome-extra/gnome-color-manager/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/metadata.xml?r1=1.1&r2=1.2
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-color-manager/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml 19 Nov 2010 13:26:03 -0000 1.1
+++ metadata.xml 19 Aug 2011 11:09:04 -0000 1.2
@@ -1,9 +1,15 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
- <maintainer>
- <email>flameeyes@gentoo.org</email>
- <name>Diego Elio Pettenò</name>
- </maintainer>
- <herd>gnome</herd>
+ <maintainer>
+ <email>flameeyes@gentoo.org</email>
+ <name>Diego Elio Pettenò</name>
+ </maintainer>
+ <herd>gnome</herd>
+ <use>
+ <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
+ for introspection</flag>
+ <flag name="packagekit">Enable support for the distro-neutral package
+ manager GUI <pkg>app-admin/packagekit</pkg></flag>
+ </use>
</pkgmetadata>
1.8 gnome-extra/gnome-color-manager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/ChangeLog?r1=1.7&r2=1.8
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-color-manager/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog 7 Jun 2011 07:07:51 -0000 1.7
+++ ChangeLog 19 Aug 2011 11:09:04 -0000 1.8
@@ -1,6 +1,14 @@
# ChangeLog for gnome-extra/gnome-color-manager
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-color-manager/ChangeLog,v 1.7 2011/06/07 07:07:51 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-color-manager/ChangeLog,v 1.8 2011/08/19 11:09:04 nirbheek Exp $
+
+*gnome-color-manager-3.0.0-r2 (19 Aug 2011)
+
+ 19 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+ +gnome-color-manager-3.0.0-r2.ebuild,
+ +files/gnome-color-manager-3.0.0-cc-panel.patch,
+ +files/gnome-color-manager-3.0.0-packagename.patch, metadata.xml:
+ Bump to 3.0.0, from gnome overlay for GNOME 3
07 Jun 2011; Diego E. Pettenò <flameeyes@gentoo.org>
gnome-color-manager-2.32.0.ebuild:
1.1 gnome-extra/gnome-color-manager/gnome-color-manager-3.0.0-r2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/gnome-color-manager-3.0.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-color-manager/gnome-color-manager-3.0.0-r2.ebuild?rev=1.1&content-type=text/plain
Index: gnome-color-manager-3.0.0-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-color-manager/gnome-color-manager-3.0.0-r2.ebuild,v 1.1 2011/08/19 11:09:04 nirbheek Exp $
EAPI="3"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
GNOME_TARBALL_SUFFIX="bz2"
inherit eutils gnome2
DESCRIPTION="Color profile manager for the GNOME desktop"
HOMEPAGE="http://projects.gnome.org/gnome-color-manager/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+introspection packagekit raw scanner"
# FIXME: raise libusb:1 to 1.0.9 when available
# FIXME: fix detection of docbook2man
COMMON_DEPEND=">=dev-libs/glib-2.25.9:2
>=dev-libs/libusb-1:1
>=gnome-base/gnome-control-center-3
gnome-base/gnome-settings-daemon
media-libs/lcms:2
>=media-libs/libcanberra-0.10[gtk3]
media-libs/libexif
media-libs/tiff
net-print/cups
|| ( sys-fs/udev[gudev] sys-fs/udev[extras] )
x11-libs/libX11
x11-libs/libXrandr
>=x11-libs/gtk+-2.91:3
>=x11-libs/libnotify-0.7
>=x11-libs/vte-0.25.1:2.90
introspection? ( >=dev-libs/gobject-introspection-0.6.7 )
scanner? ( media-gfx/sane-backends )
packagekit? ( app-admin/packagekit-base )
raw? ( media-gfx/exiv2 )
"
RDEPEND="${RDEPEND}
media-gfx/shared-color-profiles
"
# docbook-sgml-{utils,dtd:4.1} needed to generate man pages
DEPEND="${RDEPEND}
app-text/docbook-sgml-dtd:4.1
app-text/docbook-sgml-utils
app-text/gnome-doc-utils
dev-libs/libxslt
>=dev-util/intltool-0.35
"
# FIXME: run test-suite with files on live file-system
RESTRICT="test"
pkg_setup() {
# Always enable tests since they are check_PROGRAMS anyway
G2CONF="${G2CONF}
--disable-static
--disable-schemas-compile
--disable-scrollkeeper
--enable-tests
$(use_enable packagekit)
$(use_enable introspection)
$(use_enable raw exiv)
$(use_enable scanner sane)"
}
src_prepare() {
# Fix build
epatch "${FILESDIR}/${P}-packagename.patch"
# Upstream renamed 95-gcm-colorimeters.rules to 69-gcm-colorimeters.rules
# for next release (see commit dc276cbe) to fix colorimeter udev ACLs.
mv -f rules/{95,69}-gcm-colorimeters.rules || die "mv failed"
sed -e 's:95-gcm-colorimeters.rules:69-gcm-colorimeters.rules:' \
-i rules/Makefile.* || die "sed rules/Makefile.* failed"
# Upstream patch to fix a bug in control center panel when plugging in a
# colorimeter; will be in next release
epatch "${FILESDIR}/${P}-cc-panel.patch"
gnome2_src_prepare
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-08-19 11:09 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-08-19 11:09 [gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-color-manager: gnome-color-manager-3.0.0-r2.ebuild metadata.xml ChangeLog Nirbheek Chauhan (nirbheek)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox