[gentoo-commits] gentoo-x86 commit in dev-java/netbeans-ergonomics: ChangeLog netbeans-ergonomics-7.0.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-java/netbeans-ergonomics: ChangeLog netbeans-ergonomics-7.0.1.ebuild

[Miroslav Sulc (fordfrog)]

fordfrog    11/08/05 10:25:54

  Modified:             ChangeLog
  Added:                netbeans-ergonomics-7.0.1.ebuild
  Log:
  dev-java/netbeans-ergonomics: version bump
  
  (Portage version: 2.1.10.10/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  dev-java/netbeans-ergonomics/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-ergonomics/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-ergonomics/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-ergonomics/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/netbeans-ergonomics/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	21 Apr 2011 10:29:45 -0000	1.3
+++ ChangeLog	5 Aug 2011 10:25:54 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/netbeans-ergonomics
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/netbeans-ergonomics/ChangeLog,v 1.3 2011/04/21 10:29:45 fordfrog Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/netbeans-ergonomics/ChangeLog,v 1.4 2011/08/05 10:25:54 fordfrog Exp $
+
+*netbeans-ergonomics-7.0.1 (05 Aug 2011)
+
+  05 Aug 2011; Miroslav Šulc <fordfrog@gentoo.org>
+  +netbeans-ergonomics-7.0.1.ebuild:
+  Version bump
 
 *netbeans-ergonomics-7.0 (21 Apr 2011)
 



1.1                  dev-java/netbeans-ergonomics/netbeans-ergonomics-7.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-ergonomics/netbeans-ergonomics-7.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-ergonomics/netbeans-ergonomics-7.0.1.ebuild?rev=1.1&content-type=text/plain

Index: netbeans-ergonomics-7.0.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/netbeans-ergonomics/netbeans-ergonomics-7.0.1.ebuild,v 1.1 2011/08/05 10:25:54 fordfrog Exp $

EAPI="4"
WANT_ANT_TASKS="ant-nodeps"
inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="Netbeans Ergonomics Cluster"
HOMEPAGE="http://netbeans.org/"
SLOT="7.0"
SOURCE_URL="http://download.netbeans.org/netbeans/7.0.1/final/zip/netbeans-7.0.1-201107282000-src.zip"
SRC_URI="${SOURCE_URL}
	http://dev.gentoo.org/~fordfrog/distfiles/netbeans-${SLOT}-build.xml-r1.patch.bz2"
LICENSE="|| ( CDDL GPL-2-with-linking-exception )"
KEYWORDS="~amd64 ~x86"
IUSE=""
S="${WORKDIR}"

CDEPEND="~dev-java/netbeans-ide-${PV}
	~dev-java/netbeans-nb-${PV}
	~dev-java/netbeans-platform-${PV}"
DEPEND=">=virtual/jdk-1.6
	app-arch/unzip
	${CDEPEND}
	dev-java/javahelp:0"
RDEPEND=">=virtual/jdk-1.6
	${CDEPEND}"

INSTALL_DIR="/usr/share/${PN}-${SLOT}"

EANT_BUILD_XML="nbbuild/build.xml"
EANT_BUILD_TARGET="rebuild-cluster"
EANT_EXTRA_ARGS="-Drebuild.cluster.name=nb.cluster.ergonomics -Dext.binaries.downloaded=true"
JAVA_PKG_BSFIX="off"

src_unpack() {
	unpack $(basename ${SOURCE_URL})

	einfo "Deleting bundled jars..."
	find -name "*.jar" -type f -delete

	unpack netbeans-7.0-build.xml-r1.patch.bz2
}

src_prepare() {
	einfo "Deleting bundled class files..."
	find -name "*.class" -type f | xargs rm -vf

	epatch netbeans-7.0-build.xml-r1.patch

	# Support for custom patches
	if [ -n "${NETBEANS70_PATCHES_DIR}" -a -d "${NETBEANS70_PATCHES_DIR}" ] ; then
		local files=`find "${NETBEANS70_PATCHES_DIR}" -type f`

		if [ -n "${files}" ] ; then
			einfo "Applying custom patches:"

			for file in ${files} ; do
				epatch "${file}"
			done
		fi
	fi

	einfo "Symlinking external libraries..."
	java-pkg_jar-from --build-only --into javahelp/external javahelp jhall.jar jhall-2.0_05.jar

	einfo "Linking in other clusters..."
	mkdir "${S}"/nbbuild/netbeans || die
	pushd "${S}"/nbbuild/netbeans >/dev/null || die

	ln -s /usr/share/netbeans-ide-${SLOT} ide || die
	cat /usr/share/netbeans-ide-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die
	touch nb.cluster.ide.built

	ln -s /usr/share/netbeans-nb-${SLOT}/nb nb || die
	cat /usr/share/netbeans-nb-${SLOT}/nb/moduleCluster.properties >> moduleCluster.properties || die
	touch nb.cluster.nb.built

	ln -s /usr/share/netbeans-platform-${SLOT} platform || die
	cat /usr/share/netbeans-platform-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die
	touch nb.cluster.platform.built

	popd >/dev/null || die

	java-pkg-2_src_prepare
}

src_install() {
	pushd nbbuild/netbeans/ergonomics >/dev/null || die

	insinto ${INSTALL_DIR}

	grep -E "/ergonomics$" ../moduleCluster.properties > "${D}"/${INSTALL_DIR}/moduleCluster.properties || die

	doins -r *

	popd >/dev/null || die

	dosym ${INSTALL_DIR} /usr/share/netbeans-nb-${SLOT}/ergonomics
}