[gentoo-commits] gentoo-x86 commit in dev-util/glade: metadata.xml ChangeLog glade-3.10.0-r1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/glade: metadata.xml ChangeLog glade-3.10.0-r1.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/06/19 03:38:30

  Modified:             metadata.xml ChangeLog
  Added:                glade-3.10.0-r1.ebuild
  Log:
  Add new 3.10 version that uses gtk3 and GNOME 3 libraries. Slotted because it removes support for all deprecated widgets. Thanks to tetromino.
  
  (Portage version: 2.2.0_alpha39_p14/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  dev-util/glade/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/glade/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	20 Mar 2009 03:51:23 -0000	1.4
+++ metadata.xml	19 Jun 2011 03:38:30 -0000	1.5
@@ -1,5 +1,9 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>gnome</herd>
+  <herd>gnome</herd>
+  <use>
+    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
+      for introspection</flag>
+  </use>
 </pkgmetadata>



1.132                dev-util/glade/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/ChangeLog?rev=1.132&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/ChangeLog?rev=1.132&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/ChangeLog?r1=1.131&r2=1.132

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v
retrieving revision 1.131
retrieving revision 1.132
diff -u -r1.131 -r1.132
--- ChangeLog	7 Apr 2011 14:19:28 -0000	1.131
+++ ChangeLog	19 Jun 2011 03:38:30 -0000	1.132
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/glade
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.131 2011/04/07 14:19:28 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.132 2011/06/19 03:38:30 nirbheek Exp $
+
+*glade-3.10.0-r1 (19 Jun 2011)
+
+  19 Jun 2011; Nirbheek Chauhan <nirbheek@gentoo.org> +glade-3.10.0-r1.ebuild,
+  metadata.xml:
+  Add new 3.10 version that uses gtk3 and GNOME 3 libraries. Slotted because it
+  removes support for all deprecated widgets. Thanks to tetromino.
 
 *glade-3.8.0 (07 Apr 2011)
 



1.1                  dev-util/glade/glade-3.10.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/glade-3.10.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/glade-3.10.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: glade-3.10.0-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.10.0-r1.ebuild,v 1.1 2011/06/19 03:38:30 nirbheek Exp $

EAPI="2"
GNOME2_LA_PUNT="yes"
GCONF_DEBUG="yes"

inherit gnome2 versionator

DESCRIPTION="GNOME GUI Builder"
HOMEPAGE="http://glade.gnome.org/"

LICENSE="GPL-2"
SLOT="3.10"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc +introspection python"

RDEPEND=">=x11-libs/gtk+-3.0.2:3
	>=dev-libs/libxml2-2.4.0:2
	introspection? ( >=dev-libs/gobject-introspection-0.10.1 )
	python? ( >=dev-python/pygobject-2.27.0 )
"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=dev-util/intltool-0.41.0
	>=dev-util/pkgconfig-0.19
	>=sys-devel/gettext-0.17
	>=app-text/gnome-doc-utils-0.18
	app-text/docbook-xml-dtd:4.1.2
	doc? ( >=dev-util/gtk-doc-1.13 )
"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README TODO"
	G2CONF="${G2CONF}
		--disable-maintainer-mode
		--disable-static
		--enable-libtool-lock
		--disable-scrollkeeper
		$(use_enable introspection)
		$(use_enable python)"
}

src_prepare() {
	# to avoid file collision with glade:3, rename GNOME help module from
	# glade to glade-3.10, and gladeui documentation from gladeui to gladeui-2
	local i
	sed -e 's:DOC_MODULE = glade:DOC_MODULE = glade-3.10:' -i help/Makefile.in \
		|| die "sed of help/Makefile.in failed"
	sed -e 's:/glade.xml:/glade-3.10.xml:g' -i help/*/*.po \
		|| die "sed of help .po files failed"
	for i in help/*/glade.xml ; do
		mv ${i} ${i/glade/glade-3.10} || die "mv ${i} failed"
	done
	sed -e 's:DOC_MODULE = gladeui:DOC_MODULE = gladeui-2:' -i doc/Makefile.in \
		|| die "sed of doc/Makefile.in failed"
	for i in doc/gladeui-* doc/gladeui.* ; do
		mv ${i} ${i/gladeui/gladeui-2} || die "mv ${i} failed"
	done

	gnome2_src_prepare
}

src_install() {
	# modify Name in .desktop file to avoid confusion with other slots
	sed -e 's:^\(Name.*=Glade\):\1 '$(get_version_component_range 1-2): \
		-i data/glade.desktop || die "sed of data/glade.desktop failed"
	gnome2_src_install
}