* [gentoo-commits] gentoo-x86 commit in media-gfx/darktable: darktable-0.9.1.ebuild ChangeLog
@ 2011-07-28 6:57 Tim Harder (radhermit)
0 siblings, 0 replies; only message in thread
From: Tim Harder (radhermit) @ 2011-07-28 6:57 UTC (permalink / raw
To: gentoo-commits
radhermit 11/07/28 06:57:48
Modified: ChangeLog
Added: darktable-0.9.1.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha47/cvs/Linux x86_64)
Revision Changes Path
1.3 media-gfx/darktable/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/ChangeLog?r1=1.2&r2=1.3
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog 21 Jul 2011 08:55:05 -0000 1.2
+++ ChangeLog 28 Jul 2011 06:57:48 -0000 1.3
@@ -1,6 +1,12 @@
# ChangeLog for media-gfx/darktable
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.2 2011/07/21 08:55:05 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.3 2011/07/28 06:57:48 radhermit Exp $
+
+*darktable-0.9.1 (28 Jul 2011)
+
+ 28 Jul 2011; Tim Harder <radhermit@gentoo.org> +darktable-0.9.1.ebuild,
+ +files/darktable-0.9.1-system-libraw.patch:
+ Version bump.
*darktable-0.9-r1 (21 Jul 2011)
1.1 media-gfx/darktable/darktable-0.9.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-0.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-0.9.1.ebuild?rev=1.1&content-type=text/plain
Index: darktable-0.9.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-0.9.1.ebuild,v 1.1 2011/07/28 06:57:48 radhermit Exp $
EAPI="4"
if [[ ${PV} == "9999" ]]; then
EGIT_REPO_URI="git://darktable.git.sf.net/gitroot/darktable/darktable"
EGIT_BRANCH="master"
EGIT_COMMIT="master"
SCM="git-2"
KEYWORDS=""
else
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
GCONF_DEBUG="no"
inherit cmake-utils ${SCM}
DESCRIPTION="A virtual lighttable and darkroom for photographers"
HOMEPAGE="http://darktable.sf.net/"
LICENSE="GPL-3"
SLOT="0"
IUSE="debug flickr gconf gnome-keyring gphoto2 kde nls openmp +slideshow"
RDEPEND="
dev-db/sqlite:3
dev-libs/libxml2:2
flickr? ( media-libs/flickcurl )
gconf? ( gnome-base/gconf )
gnome-base/libglade:2.0
gnome-base/librsvg:2
gnome-keyring? ( gnome-base/gnome-keyring )
gphoto2? ( media-libs/libgphoto2 )
kde? ( dev-libs/dbus-glib )
media-gfx/exiv2
media-libs/lcms:2
>=media-libs/lensfun-0.2.3
media-libs/libpng
>=media-libs/libraw-0.13.4[demosaic]
media-libs/openexr
media-libs/tiff
net-misc/curl
slideshow? (
media-libs/libsdl
virtual/opengl
)
virtual/jpeg
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:2"
DEPEND="${RDEPEND}
dev-util/pkgconfig
nls? ( sys-devel/gettext )
openmp? ( >=sys-devel/gcc-4.4[openmp] )"
PATCHES=(
"${FILESDIR}"/${PN}-0.9-automagic-deps.patch
"${FILESDIR}"/${P}-system-libraw.patch
"${FILESDIR}"/${PN}-0.9-cflags.patch
)
src_prepare() {
base_src_prepare
sed -i -e "s:\(/share/doc/\)darktable:\1${PF}:" \
-e "s:LICENSE::" doc/CMakeLists.txt || die
}
src_configure() {
use debug && CMAKE_BUILD_TYPE=Debug
mycmakeargs=(
$(cmake-utils_use_use flickr FLICKR)
$(cmake-utils_use_use gconf GCONF_BACKEND)
$(cmake-utils_use_use gnome-keyring GNOME_KEYRING)
$(cmake-utils_use_use gphoto2 CAMERA_SUPPORT)
$(cmake-utils_use_use kde KWALLET)
$(cmake-utils_use_use nls NLS)
$(cmake-utils_use_use openmp OPENMP)
$(cmake-utils_use_build slideshow SLIDESHOW)
-DDONT_INSTALL_GCONF_SCHEMAS=ON
-DINSTALL_IOP_EXPERIMENTAL=ON
-DINSTALL_IOP_LEGACY=ON
)
cmake-utils_src_configure
}
src_install(){
cmake-utils_src_install
newicon data/pixmaps/48x48/darktable.png darktable.png
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-07-28 6:58 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-07-28 6:57 [gentoo-commits] gentoo-x86 commit in media-gfx/darktable: darktable-0.9.1.ebuild ChangeLog Tim Harder (radhermit)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox