[gentoo-commits] gentoo-x86 commit in dev-libs/rasqal: ChangeLog rasqal-0.9.26.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/rasqal: ChangeLog rasqal-0.9.26.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/07/09 08:21:02

  Modified:             ChangeLog
  Added:                rasqal-0.9.26.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.54                 dev-libs/rasqal/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/ChangeLog?r1=1.53&r2=1.54

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog	5 Feb 2011 08:10:35 -0000	1.53
+++ ChangeLog	9 Jul 2011 08:21:02 -0000	1.54
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/rasqal
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v 1.53 2011/02/05 08:10:35 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v 1.54 2011/07/09 08:21:02 ssuominen Exp $
+
+*rasqal-0.9.26 (09 Jul 2011)
+
+  09 Jul 2011; Samuli Suominen <ssuominen@gentoo.org> +rasqal-0.9.26.ebuild:
+  Version bump.
 
   03 Feb 2011; Kacper Kowalik <xarthisius@gentoo.org> rasqal-0.9.24.ebuild:
   Add ~ppc/~ppc64 wrt #341149



1.1                  dev-libs/rasqal/rasqal-0.9.26.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/rasqal-0.9.26.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/rasqal-0.9.26.ebuild?rev=1.1&content-type=text/plain

Index: rasqal-0.9.26.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/rasqal-0.9.26.ebuild,v 1.1 2011/07/09 08:21:02 ssuominen Exp $

EAPI=4
inherit libtool

DESCRIPTION="library that handles Resource Description Framework (RDF)"
HOMEPAGE="http://librdf.org/rasqal/"
SRC_URI="http://download.librdf.org/source/${P}.tar.gz"

LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos"
IUSE="+crypt gmp +mhash pcre static-libs test xml"

RDEPEND="media-libs/raptor:2
	pcre? ( dev-libs/libpcre )
	xml? ( dev-libs/libxml2 )
	!gmp? ( dev-libs/mpfr )
	gmp? ( dev-libs/gmp )
	crypt? (
		!mhash? ( dev-libs/libgcrypt )
		mhash? ( app-crypt/mhash )
		)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/flex
	test? ( dev-perl/XML-DOM )"

DOCS=( AUTHORS ChangeLog NEWS README )

src_prepare() {
	elibtoolize
}

src_configure() {
	local regex=posix
	local decimal=mpfr
	local digest=internal

	use pcre && regex=pcre
	use gmp && decimal=gmp

	if use crypt; then
		digest=gcrypt
		use mhash && digest=mhash
	fi

	econf \
		$(use_enable static-libs static) \
		$(use_enable pcre) \
		$(use_enable xml xml2) \
		--with-regex-library=${regex} \
		--with-digest-library=${digest} \
		--with-decimal=${decimal} \
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}

src_install() {
	default
	dohtml {NEWS,README,RELEASE}.html
	find "${ED}" -name '*.la' -exec rm -f {} +
}