[gentoo-commits] gentoo-x86 commit in net-irc/atheme-services: metadata.xml ChangeLog atheme-services-6.0.8.ebuild

[gentoo-commits] gentoo-x86 commit in net-irc/atheme-services: metadata.xml ChangeLog atheme-services-6.0.8.ebuild

[Nathan Phillip Brink (binki)]

binki       11/06/09 04:38:07

  Modified:             metadata.xml ChangeLog
  Added:                atheme-services-6.0.8.ebuild
  Log:
  Completely reworked for bump to atheme-services-6.0.8, fixing bug #305411.
  
  (Portage version: 2.2.0_alpha37-r1/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  net-irc/atheme-services/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/atheme-services/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	8 Jun 2011 00:45:34 -0000	1.1
+++ metadata.xml	9 Jun 2011 04:38:06 -0000	1.2
@@ -4,5 +4,7 @@
 	<herd>net-irc</herd>
 	<use>
 		<flag name='largenet'>Enable support/tweaks for large networks</flag>
+		<flag name='ldap'>Enable ldap-backed authentication module</flag>
+		<flag name='perl'>Install a perl module which wraps around the services' XML-RPC interface</flag>
 	</use>
 </pkgmetadata>



1.2                  net-irc/atheme-services/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/atheme-services/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	8 Jun 2011 00:45:34 -0000	1.1
+++ ChangeLog	9 Jun 2011 04:38:06 -0000	1.2
@@ -1,6 +1,13 @@
 # ChangeLog for net-irc/atheme-services
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/ChangeLog,v 1.1 2011/06/08 00:45:34 binki Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/ChangeLog,v 1.2 2011/06/09 04:38:06 binki Exp $
+
+*atheme-services-6.0.8 (09 Jun 2011)
+
+  09 Jun 2011; Nathan Phillip Brink <binki@gentoo.org>
+  +atheme-services-6.0.8.ebuild, +files/atheme-services.initd.in,
+  metadata.xml:
+  Completely reworked for bump to atheme-services-6.0.8, fixing bug #305411.
 
 *atheme-services-1.2.1 (08 Jun 2011)
 *atheme-services-0.2.2 (08 Jun 2011)



1.1                  net-irc/atheme-services/atheme-services-6.0.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.8.ebuild?rev=1.1&content-type=text/plain

Index: atheme-services-6.0.8.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.8.ebuild,v 1.1 2011/06/09 04:38:06 binki Exp $

EAPI=4

inherit eutils flag-o-matic perl-module prefix

DESCRIPTION="A portable and secure set of open-source and modular IRC services"
HOMEPAGE="http://atheme.net/"
SRC_URI="http://atheme.net/downloads/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86 ~x86-fbsd"
IUSE="largenet ldap nls +pcre perl profile ssl"

RDEPEND="dev-libs/libmowgli
	ldap? ( net-nds/openldap )
	nls? ( sys-devel/gettext )
	pcre? ( dev-libs/libpcre )
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	# the dependency calculation puts all of the .c files together and
	# overwhelms cc1 with this flag :-(
	filter-flags -combine

	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
}

src_prepare() {
	# fix docdir
	sed -i -e 's/\(^DOCDIR.*=.\)@DOCDIR@/\1@docdir@/' extra.mk.in || die

	# basic logging config directive fix
	sed -i -e '/^logfile/s;var/\(.*\.log\);'"${EPREFIX}"'/var/log/atheme/\1;g' dist/* || die

	# QA against bundled libs
	rm -rf libmowgli || die

	# Get useful information into build.log
	sed -i -e '/^\.SILENT:$/d' buildsys.mk.in || die
}

src_configure() {
	econf \
		--sysconfdir="${EPREFIX}"/etc/${PN} \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		--localstatedir="${EPREFIX}"/var \
		--enable-fhs-paths \
		--enable-contrib \
		$(use_enable largenet large-net) \
		$(use_with ldap) \
		$(use_with nls) \
		$(use_enable profile) \
		$(use_with pcre) \
		$(use_enable ssl)
}

src_install() {
	emake DESTDIR="${D}" install

	insinto /etc/${PN}
	for conf in dist/*.example; do
		# The .cron file isn't meant to live in /etc/${PN}, so only
		# install a .example version.
		[[ ${conf} == *cron* ]] && continue

		newins ${conf} $(basename ${conf} .example)
	done

	fowners -R 0:${PN} /etc/${PN}
	keepdir /var/{lib,log}/atheme
	fowners ${PN}:${PN} /var/{lib,log}/atheme
	fperms -R 640 /etc/${PN}
	fperms 750 /etc/${PN} /var/{lib,log,run}/atheme

	cp "${FILESDIR}"/${PN}.initd.in "${T}"/${PN}.initd || die
	eprefixify "${T}"/${PN}.initd
	newinitd "${T}"/${PN}.initd ${PN}

	# contributed scripts and such:
	insinto /usr/share/doc/${PF}/contrib
	doins contrib/*.{c,pl,php,py,rb}

	if use perl; then
		perlinfo
		insinto "${VENDOR_LIB}"
		doins -r contrib/Atheme{,.pm}
	fi
}