[gentoo-commits] gentoo-x86 commit in net-proxy/squidclamav: squidclamav-6.3.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-proxy/squidclamav: squidclamav-6.3.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    11/07/06 22:43:27

  Modified:             ChangeLog
  Added:                squidclamav-6.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.13                 net-proxy/squidclamav/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	12 Dec 2010 15:43:43 -0000	1.12
+++ ChangeLog	6 Jul 2011 22:43:27 -0000	1.13
@@ -1,6 +1,12 @@
 # ChangeLog for net-proxy/squidclamav
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/ChangeLog,v 1.12 2010/12/12 15:43:43 fauli Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/ChangeLog,v 1.13 2011/07/06 22:43:27 flameeyes Exp $
+
+*squidclamav-6.3 (06 Jul 2011)
+
+  06 Jul 2011; Diego E. Pettenò <flameeyes@gentoo.org>
+  +squidclamav-6.3.ebuild:
+  Version bump.
 
   12 Dec 2010; Christian Faulhammer <fauli@gentoo.org>
   squidclamav-6.1.ebuild:



1.1                  net-proxy/squidclamav/squidclamav-6.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/squidclamav-6.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/squidclamav-6.3.ebuild?rev=1.1&content-type=text/plain

Index: squidclamav-6.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/squidclamav-6.3.ebuild,v 1.1 2011/07/06 22:43:27 flameeyes Exp $

EAPI=4

inherit libtool autotools

DESCRIPTION="HTTP Antivirus for Squid based on ClamAv and ICAP"
HOMEPAGE="http://squidclamav.darold.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="net-proxy/c-icap"
DEPEND="${RDEPEND}"

src_prepare() {
	# version 6.3 causes maintainer-mode rebuild from tarball, and
	# contains acinclude.m4 with libtool macros which cause trouble.
	rm acinclude.m4 || die
	eautoreconf
	elibtoolize
}

src_install() {
	emake DESTDIR="${D}" install
	find "${D}" -name '*.la' -delete || die

	# delete its own documentation installed
	rm -r "${D}"/usr/share/${PN} || die

	dodoc README AUTHORS ChangeLog

	# Fix configuration file to adapt to the Gentoo configuration
	sed -i \
		-e '/clamd_local/s:/tmp/clamd:/var/run/clamav/clamd.sock:' \
		"${D}"/etc/squidclamav.conf || die
}

pkg_postinst() {
	elog "Starting from version 6, Squid Clamav is now a module for the c-icap"
	elog "server, which is called from squid, rather than being a redirector"
	elog "directly."
	elog ""
	elog "To enable the service, you should add this to your c-icap.conf file:"
	elog ""
	elog "    Service clamav squidclamav.so"
	elog ""
	elog "And then this to squid.conf (for a local ICAP server):"
	elog ""
	elog "    icap_enable on"
	elog ""
	elog "    # not strictly needed, but useful for special access"
	elog "    icap_send_client_ip on"
	elog "    icap_send_client_username on"
	elog ""
	elog "    icap_service clamav respmod_precache bypass=0 icap://localhost:1344/clamav"
	elog "    adaptation_access clamav allow all"
}