* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: metadata.xml ChangeLog networkmanager-0.9_rc3.ebuild
@ 2011-08-15 14:58 Nirbheek Chauhan (nirbheek)
0 siblings, 0 replies; only message in thread
From: Nirbheek Chauhan (nirbheek) @ 2011-08-15 14:58 UTC (permalink / raw
To: gentoo-commits
nirbheek 11/08/15 14:58:42
Modified: metadata.xml ChangeLog
Added: networkmanager-0.9_rc3.ebuild
Log:
Bump to 0.9_rc3, from gnome overlay for great justice (and GNOME 3)
(Portage version: 2.2.0_alpha39_p14/cvs/Linux x86_64)
Revision Changes Path
1.17 net-misc/networkmanager/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/metadata.xml?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/metadata.xml?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/metadata.xml?r1=1.16&r2=1.17
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/metadata.xml,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- metadata.xml 21 Jul 2011 08:05:28 -0000 1.16
+++ metadata.xml 15 Aug 2011 14:58:42 -0000 1.17
@@ -10,21 +10,28 @@
<email>nirbheek@gentoo.org</email>
<name>Nirbheek Chauhan</name>
</maintainer>
- <maintainer>
- <email>steev@gentoo.org</email>
- <name>Stephen Klimaszewski</name>
- </maintainer>
<maintainer>
<email>qiaomuf@gentoo.org</email>
<name>Mu Qiao</name>
</maintainer>
-
+ <maintainer>
+ <email>steev@gentoo.org</email>
+ <name>Stephen Klimaszewski</name>
+ </maintainer>
<use>
- <flag name="dhclient">Use dhclient from <pkg>net-misc/dhcp</pkg> for getting ip.</flag>
- <flag name="dhcpcd">Use <pkg>net-misc/dhcpcd</pkg> for getting ip.</flag>
- <flag name="nss">Use <pkg>dev-libs/nss</pkg> for cryptography.</flag>
- <flag name="ppp">Enable support for mobile broadband and PPPoE connections using <pkg>net-dialup/ppp</pkg>.</flag>
- <flag name="resolvconf">Use <pkg>net-dns/openresolv</pkg> for managing DNS information</flag>
- <flag name="connection-sharing">Use <pkg>net-dns/dnsmasq</pkg> and <pkg>net-firewall/iptables</pkg> for connection sharing </flag>
+ <flag name="connection-sharing">Use <pkg>net-dns/dnsmasq</pkg> and
+ <pkg>net-firewall/iptables</pkg> for connection sharing</flag>
+ <flag name="dhclient">Use dhclient from <pkg>net-misc/dhcp</pkg> for
+ getting ip</flag>
+ <flag name="dhcpcd">Use <pkg>net-misc/dhcpcd</pkg> for getting ip</flag>
+ <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
+ for introspection</flag>
+ <flag name="nss">Use <pkg>dev-libs/nss</pkg> for cryptography</flag>
+ <flag name="ppp">Enable support for mobile broadband and PPPoE
+ connections using <pkg>net-dialup/ppp</pkg></flag>
+ <flag name="resolvconf">Use <pkg>net-dns/openresolv</pkg> for managing
+ DNS information</flag>
+ <flag name="wimax">Enable support for WiMAX connections using
+ <pkg>net-wireless/wimax</pkg></flag>
</use>
</pkgmetadata>
1.110 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.109&r2=1.110
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog 14 Aug 2011 09:04:08 -0000 1.109
+++ ChangeLog 15 Aug 2011 14:58:42 -0000 1.110
@@ -1,6 +1,13 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.109 2011/08/14 09:04:08 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.110 2011/08/15 14:58:42 nirbheek Exp $
+
+*networkmanager-0.9_rc3 (15 Aug 2011)
+
+ 15 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+ +networkmanager-0.9_rc3.ebuild,
+ +files/networkmanager-0.9_rc3-fix-tests.patch, metadata.xml:
+ Bump to 0.9_rc3, from gnome overlay for great justice (and GNOME 3)
14 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
networkmanager-0.8.4.0-r2.ebuild:
1.1 net-misc/networkmanager/networkmanager-0.9_rc3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9_rc3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.9_rc3.ebuild?rev=1.1&content-type=text/plain
Index: networkmanager-0.9_rc3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.9_rc3.ebuild,v 1.1 2011/08/15 14:58:42 nirbheek Exp $
EAPI="4"
GNOME_ORG_MODULE="NetworkManager"
PATCHSET="${PN}-0.9-patches-0.1"
REAL_PV="0.8.9997"
inherit autotools eutils gnome.org linux-info systemd
DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
# Replace our fake _rc version with the actual version
SRC_URI="${SRC_URI//${PV}/${REAL_PV}}
mirror://gentoo/${PATCHSET}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
IUSE="avahi bluetooth doc +nss gnutls dhclient +dhcpcd +introspection
kernel_linux +ppp resolvconf connection-sharing wimax"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
REQUIRED_USE="
^^ ( nss gnutls )
^^ ( dhclient dhcpcd )"
# gobject-introspection-0.10.3 is needed due to gnome bug 642300
# wpa_supplicant-0.7.3-r3 is needed due to bug 359271
# make consolekit and/or polkit support optional ?
COMMON_DEPEND=">=sys-apps/dbus-1.2
>=dev-libs/dbus-glib-0.75
>=net-wireless/wireless-tools-28_pre9
|| ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-147[extras] )
>=dev-libs/glib-2.26
>=sys-auth/polkit-0.97
>=dev-libs/libnl-1.1
>=net-misc/modemmanager-0.4
>=net-wireless/wpa_supplicant-0.7.3-r3[dbus]
bluetooth? ( >=net-wireless/bluez-4.82 )
avahi? ( net-dns/avahi[autoipd] )
gnutls? (
dev-libs/libgcrypt
net-libs/gnutls )
nss? ( >=dev-libs/nss-3.11 )
dhclient? ( net-misc/dhcp )
dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
introspection? ( >=dev-libs/gobject-introspection-0.10.3 )
ppp? ( >=net-dialup/ppp-2.4.5 )
resolvconf? ( net-dns/openresolv )
connection-sharing? (
net-dns/dnsmasq
net-firewall/iptables )
wimax? ( >=net-wireless/wimax-1.5.1 )"
RDEPEND="${COMMON_DEPEND}
sys-auth/consolekit"
DEPEND="${COMMON_DEPEND}
dev-util/pkgconfig
>=dev-util/intltool-0.40
>=sys-devel/gettext-0.17
doc? ( >=dev-util/gtk-doc-1.8 )"
# Replace our fake _rc version with the actual version
S="${WORKDIR}/${GNOME_ORG_MODULE}-${REAL_PV}"
sysfs_deprecated_check() {
ebegin "Checking for SYSFS_DEPRECATED support"
if { linux_chkconfig_present SYSFS_DEPRECATED_V2; }; then
eerror "Please disable SYSFS_DEPRECATED_V2 support in your kernel config and recompile your kernel"
eerror "or NetworkManager will not work correctly."
eerror "See http://bugs.gentoo.org/333639 for more info."
die "CONFIG_SYSFS_DEPRECATED_V2 support detected!"
fi
eend $?
}
pkg_pretend() {
if use kernel_linux; then
get_version
if linux_config_exists; then
sysfs_deprecated_check
else
ewarn "Was unable to determine your kernel .config"
ewarn "Please note that if CONFIG_SYSFS_DEPRECATED_V2 is set in your kernel .config, NetworkManager will not work correctly."
ewarn "See http://bugs.gentoo.org/333639 for more info."
fi
fi
}
src_prepare() {
# Add useful patches from upstream git (fixing crashes, SSID parsing bugs,
# and significant usability problems).
epatch "${WORKDIR}/${PATCHSET}/"*.patch
# Don't build tests
epatch "${FILESDIR}/${P}-fix-tests.patch"
eautoreconf
default
}
src_configure() {
ECONF="--disable-more-warnings
--disable-static
--localstatedir=/var
--with-distro=gentoo
--with-dbus-sys-dir=/etc/dbus-1/system.d
--with-udev-dir=/lib/udev
--with-iptables=/sbin/iptables
$(use_enable doc gtk-doc)
$(use_enable introspection)
$(use_enable ppp)
$(use_enable wimax)
$(use_with dhclient)
$(use_with dhcpcd)
$(use_with doc docs)
$(use_with resolvconf)
$(systemd_with_unitdir)"
if use nss ; then
ECONF="${ECONF} $(use_with nss crypto=nss)"
else
ECONF="${ECONF} $(use_with gnutls crypto=gnutls)"
fi
econf ${ECONF}
}
src_install() {
default
# Need to keep the /var/run/NetworkManager directory
keepdir /var/run/NetworkManager
# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
keepdir /etc/NetworkManager/dispatcher.d
# Add keyfile plugin support
keepdir /etc/NetworkManager/system-connections
insinto /etc/NetworkManager
newins "${FILESDIR}/nm-system-settings.conf-ifnet" nm-system-settings.conf
# Remove useless .la files
find "${D}" -name '*.la' -exec rm -f {} + || die "la file removal failed"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-08-15 14:58 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-08-15 14:58 [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: metadata.xml ChangeLog networkmanager-0.9_rc3.ebuild Nirbheek Chauhan (nirbheek)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox