[gentoo-commits] gentoo-x86 commit in sci-physics/cernlib-montecarlo: ChangeLog cernlib-montecarlo-2006-r3.ebuild

[gentoo-commits] gentoo-x86 commit in sci-physics/cernlib-montecarlo: ChangeLog cernlib-montecarlo-2006-r3.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    11/07/21 16:49:43

  Modified:             ChangeLog
  Added:                cernlib-montecarlo-2006-r3.ebuild
  Log:
  New debian patch set. Switch to EAPI4
  
  (Portage version: 2.1.10.7/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 sci-physics/cernlib-montecarlo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/cernlib-montecarlo/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/cernlib-montecarlo/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/cernlib-montecarlo/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/cernlib-montecarlo/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	21 Jun 2011 14:40:57 -0000	1.15
+++ ChangeLog	21 Jul 2011 16:49:43 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for sci-physics/cernlib-montecarlo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/cernlib-montecarlo/ChangeLog,v 1.15 2011/06/21 14:40:57 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/cernlib-montecarlo/ChangeLog,v 1.16 2011/07/21 16:49:43 bicatali Exp $
+
+*cernlib-montecarlo-2006-r3 (21 Jul 2011)
+
+  21 Jul 2011; Sébastien Fabbro <bicatali@gentoo.org>
+  +cernlib-montecarlo-2006-r3.ebuild:
+  New debian patch set. Switch to EAPI4
 
   21 Jun 2011; Justin Lecher <jlec@gentoo.org>
   cernlib-montecarlo-2006-r2.ebuild:



1.1                  sci-physics/cernlib-montecarlo/cernlib-montecarlo-2006-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/cernlib-montecarlo/cernlib-montecarlo-2006-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/cernlib-montecarlo/cernlib-montecarlo-2006-r3.ebuild?rev=1.1&content-type=text/plain

Index: cernlib-montecarlo-2006-r3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/cernlib-montecarlo/cernlib-montecarlo-2006-r3.ebuild,v 1.1 2011/07/21 16:49:43 bicatali Exp $

EAPI=4
inherit eutils toolchain-funcs

DEB_PN=mclibs
DEB_PV=20061220+dfsg3
DEB_PR=1
DEB_P=${DEB_PN}_${DEB_PV}

DESCRIPTION="Monte-carlo library and tools for the cernlib"
HOMEPAGE="http://wwwasd.web.cern.ch/wwwasd/cernlib"
LICENSE="GPL-2 LGPL-2 BSD"
SRC_URI="mirror://debian/pool/main/${DEB_PN:0:1}/${DEB_PN}/${DEB_P}.orig.tar.gz
	mirror://debian/pool/main/${DEB_PN:0:1}/${DEB_PN}/${DEB_P}-${DEB_PR}.debian.tar.gz"

KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="+herwig"

RDEPEND=">=x11-libs/openmotif-2.3:0
	dev-lang/cfortran
	virtual/fortran
	sci-physics/cernlib
	herwig? ( !sci-physics/herwig )"

DEPEND="${RDEPEND}
	virtual/latex-base
	x11-misc/imake
	x11-misc/makedepend"

S="${WORKDIR}/${DEB_PN}-${DEB_PV}.orig"

src_prepare() {
	mv ../debian .
	cp debian/add-ons/Makefile .
	export DEB_BUILD_OPTIONS="$(tc-getFC) nostrip nocheck"
	sed -i \
		-e 's:/usr/local:/usr:g' \
		Makefile || die "sed'ing the Makefile failed"

	einfo "Applying Debian patches"
	emake -j1 patch
	use herwig || epatch "${FILESDIR}"/${P}-noherwig.patch
	# since we depend on cfortran, do not use the one from cernlib
	rm -f src/include/cfortran/cfortran.h
}

src_compile() {
	VARTEXFONTS="${T}"/fonts
	emake -j1 cernlib-indep cernlib-arch
}

src_test() {
	LD_LIBRARY_PATH="${S}"/shlib \
		emake -j1 cernlib-test
}

src_install() {
	emake DESTDIR="${D}" MCDOC="${D}usr/share/doc/${PF}" install
	cd "${S}"/debian
	dodoc changelog README.* deadpool.txt copyright
	newdoc add-ons/README README.add-ons
}