* [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-9999.ebuild ChangeLog pulseaudio-0.9.23-r1.ebuild pulseaudio-0.9.23.ebuild
@ 2011-07-09 20:28 Arun Raghavan (ford_prefect)
0 siblings, 0 replies; only message in thread
From: Arun Raghavan (ford_prefect) @ 2011-07-09 20:28 UTC (permalink / raw
To: gentoo-commits
ford_prefect 11/07/09 20:28:49
Modified: pulseaudio-9999.ebuild ChangeLog
Added: pulseaudio-0.9.23-r1.ebuild
Removed: pulseaudio-0.9.23.ebuild
Log:
Fix udev rules to go to /lib not /$(get_libdir) (thanks to Samuli for pointing this out)
(Portage version: 2.2.0_alpha43/cvs/Linux x86_64)
Revision Changes Path
1.10 media-sound/pulseaudio/pulseaudio-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?r1=1.9&r2=1.10
Index: pulseaudio-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- pulseaudio-9999.ebuild 28 Jun 2011 21:20:37 -0000 1.9
+++ pulseaudio-9999.ebuild 9 Jul 2011 20:28:49 -0000 1.10
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v 1.9 2011/06/28 21:20:37 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v 1.10 2011/07/09 20:28:49 ford_prefect Exp $
EAPI=4
@@ -111,7 +111,7 @@
--localstatedir="${EPREFIX}"/var \
--disable-per-user-esound-socket \
--with-database=gdbm \
- --with-udev-rules-dir="${EPREFIX}/$(get_libdir)/udev/rules.d"
+ --with-udev-rules-dir="${EPREFIX}/lib/udev/rules.d"
if use doc; then
pushd doxygen
1.238 media-sound/pulseaudio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.238&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.238&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.237&r2=1.238
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.237
retrieving revision 1.238
diff -u -r1.237 -r1.238
--- ChangeLog 9 Jul 2011 19:54:34 -0000 1.237
+++ ChangeLog 9 Jul 2011 20:28:49 -0000 1.238
@@ -1,6 +1,14 @@
# ChangeLog for media-sound/pulseaudio
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.237 2011/07/09 19:54:34 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.238 2011/07/09 20:28:49 ford_prefect Exp $
+
+*pulseaudio-0.9.23-r1 (09 Jul 2011)
+
+ 09 Jul 2011; Arun Raghavan <ford_prefect@gentoo.org>
+ -pulseaudio-0.9.23.ebuild, +pulseaudio-0.9.23-r1.ebuild,
+ pulseaudio-9999.ebuild:
+ Fix udev rules to go to /lib not /$(get_libdir) (thanks to Samuli for
+ pointing this out)
09 Jul 2011; Arun Raghavan <ford_prefect@gentoo.org>
pulseaudio-0.9.23.ebuild:
1.1 media-sound/pulseaudio/pulseaudio-0.9.23-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.23-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.23-r1.ebuild?rev=1.1&content-type=text/plain
Index: pulseaudio-0.9.23-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.23-r1.ebuild,v 1.1 2011/07/09 20:28:49 ford_prefect Exp $
EAPI=4
inherit eutils libtool flag-o-matic versionator
DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"
SRC_URI="http://freedesktop.org/software/pulseaudio/releases/${P}.tar.gz"
LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+alsa avahi +caps jack lirc oss tcpd +X dbus libsamplerate gnome bluetooth +asyncns +glib test doc +udev ipv6 system-wide realtime"
RDEPEND="app-admin/eselect-esd
X? (
|| ( >=x11-libs/libX11-1.4.0 <x11-libs/libX11-1.4.0[xcb] )
>=x11-libs/libxcb-1.6
>=x11-libs/xcb-util-0.3.1
x11-libs/libSM
x11-libs/libICE
x11-libs/libXtst
)
caps? ( sys-libs/libcap )
libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
alsa? ( >=media-libs/alsa-lib-1.0.19 )
glib? ( >=dev-libs/glib-2.4.0 )
avahi? ( >=net-dns/avahi-0.6.12[dbus] )
jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
tcpd? ( sys-apps/tcp-wrappers )
lirc? ( app-misc/lirc )
dbus? ( >=sys-apps/dbus-1.0.0 )
gnome? ( >=gnome-base/gconf-2.4.0 )
bluetooth? (
>=net-wireless/bluez-4
>=sys-apps/dbus-1.0.0
)
asyncns? ( net-libs/libasyncns )
udev? ( || ( >=sys-fs/udev-171[hwdb] >=sys-fs/udev-143[extras] ) )
realtime? ( sys-auth/rtkit )
>=media-libs/audiofile-0.2.6-r1
>=media-libs/speex-1.2_rc1
>=media-libs/libsndfile-1.0.20
sys-libs/gdbm
>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )
X? (
x11-proto/xproto
|| ( >=x11-libs/libXtst-1.0.99.2 <x11-proto/xextproto-7.0.99 )
)
dev-libs/libatomic_ops
dev-util/pkgconfig
system-wide? ( || ( dev-util/unifdef sys-freebsd/freebsd-ubin ) )
dev-util/intltool"
# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez dep is for the bluetooth init.d script
RDEPEND="${RDEPEND}
X? ( gnome-extra/gnome-audio )
system-wide? (
sys-apps/openrc
alsa? ( media-sound/alsa-utils )
bluetooth? ( >=net-wireless/bluez-4 )
)"
pkg_setup() {
enewgroup audio 18 # Just make sure it exists
enewgroup pulse-access
enewgroup pulse
enewuser pulse -1 -1 /var/run/pulse pulse,audio
}
src_configure() {
# It's a binutils bug, once I can find time to fix that I'll add a
# proper dependency and fix this up. — flameeyes
append-ldflags $(no-as-needed)
econf \
--enable-largefile \
$(use_enable glib glib2) \
--disable-solaris \
$(use_enable asyncns) \
$(use_enable oss oss-output) \
$(use_enable alsa) \
$(use_enable lirc) \
$(use_enable tcpd tcpwrap) \
$(use_enable jack) \
$(use_enable lirc) \
$(use_enable avahi) \
--disable-hal \
$(use_enable dbus) \
$(use_enable gnome gconf) \
$(use_enable libsamplerate samplerate) \
$(use_enable bluetooth bluez) \
$(use_enable X x11) \
$(use_enable test default-build-tests) \
$(use_enable udev) \
$(use_enable ipv6) \
$(use_with caps) \
--localstatedir="${EPREFIX}"/var \
--disable-per-user-esound-socket \
--with-database=gdbm \
--with-udev-rules-dir="${EPREFIX}/lib/udev/rules.d"
if use doc; then
pushd doxygen
doxygen doxygen.conf
popd
fi
}
src_test() {
# We avoid running the toplevel check target because that will run
# po/'s tests too, and they are broken. Officially, it should work
# with intltool 0.41, but that doesn't look like a stable release.
emake -C src check
}
src_install() {
emake -j1 DESTDIR="${D}" install
# Drop the script entirely if X is disabled
use X || rm "${ED}"/usr/bin/start-pulseaudio-x11
if use system-wide; then
newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
use_define() {
local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}
use "$1" && echo "-D$define" || echo "-U$define"
}
unifdef $(use_define avahi) \
$(use_define alsa) \
$(use_define bluetooth) \
$(use_define udev) \
"${FILESDIR}/pulseaudio.init.d-5" \
> "${T}/pulseaudio"
doinitd "${T}/pulseaudio"
fi
use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${ED}/etc/pulse/default.pa"
dodoc README todo
if use doc; then
pushd doxygen/html
dohtml *
popd
fi
# Create the state directory
use prefix || diropts -o pulse -g pulse -m0755
keepdir /var/run/pulse
find "${D}" -name '*.la' -delete
}
pkg_postinst() {
if use system-wide; then
elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
elog "This support is enabled by starting the pulseaudio init.d ."
elog "To be able to access that you need to be in the group pulse-access."
elog "If you choose to use this feature, please make sure that you"
elog "really want to run PulseAudio this way:"
elog " http://pulseaudio.org/wiki/WhatIsWrongWithSystemMode"
elog "For more information about system-wide support, please refer to:"
elog " http://pulseaudio.org/wiki/SystemWideInstance"
if use gnome ; then
elog
elog "By enabling gnome USE flag, you enabled gconf support. Please note"
elog "that you might need to remove the gnome USE flag or disable the"
elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
elog "with a system-wide instance."
fi
elog
elog "To use the ESounD wrapper while using a system-wide daemon, you also"
elog "need to enable auth-anonymous for the esound-unix module, or to copy"
elog "/var/run/pulse/.esd_auth into each home directory."
elog
fi
if use bluetooth; then
elog
elog "The BlueTooth proximity module is not enabled in the default"
elog "configuration file. If you do enable it, you'll have to have"
elog "your BlueTooth controller enabled and inserted at bootup or"
elog "PulseAudio will refuse to start."
elog
elog "Please note that the BlueTooth proximity module seems itself"
elog "still experimental, so please report to upstream if you have"
elog "problems with it."
fi
if use alsa; then
local pkg="media-plugins/alsa-plugins"
if has_version ${pkg} && ! has_version "${pkg}[pulseaudio]"; then
elog
elog "You have alsa support enabled so you probably want to install"
elog "${pkg} with pulseaudio support to have"
elog "alsa using applications route their sound through pulseaudio"
fi
fi
eselect esd update --if-unset
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-07-09 20:29 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-07-09 20:28 [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-9999.ebuild ChangeLog pulseaudio-0.9.23-r1.ebuild pulseaudio-0.9.23.ebuild Arun Raghavan (ford_prefect)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox