[gentoo-commits] gentoo-x86 commit in sci-geosciences/gpsd: ChangeLog gpsd-2.96-r1.ebuild gpsd-2.96.ebuild

[gentoo-commits] gentoo-x86 commit in sci-geosciences/gpsd: ChangeLog gpsd-2.96-r1.ebuild gpsd-2.96.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    11/06/17 09:39:38

  Modified:             ChangeLog
  Added:                gpsd-2.96-r1.ebuild
  Removed:              gpsd-2.96.ebuild
  Log:
  Install udev rules. Fixes bug #369125.
  
  (Portage version: 2.2.0_alpha38/cvs/Linux x86_64)

Revision  Changes    Path
1.69                 sci-geosciences/gpsd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?r1=1.68&r2=1.69

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog	4 Jun 2011 08:03:01 -0000	1.68
+++ ChangeLog	17 Jun 2011 09:39:38 -0000	1.69
@@ -1,6 +1,12 @@
 # ChangeLog for sci-geosciences/gpsd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.68 2011/06/04 08:03:01 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.69 2011/06/17 09:39:38 scarabeus Exp $
+
+*gpsd-2.96-r1 (17 Jun 2011)
+
+  17 Jun 2011; Tomáš Chvátal <scarabeus@gentoo.org> -gpsd-2.96.ebuild,
+  +gpsd-2.96-r1.ebuild:
+  Install udev rules. Fixes bug #369125.
 
   04 Jun 2011; Tomáš Chvátal <scarabeus@gentoo.org> gpsd-2.96.ebuild:
   Drop unused variable and double definition.



1.1                  sci-geosciences/gpsd/gpsd-2.96-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.96-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.96-r1.ebuild?rev=1.1&content-type=text/plain

Index: gpsd-2.96-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.96-r1.ebuild,v 1.1 2011/06/17 09:39:38 scarabeus Exp $

EAPI=3

PYTHON_DEPEND="2:2.6"

inherit python base autotools

DESCRIPTION="GPS daemon and library to support USB/serial GPS devices and various GPS/mapping clients."
HOMEPAGE="http://gpsd.berlios.de/"
SRC_URI="mirror://berlios/gpsd/${P}bis.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

GPSD_PROTOCOLS="ashtech aivdm clientdebug earthmate evermore fv18 garmin
	garmintxt gpsclock itrax mtk3301 nmea ntrip navcom oceanserver
	oldstyle oncore rtcm104v2 rtcm104v3 sirf superstar2 timing tsip
	tripmate tnt ubx"
for protocol in ${GPSD_PROTOCOLS}; do
	IUSE_GPSD_PROTOCOLS+=" gpsd_protocols_${protocol}"
done

IUSE="${IUSE_GPSD_PROTOCOLS} dbus ipv6 ntp qt4 udev"

# those harddeps are de-facto automagicall
RDEPEND="
	dev-python/pygtk:2
	sys-libs/ncurses
	virtual/libusb:1
	dbus? (
		sys-apps/dbus
		dev-libs/dbus-glib
	)
	ntp? ( net-misc/ntp )
	qt4? ( x11-libs/qt-gui )"

DEPEND="${RDEPEND}
	app-text/xmlto
	=app-text/docbook-xml-dtd-4.1*"

PATCHES=(
	"${FILESDIR}/2.95-disable-strip.patch"
	"${FILESDIR}/${PV}-fix-ldflags.patch"
	"${FILESDIR}/${PV}-fix-tests.patch"
	"${FILESDIR}/${PV}-pkgconfig.patch"
)

pkg_setup() {
	python_set_active_version 2

	# Run the gpsd daemon as gpsd and group uucp
	enewuser gpsd -1 -1 -1 "uucp"
}

src_prepare() {
	base_src_prepare
	eautoreconf
}

src_configure() {
	local myopts

	# enable specified protocols
	for protocol in ${GPSD_PROTOCOLS}; do
		myopts+=" $(use_enable gpsd_protocols_${protocol} ${protocol})"
	done

	if ! use qt4 ; then
		myopts+=" --disable-libQgpsmm --disable-libgpsmm"
	fi

	# --disable-bluetooth: considered experimental -> disable
	# Hack to make it not generate docs on the fly; xmlto is
	# needed for man pages (xsltproc is only needed for web pages)
	WITH_XMLTO=yes WITH_XSLTPROC=no econf \
		--disable-dependency-tracking \
		--disable-bluetooth \
		--disable-static \
		--enable-gpsd-user=gpsd \
		--enable-gpsd-group=uucp \
		$(use_enable dbus) \
		$(use_enable ipv6) \
		$(use_enable ntp ntpshm) \
		$(use_enable ntp pps) \
		${myopts}
}

src_install() {
	# no it can't be done using emake cause it is non-compliant
	make DESTDIR="${D}" install || die

	if use udev ; then
		insinto /lib/udev/rules.d/
		newins gpsd.rules 25-gpsd.rules
		exeinto /lib/udev/
		doexe gpsd.hotplug{,.wrapper}
	fi

	# needs this header for libQgpsmm
	if use qt4 ; then
		insinto /usr/include
		doins libQgpsmm/libQgpsmm_global.h
	fi

	# no need for .la files here
	find "${D}" -type f -name '*.la' -exec rm -f '{}' +

	newconfd "${FILESDIR}"/gpsd.conf-2 gpsd || die
	newinitd "${FILESDIR}"/gpsd.init-2 gpsd || die
}