[gentoo-commits] gentoo-x86 commit in app-office/scribus: ChangeLog scribus-1.4.0_rc5.ebuild

[gentoo-commits] gentoo-x86 commit in app-office/scribus: ChangeLog scribus-1.4.0_rc5.ebuild

[Tim Harder (radhermit)]

radhermit    11/06/22 22:11:32

  Modified:             ChangeLog
  Added:                scribus-1.4.0_rc5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha40/cvs/Linux x86_64)

Revision  Changes    Path
1.142                app-office/scribus/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/ChangeLog?rev=1.142&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/ChangeLog?rev=1.142&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/ChangeLog?r1=1.141&r2=1.142

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/scribus/ChangeLog,v
retrieving revision 1.141
retrieving revision 1.142
diff -u -r1.141 -r1.142
--- ChangeLog	3 Jun 2011 22:57:52 -0000	1.141
+++ ChangeLog	22 Jun 2011 22:11:32 -0000	1.142
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/scribus
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/ChangeLog,v 1.141 2011/06/03 22:57:52 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/ChangeLog,v 1.142 2011/06/22 22:11:32 radhermit Exp $
+
+*scribus-1.4.0_rc5 (22 Jun 2011)
+
+  22 Jun 2011; Tim Harder <radhermit@gentoo.org> +scribus-1.4.0_rc5.ebuild:
+  Version bump.
 
 *scribus-1.4.0_rc3 (03 Jun 2011)
 



1.1                  app-office/scribus/scribus-1.4.0_rc5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/scribus-1.4.0_rc5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/scribus-1.4.0_rc5.ebuild?rev=1.1&content-type=text/plain

Index: scribus-1.4.0_rc5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/scribus-1.4.0_rc5.ebuild,v 1.1 2011/06/22 22:11:32 radhermit Exp $

EAPI=2
PYTHON_DEPEND="2:2.6"

inherit cmake-utils fdo-mime multilib python

MY_P="${P/_/.}"
DESCRIPTION="Desktop publishing (DTP) and layout program"
HOMEPAGE="http://www.scribus.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="cairo debug +minimal +pdf spell"

COMMON_DEPEND="
	dev-libs/hyphen
	dev-libs/libxml2
	media-libs/fontconfig
	media-libs/freetype:2
	virtual/jpeg
	media-libs/lcms:0
	media-libs/libpng
	media-libs/tiff
	net-print/cups
	sys-libs/zlib
	x11-libs/qt-gui:4
	x11-libs/qt-core:4
	spell? ( app-text/aspell )
	pdf? ( app-text/podofo )
	cairo? ( x11-libs/cairo[X,svg] )"
RDEPEND="${COMMON_DEPEND}
	app-text/ghostscript-gpl"
DEPEND="${COMMON_DEPEND}
	dev-libs/boost"

DOCS="AUTHORS ChangeLog* LINKS NEWS README TODO TRANSLATION"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	python_set_active_version 2
}

src_configure() {
	mycmakeargs=(
		"-DHAVE_PYTHON=ON"
		"-DPYTHON_INCLUDE_PATH=$(python_get_includedir)"
		"-DPYTHON_LIBRARY=$(python_get_library)"
		"-DWANT_NORPATH=ON"
		"-DWANT_QTARTHUR=ON"
		"-DWANT_QT3SUPPORT=OFF"
		$(cmake-utils_use_has spell ASPELL)
		$(cmake-utils_use_has pdf PODOFO)
		$(cmake-utils_use_want cairo)
		$(cmake-utils_use_want minimal NOHEADERINSTALL)
		)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	# Use one directory for documentation
	mv "${D}"/usr/share/doc/${PN}/* "${D}"/usr/share/doc/${PF}/
	rmdir "${D}"/usr/share/doc/${PN}

	doicon resources/icons/scribus.png
	domenu scribus.desktop
}

pkg_postinst() {
	fdo-mime_mime_database_update
}

pkg_postrm() {
	fdo-mime_mime_database_update
}