[gentoo-commits] gentoo-x86 commit in sci-physics/lhapdf: ChangeLog lhapdf-5.8.6.ebuild

[gentoo-commits] gentoo-x86 commit in sci-physics/lhapdf: ChangeLog lhapdf-5.8.6.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    11/08/06 20:53:59

  Modified:             ChangeLog
  Added:                lhapdf-5.8.6.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.10/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 sci-physics/lhapdf/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	9 Mar 2011 20:03:41 -0000	1.17
+++ ChangeLog	6 Aug 2011 20:53:59 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for sci-physics/lhapdf
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/ChangeLog,v 1.17 2011/03/09 20:03:41 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/ChangeLog,v 1.18 2011/08/06 20:53:59 bicatali Exp $
+
+*lhapdf-5.8.6 (06 Aug 2011)
+
+  06 Aug 2011; Sébastien Fabbro <bicatali@gentoo.org> +lhapdf-5.8.6.ebuild:
+  Version bump
 
 *lhapdf-5.8.5 (09 Mar 2011)
 



1.1                  sci-physics/lhapdf/lhapdf-5.8.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/lhapdf-5.8.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/lhapdf/lhapdf-5.8.6.ebuild?rev=1.1&content-type=text/plain

Index: lhapdf-5.8.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/lhapdf-5.8.6.ebuild,v 1.1 2011/08/06 20:53:59 bicatali Exp $

EAPI=4

inherit versionator eutils

MY_PV=$(get_version_component_range 1-3 ${PV})
MY_PF=${PN}-${MY_PV}

DESCRIPTION="Les Houches Parton Density Function unified library"
HOMEPAGE="http://projects.hepforge.org/lhapdf/"
SRC_URI="http://www.hepforge.org/archive/lhapdf/${MY_PF}.tar.gz
	test? (
		http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/cteq61.LHgrid
		http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/MRST2004nlo.LHgrid
		http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/cteq61.LHpdf
		octave? ( http://svn.hepforge.org/${PN}/pdfsets/tags/${MY_PV}/cteq5l.LHgrid ) )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cxx doc examples octave python static-libs test"
REQUIRED_USE="octave? ( cxx )"
RDEPEND="octave? ( sci-mathematics/octave )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen[latex] )
	python? ( dev-lang/swig )"

S="${WORKDIR}/${MY_PF}"

src_prepare() {
	# do not create extra latex docs
	sed -i \
		-e 's/GENERATE_LATEX.*=YES/GENERATE_LATEX = NO/g' \
		ccwrap/Doxyfile || die
}

src_configure() {
	econf \
		$(use_enable cxx ccwrap) \
		$(use_enable cxx old-ccwrap ) \
		$(use_enable doc doxygen) \
		$(use_enable octave) \
		$(use_enable python pyext) \
		$(use_enable static-libs static)
}

src_test() {
	# need to make a bogus link for octave test
	ln -s "${DISTDIR}" PDFsets
	LHAPATH="${PWD}/PDFsets" \
		LD_LIBRARY_PATH="${PWD}/lib/.libs:${LD_LIBRARY_PATH}" \
		emake check
}

src_install() {
	default
	# leftover
	rm -rf "${ED}"/usr/share/${PN}/doc || die
	use doc && use cxx && dohtml -r ccwrap/doxy/html/*
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.{f,cc}
	fi
}

pkg_postinst() {
	elog "To install data files, you have to run as root:"
	elog "lhapdf-getdata --dest=${EROOT}usr/share/lhapdf/PDFsets --all"
}