public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in dev-util/android-sdk-update-manager: ChangeLog android-sdk-update-manager-12.ebuild
@ 2011-07-29 19:12 Richard Freeman (rich0)
  0 siblings, 0 replies; only message in thread
From: Richard Freeman (rich0) @ 2011-07-29 19:12 UTC (permalink / raw
  To: gentoo-commits

rich0       11/07/29 19:12:19

  Modified:             ChangeLog
  Added:                android-sdk-update-manager-12.ebuild
  Log:
  Version bump - 376097
  
  (Portage version: 2.1.10.3/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 dev-util/android-sdk-update-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/android-sdk-update-manager/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/android-sdk-update-manager/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/android-sdk-update-manager/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/android-sdk-update-manager/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	9 Jul 2011 13:37:34 -0000	1.24
+++ ChangeLog	29 Jul 2011 19:12:19 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/android-sdk-update-manager
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/android-sdk-update-manager/ChangeLog,v 1.24 2011/07/09 13:37:34 rich0 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/android-sdk-update-manager/ChangeLog,v 1.25 2011/07/29 19:12:19 rich0 Exp $
+
+*android-sdk-update-manager-12 (29 Jul 2011)
+
+  29 Jul 2011; Richard Freeman <rich0@gentoo.org>
+  +android-sdk-update-manager-12.ebuild:
+  Version bump - 376097
 
   09 Jul 2011; Richard Freeman <rich0@gentoo.org>
   -android-sdk-update-manager-8-r2.ebuild,



1.1                  dev-util/android-sdk-update-manager/android-sdk-update-manager-12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/android-sdk-update-manager/android-sdk-update-manager-12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/android-sdk-update-manager/android-sdk-update-manager-12.ebuild?rev=1.1&content-type=text/plain

Index: android-sdk-update-manager-12.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/android-sdk-update-manager/android-sdk-update-manager-12.ebuild,v 1.1 2011/07/29 19:12:19 rich0 Exp $

EAPI="3"

inherit eutils

MY_P="android-sdk_r${PV}-linux_x86"

DESCRIPTION="Open Handset Alliance's Android SDK"
HOMEPAGE="http://developer.android.com"
SRC_URI="http://dl.google.com/android/${MY_P}.tgz"
IUSE=""
RESTRICT="mirror"

LICENSE="android"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="app-arch/tar
		app-arch/gzip"
RDEPEND=">=virtual/jdk-1.5
	>=dev-java/ant-core-1.6.5
	=dev-java/swt-3.5*
	amd64? ( app-emulation/emul-linux-x86-gtklibs )
	x86? ( x11-libs/gtk+:2 )"

ANDROID_SDK_DIR="/opt/${PN}"
QA_DT_HASH_x86="
	${ANDROID_SDK_DIR/\/}/tools/emulator
	${ANDROID_SDK_DIR/\/}/tools/adb
	${ANDROID_SDK_DIR/\/}/tools/mksdcard
	${ANDROID_SDK_DIR/\/}/tools/sqlite3
	${ANDROID_SDK_DIR/\/}/tools/hprof-conv
	${ANDROID_SDK_DIR/\/}/tools/zipalign
	${ANDROID_SDK_DIR/\/}/tools/dmtracedump
"
QA_DT_HASH_amd64="${QA_DT_HASH_x86}"

S="${WORKDIR}/android-sdk-linux_x86"

pkg_setup() {
	enewgroup android || die
}

src_prepare(){
#	epatch "${FILESDIR}/${PN}-8-swt.patch"

	rm -rf tools/lib/x86*
}

src_install(){
	dodoc tools/NOTICE.txt "SDK Readme.txt" || die
	rm -f tools/NOTICE.txt "SDK Readme.txt"

	dodir "${ANDROID_SDK_DIR}/tools"
	cp -pPR tools/* "${ED}${ANDROID_SDK_DIR}/tools" || die "failed to install tools"

	# Maybe this is needed for the tools directory too.
	#keepdir "${ANDROID_SDK_DIR}"/{add-ons,docs,platforms,temp} || die "failed to keepdir"
	dodir "${ANDROID_SDK_DIR}"/{add-ons,docs,platforms,temp} || die "failed to dodir"

	fowners root:android "${ANDROID_SDK_DIR}"/{,add-ons,docs,platforms,temp,tools} || die
	fperms 0775 "${ANDROID_SDK_DIR}"/{,add-ons,docs,platforms,temp,tools} || die

	echo "PATH=\"${EPREFIX}${ANDROID_SDK_DIR}/tools:${EPREFIX}${ANDROID_SDK_DIR}/platform-tools\"" > "${T}/80${PN}" || die

	SWT_PATH="`dirname \`java-config -p swt-3.5\``"

	echo "ANDROID_SWT=\"${SWT_PATH}\"" >> "${T}/80${PN}" || die

	doenvd "${T}/80${PN}" || die

	echo "SEARCH_DIRS_MASK=\"${EPREFIX}${ANDROID_SDK_DIR}\"" > "${T}/80${PN}" || die

	insinto "/etc/revdep-rebuild" && doins "${T}/80${PN}" || die

}

pkg_postinst() {
	elog "The Android SDK now uses its own manager for the development	environment."
	elog "Run 'android' to download the full SDK, including some of the platform tools."
	elog "You must be in the android group to manage the development environment."
	elog "Just run 'gpasswd -a <USER> android', then have <USER> re-login."
	elog "See http://developer.android.com/sdk/adding-components.html for more"
	elog "information."
	elog "If you have problems downloading the SDK, see http://code.google.com/p/android/issues/detail?id=4406"
	elog "You need to run env-update and source /etc/profile in any open shells"
	elog "if you get an SWT error."
}






^ permalink raw reply	[flat|nested] only message in thread

only message in thread, other threads:[~2011-07-29 19:12 UTC | newest]

Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-07-29 19:12 [gentoo-commits] gentoo-x86 commit in dev-util/android-sdk-update-manager: ChangeLog android-sdk-update-manager-12.ebuild Richard Freeman (rich0)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox