* [gentoo-commits] gentoo-x86 commit in dev-lang/v8: v8-3.4.6.2.ebuild ChangeLog
@ 2011-06-29 11:28 PaweA Hajdan (phajdan.jr)
0 siblings, 0 replies; only message in thread
From: PaweA Hajdan (phajdan.jr) @ 2011-06-29 11:28 UTC (permalink / raw
To: gentoo-commits
phajdan.jr 11/06/29 11:28:42
Modified: ChangeLog
Added: v8-3.4.6.2.ebuild
Log:
Version bump for dev channel release.
(Portage version: 2.1.9.42/cvs/Linux i686)
Revision Changes Path
1.64 dev-lang/v8/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/ChangeLog?r1=1.63&r2=1.64
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog 21 Jun 2011 07:13:09 -0000 1.63
+++ ChangeLog 29 Jun 2011 11:28:42 -0000 1.64
@@ -1,6 +1,11 @@
# ChangeLog for dev-lang/v8
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.63 2011/06/21 07:13:09 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.64 2011/06/29 11:28:42 phajdan.jr Exp $
+
+*v8-3.4.6.2 (29 Jun 2011)
+
+ 29 Jun 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org> +v8-3.4.6.2.ebuild:
+ Version bump for dev channel release.
21 Jun 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org> v8-3.2.10.15.ebuild:
x86 stable wrt security bug #370627
1.1 dev-lang/v8/v8-3.4.6.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/v8-3.4.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/v8/v8-3.4.6.2.ebuild?rev=1.1&content-type=text/plain
Index: v8-3.4.6.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-3.4.6.2.ebuild,v 1.1 2011/06/29 11:28:42 phajdan.jr Exp $
EAPI="2"
inherit eutils flag-o-matic multilib pax-utils scons-utils toolchain-funcs
DESCRIPTION="Google's open source JavaScript engine"
HOMEPAGE="http://code.google.com/p/v8"
SRC_URI="mirror://gentoo/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="readline"
RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
DEPEND="${RDEPEND}"
pkg_setup() {
tc-export AR CC CXX RANLIB
# Make the build respect LDFLAGS.
export LINKFLAGS="${LDFLAGS}"
}
src_prepare() {
# Stop -Werror from breaking the build.
epatch "${FILESDIR}"/${PN}-no-werror-r0.patch
# Respect the user's CFLAGS, including the optimization level.
epatch "${FILESDIR}"/${PN}-no-O3-r0.patch
# Remove a test that is known to fail:
# http://groups.google.com/group/v8-users/browse_thread/thread/b8a3f42b5aa18d06
rm test/mjsunit/debug-script.js || die
# Remove a test that behaves differently depending on FEATURES="userpriv",
# see bug #348558.
rm test/mjsunit/d8-os.js || die
}
src_configure() {
# GCC issues multiple warnings about strict-aliasing issues in v8 code.
append-flags -fno-strict-aliasing
}
src_compile() {
# To make tests work, we compile with sample=shell and visibility=default.
# For more info see http://groups.google.com/group/v8-users/browse_thread/thread/61ca70420e4476bc
# and http://groups.google.com/group/v8-users/browse_thread/thread/165f89728ed6f97d
local myconf="library=shared soname=on sample=shell visibility=default importenv=LINKFLAGS,PATH"
# Use target arch detection logic from bug #354601.
case ${CHOST} in
i?86-*) myarch=x86 ;;
x86_64-*)
if [[ $ABI = "" ]] ; then
myarch=amd64
else
myarch="$ABI"
fi ;;
arm*-*) myarch=arm ;;
*) die "Unrecognized CHOST: ${CHOST}"
esac
if [[ $myarch = amd64 ]] ; then
myconf+=" arch=x64"
elif [[ $myarch = x86 ]] ; then
myconf+=" arch=ia32"
elif [[ $myarch = arm ]] ; then
myconf+=" arch=arm"
else
die "Failed to determine target arch, got '$myarch'."
fi
escons $(use_scons readline console readline dumb) ${myconf} . || die
pax-mark -m obj/test/release/cctest shell d8
}
src_install() {
insinto /usr
doins -r include || die
dobin d8 || die
dolib libv8-${PV}.so || die
dosym libv8-${PV}.so /usr/$(get_libdir)/libv8.so || die
dodoc AUTHORS ChangeLog || die
}
src_test() {
# Make sure we use the libv8.so from our build directory,
# and not the /usr/lib one (it may be missing if we are
# installing for the first time or upgrading), see bug #352374.
LD_LIBRARY_PATH="${S}" tools/test.py --no-build -p dots || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-06-29 11:28 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-06-29 11:28 [gentoo-commits] gentoo-x86 commit in dev-lang/v8: v8-3.4.6.2.ebuild ChangeLog PaweA Hajdan (phajdan.jr)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox