[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.2.31_rc.ebuild tor-0.2.2.30_rc-r1.ebuild tor-0.2.3.2_alpha.ebuild tor-0.2.2.30_rc.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.2.31_rc.ebuild tor-0.2.2.30_rc-r1.ebuild tor-0.2.3.2_alpha.ebuild tor-0.2.2.30_rc.ebuild

[Anthony G. Basile (blueness)]

blueness    11/08/19 10:54:21

  Modified:             ChangeLog
  Added:                tor-0.2.2.31_rc.ebuild
  Removed:              tor-0.2.2.30_rc-r1.ebuild tor-0.2.3.2_alpha.ebuild
                        tor-0.2.2.30_rc.ebuild
  Log:
  Version bump RC and remove deprecated
  
  (Portage version: 2.1.10.3/cvs/Linux x86_64)

Revision  Changes    Path
1.266                net-misc/tor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.266&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.266&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?r1=1.265&r2=1.266

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v
retrieving revision 1.265
retrieving revision 1.266
diff -u -r1.265 -r1.266
--- ChangeLog	5 Aug 2011 11:29:39 -0000	1.265
+++ ChangeLog	19 Aug 2011 10:54:21 -0000	1.266
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/tor
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.265 2011/08/05 11:29:39 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.266 2011/08/19 10:54:21 blueness Exp $
+
+*tor-0.2.2.31_rc (19 Aug 2011)
+
+  19 Aug 2011; Anthony G. Basile <blueness@gentoo.org> -tor-0.2.2.30_rc.ebuild,
+  -tor-0.2.2.30_rc-r1.ebuild, +tor-0.2.2.31_rc.ebuild,
+  -tor-0.2.3.2_alpha.ebuild:
+  Version bump RC and remove deprecated
 
   05 Aug 2011; Anthony G. Basile <blueness@gentoo.org> files/tor.initd-r4:
   Removed deprecated -oknodo, bug #377773



1.1                  net-misc/tor/tor-0.2.2.31_rc.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.2.31_rc.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.2.31_rc.ebuild?rev=1.1&content-type=text/plain

Index: tor-0.2.2.31_rc.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.2.31_rc.ebuild,v 1.1 2011/08/19 10:54:21 blueness Exp $

EAPI=4

inherit autotools eutils flag-o-matic versionator

MY_PV="$(replace_version_separator 4 -)"
MY_PF="${PN}-${MY_PV}"
DESCRIPTION="Anonymizing overlay network for TCP"
HOMEPAGE="http://www.torproject.org/"
SRC_URI="http://www.torproject.org/dist/${MY_PF}.tar.gz"
S="${WORKDIR}/${MY_PF}"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc tor-hardening +transparent-proxy threads"

DEPEND="dev-libs/openssl
	>=dev-libs/libevent-2.0"
# The tordns patch for tsocks avoids some leakage of information thus raising anonymity
RDEPEND="${DEPEND}
	net-proxy/tsocks[tordns]"

pkg_setup() {
	enewgroup tor
	enewuser tor -1 -1 /var/lib/tor tor
}

src_prepare() {
	epatch "${FILESDIR}"/torrc.sample-0.1.2.6.patch
	epatch "${FILESDIR}"/${PN}-0.2.1.19-logrotate.patch

	einfo "Regenerating autotools files ..."
	epatch "${FILESDIR}"/${PN}-0.2.2.24_alpha-respect-CFLAGS.patch
	eautoreconf || die "eautoreconf failed"
}

src_configure() {
	# Upstream isn't sure of all the user provided CFLAGS that
	# will break tor, but does recommend against -fstrict-aliasing.
	# We'll filter-flags them here as we encounter them.
	filter-flags -fstrict-aliasing
	econf --docdir=/usr/share/doc/${PF}				\
		$(use_enable doc asciidoc)					\
		$(use_enable tor-hardening gcc-hardening)	\
		$(use_enable tor-hardening linker-hardening)\
		$(use_enable transparent-proxy transparent)	\
		$(use_enable threads)
}

src_install() {
	newconfd "${FILESDIR}"/tor.confd tor
	newinitd "${FILESDIR}"/tor.initd-r4 tor
	emake DESTDIR="${D}" install || die
	keepdir /var/{lib,log,run}/tor

	dodoc README ChangeLog ReleaseNotes \
		doc/{HACKING,TODO} \
		doc/spec/README

	fperms 750 /var/lib/tor /var/log/tor
	fperms 755 /var/run/tor
	fowners tor:tor /var/lib/tor /var/log/tor /var/run/tor

	insinto /etc/tor/
	doins "${FILESDIR}"/torrc

	insinto /etc/logrotate.d
	newins contrib/tor.logrotate tor
}

pkg_postinst() {
	elog
	elog "We created a configuration file for tor, /etc/tor/torrc, but you can"
	elog "change it according to your needs.  Use the torrc.sample that is in"
	elog "that directory as a guide.  Also, to have privoxy work with tor"
	elog "just add the following line"
	elog
	elog "forward-socks4a / localhost:9050 ."
	elog
	elog "to /etc/privoxy/config.  Notice the . at the end!"
	elog
}