[gentoo-commits] gentoo-x86 commit in sci-libs/flann: metadata.xml ChangeLog flann-1.6.10.ebuild

["Sebastien Fabbro (bicatali)" <bicatali@gentoo.org>]

bicatali    11/06/10 20:13:15

  Modified:             metadata.xml ChangeLog
  Added:                flann-1.6.10.ebuild
  Log:
  Version bump. Many fixes. Now install octave, python in proper directories. Does not build useless examples. Make mpi an option. Added longdescription.
  
  (Portage version: 2.1.10/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  sci-libs/flann/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/flann/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	30 Apr 2011 19:14:46 -0000	1.1
+++ metadata.xml	10 Jun 2011 20:13:15 -0000	1.2
@@ -1,4 +1,16 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>sci</herd>
+<longdescription lang='en'>
+  FLANN is a library for performing fast approximate nearest neighbor
+  searches in high dimensional spaces. It contains a collection of
+  algorithms we found to work best for nearest neighbor search and a
+  system for automatically choosing the best algorithm and optimum
+  parameters depending on the dataset.
+  FLANN is written in C++ and contains bindings for the following
+  languages: C, MATLAB and Python.
+</longdescription>
+<use>
+  <flag name='octave'>Add bindings for <pkg>sci-mathematics/octave</pkg></flag> 
+</use>
 </pkgmetadata>



1.5                  sci-libs/flann/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/flann/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	9 May 2011 23:11:58 -0000	1.4
+++ ChangeLog	10 Jun 2011 20:13:15 -0000	1.5
@@ -1,6 +1,13 @@
 # ChangeLog for sci-libs/flann
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/flann/ChangeLog,v 1.4 2011/05/09 23:11:58 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/flann/ChangeLog,v 1.5 2011/06/10 20:13:15 bicatali Exp $
+
+*flann-1.6.10 (10 Jun 2011)
+
+  10 Jun 2011; Sébastien Fabbro <bicatali@gentoo.org> +flann-1.6.10.ebuild,
+  metadata.xml:
+  Version bump. Many fixes. Now install octave, python in proper directories.
+  Does not build useless examples. Make mpi an option. Added longdescription.
 
   09 May 2011; Markos Chandras <hwoarang@gentoo.org> flann-1.6.8.ebuild:
   Stable on amd64 wrt bug #354033



1.1                  sci-libs/flann/flann-1.6.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/flann-1.6.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/flann/flann-1.6.10.ebuild?rev=1.1&content-type=text/plain

Index: flann-1.6.10.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/flann/flann-1.6.10.ebuild,v 1.1 2011/06/10 20:13:15 bicatali Exp $

EAPI=3

PYTHON_DEPEND="python? 2:2.5"

inherit python cmake-utils eutils

DESCRIPTION="Fast approximate nearest neighbor searches library"
HOMEPAGE="http://www.cs.ubc.ca/~mariusm/index.php/FLANN/FLANN"
SRC_URI="http://people.cs.ubc.ca/~mariusm/uploads/FLANN/${P}-src.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc mpi octave python static-libs test"

RDEPEND="sci-libs/hdf5[mpi?]
	mpi? ( dev-libs/boost[mpi] )
	octave? ( sci-mathematics/octave )
	python? ( dev-python/numpy )"
DEPEND="${DEPEND}
	test? ( dev-util/gtest )"

S=${WORKDIR}/${P}-src

src_prepare() {
	# bug #302621
	has_version sci-libs/hdf5[mpi] && export CXX=mpicxx
	# gentoo doc directory respected
	sed -i \
		-e "s:share/doc/flann:share/doc/${PF}:" \
		doc/CMakeLists.txt || die
	# python standard installation directory respected
	sed -i \
		-e "/share/d" \
		-e "/COMMAND/s:install:install --root=${ED} --no-compile:" \
		src/python/CMakeLists.txt || die
	# produce pure octave files
	# octave gentoo installation for .m files respected
	sed -i \
		-e 's/--mex//' \
		-e 's/\.mex/\.oct/' \
		-e '/FILES/s/${MEX_FILE}//' \
		-e 's:share/flann/octave:share/octave/site/m:' \
		-e "/CUSTOM_TARGET/a\INSTALL(FILES \${MEX_FILE} DESTINATION libexec/octave/site/oct/${CHOST})" \
		src/matlab/CMakeLists.txt || die
	# do not compile examples by default
	sed -i \
		-e '/add_subdirectory.*examples/d' \
		CMakeLists.txt || die
	# compile tests only when requested
	use test || sed -i -e '/add_subdirectory.*test/d' CMakeLists.txt
	# avoid automatic installation of pdf
	use doc || sed -i -e '/doc/d' CMakeLists.txt
}

src_configure() {
	local mycmakeargs=(
		"-DBUILD_C_BINDINGS=ON"
		$(cmake-utils_use_build octave MATLAB_BINDINGS)
		$(cmake-utils_use_build python PYTHON_BINDINGS)
		$(cmake-utils_use_use mpi)
	)
	cmake-utils_src_configure
}

src_test() {
	cd "${CMAKE_BUILD_DIR}"
	LD_LIBRARY_PATH="${PWD}/lib" PYTHONPATH="${S}/src/python" \
		make test || die
}

src_install() {
	cmake-utils_src_install
	dodoc README.md
	use static-libs || find "${ED}" -name 'lib*.a' -exec rm -rf '{}' '+'
}