[gentoo-commits] gentoo-x86 commit in www-apps/drupal: drupal-7.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in www-apps/drupal: drupal-7.4.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    11/07/08 00:14:20

  Modified:             ChangeLog
  Added:                drupal-7.4.ebuild
  Log:
  Version bump (bug #374247).
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.72                 www-apps/drupal/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/drupal/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/drupal/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/drupal/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/drupal/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	27 May 2011 21:24:43 -0000	1.71
+++ ChangeLog	8 Jul 2011 00:14:20 -0000	1.72
@@ -1,6 +1,11 @@
 # ChangeLog for www-apps/drupal
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/drupal/ChangeLog,v 1.71 2011/05/27 21:24:43 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/drupal/ChangeLog,v 1.72 2011/07/08 00:14:20 radhermit Exp $
+
+*drupal-7.4 (08 Jul 2011)
+
+  08 Jul 2011; Tim Harder <radhermit@gentoo.org> +drupal-7.4.ebuild:
+  Version bump (bug #374247).
 
 *drupal-7.2 (27 May 2011)
 



1.1                  www-apps/drupal/drupal-7.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/drupal/drupal-7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/drupal/drupal-7.4.ebuild?rev=1.1&content-type=text/plain

Index: drupal-7.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/drupal/drupal-7.4.ebuild,v 1.1 2011/07/08 00:14:20 radhermit Exp $

EAPI=4

inherit webapp depend.php

MY_PV=${PV:0:3}.0

DESCRIPTION="PHP-based open-source platform and content management system"
HOMEPAGE="http://drupal.org/"
SRC_URI="http://drupal.org/files/projects/${P/_/-}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE="+mysql postgres sqlite"

need_httpd_cgi
need_php_httpd

RDEPEND="dev-lang/php[pdo,postgres?,sqlite?,xml]
	mysql? ( || ( dev-lang/php[mysql] dev-lang/php[mysqli] ) )
	|| ( dev-lang/php[gd] dev-lang/php[gd-external] )"

REQUIRED_USE="|| ( mysql postgres sqlite )"

S="${WORKDIR}/${P/_/-}"

src_install() {
	webapp_src_preinst

	local docs="MAINTAINERS.txt LICENSE.txt INSTALL.txt CHANGELOG.txt INSTALL.mysql.txt INSTALL.pgsql.txt INSTALL.sqlite.txt UPGRADE.txt "
	dodoc ${docs}
	rm -f ${docs} INSTALL COPYRIGHT.txt

	cp sites/default/{default.settings.php,settings.php}
	insinto "${MY_HTDOCSDIR}"
	doins -r .

	dodir "${MY_HTDOCSDIR}"/files
	webapp_serverowned "${MY_HTDOCSDIR}"/files
	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default
	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default/settings.php

	webapp_configfile "${MY_HTDOCSDIR}"/sites/default/settings.php
	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt

	webapp_src_install
}

pkg_postinst() {
	ewarn
	ewarn "SECURITY NOTICE"
	ewarn "If you plan on using SSL on your Drupal site, please consult the postinstall information:"
	ewarn "\t# webapp-config --show-postinst ${PN} ${PV}"
	ewarn
}