[gentoo-commits] gentoo-x86 commit in sci-geosciences/gmt: metadata.xml ChangeLog gmt-4.5.6.ebuild gmt-4.1.1.ebuild gmt-4.5.0-r2.ebuild

[gentoo-commits] gentoo-x86 commit in sci-geosciences/gmt: metadata.xml ChangeLog gmt-4.5.6.ebuild gmt-4.1.1.ebuild gmt-4.5.0-r2.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    11/06/07 13:03:15

  Modified:             metadata.xml ChangeLog
  Added:                gmt-4.5.6.ebuild
  Removed:              gmt-4.1.1.ebuild gmt-4.5.0-r2.ebuild
  Log:
  Version bump. Drop older.
  
  (Portage version: 2.2.0_alpha38/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sci-geosciences/gmt/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gmt/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	6 Aug 2008 17:51:06 -0000	1.3
+++ metadata.xml	7 Jun 2011 13:03:15 -0000	1.4
@@ -7,5 +7,9 @@
   <flag name='gmthigh'>Add high resolution bathymetry database</flag>
   <flag name='gmtsuppl'>Supplement functions for GMT</flag>
   <flag name='gmttria'>Non GNU triangulation method, more efficient</flag>
+  <flag name='metric'>Use SI (cm) units instead of US (inches) ones</flag>
+  <flag name='mex'>Enable compilation of mex supplement which requires Octave/Matlab</flag>
+  <flag name='octave'>Enable octave support</flag>
+  <flag name='ps'>Enable rendering EPS files</flag>
 </use>
 </pkgmetadata>



1.22                 sci-geosciences/gmt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gmt/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	24 Jun 2010 19:48:35 -0000	1.21
+++ ChangeLog	7 Jun 2011 13:03:15 -0000	1.22
@@ -1,6 +1,13 @@
 # ChangeLog for sci-geosciences/gmt
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gmt/ChangeLog,v 1.21 2010/06/24 19:48:35 jlec Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gmt/ChangeLog,v 1.22 2011/06/07 13:03:15 scarabeus Exp $
+
+*gmt-4.5.6 (07 Jun 2011)
+
+  07 Jun 2011; Tomáš Chvátal <scarabeus@gentoo.org> -gmt-4.1.1.ebuild,
+  -gmt-4.5.0-r2.ebuild, +gmt-4.5.6.ebuild,
+  +files/gmt-4.5.6-respect-ldflags.patch, metadata.xml:
+  Version bump. Drop older.
 
 *gmt-4.5.0-r2 (24 Jun 2010)
 



1.1                  sci-geosciences/gmt/gmt-4.5.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/gmt-4.5.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gmt/gmt-4.5.6.ebuild?rev=1.1&content-type=text/plain

Index: gmt-4.5.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gmt/gmt-4.5.6.ebuild,v 1.1 2011/06/07 13:03:15 scarabeus Exp $

EAPI=4

inherit multilib autotools eutils

GSHHS="GSHHS2.1.1"

DESCRIPTION="Powerful map generator"
HOMEPAGE="http://gmt.soest.hawaii.edu/"
SRC_URI="mirror://gmt/GMT${PV}_src.tar.bz2
	mirror://gmt/GMT${PV}_share.tar.bz2
	mirror://gmt/${GSHHS}_coast.tar.bz2
	mirror://gmt/GMT${PV}_suppl.tar.bz2
	doc? ( mirror://gmt/GMT${PV}_doc.tar.bz2 )
	gmtfull? ( mirror://gmt/${GSHHS}_full.tar.bz2 )
	gmthigh? ( mirror://gmt/${GSHHS}_high.tar.bz2 )
	gmttria? ( mirror://gmt/GMT${PV}_triangle.tar.bz2 )"

LICENSE="GPL-2 gmttria? ( Artistic )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc debug gmtfull gmthigh gmttria +metric mex +netcdf octave ps"

RDEPEND="
	!sci-biology/probcons
	netcdf? ( >=sci-libs/netcdf-4.1 )
	octave? ( sci-mathematics/octave )
"
DEPEND="${RDEPEND}"

RESTRICT="mirror" # for the gmttria

S="${WORKDIR}/GMT${PV}"

# mex can use matlab too which i can't test
REQUIRED_USE="
	mex? ( octave )
	gmthigh? ( !gmtfull ) gmtfull? ( !gmthigh )
"

# hand written make files that are not parallel safe
MAKEOPTS+=" -j1"

src_prepare() {
	mv -f "${WORKDIR}/share/"*  "${S}/share/" || die "Moving sources failed."

	epatch \
		"${FILESDIR}/${PN}-4.5.0-no-strip.patch" \
		"${FILESDIR}/${PN}-4.5.6-respect-ldflags.patch"

	eautoreconf
}

src_configure() {
	# triangle disabled due to non-comercial license
	econf \
		--libdir=/usr/$(get_libdir)/${P} \
		--includedir=/usr/include/${P} \
		--datadir=/usr/share/${P} \
		--docdir=/usr/share/doc/${PF} \
		--disable-update \
		--disable-debug \
		--disable-gdal \
		--disable-matlab \
		--disable-xgrid \
		--disable-triangle \
		--enable-shared \
		$(use_enable netcdf) \
		$(use_enable octave) \
		$(use_enable debug devdebug) \
		$(use_enable !metric US) \
		$(use_enable ps eps) \
		$(use_enable mex)
}

src_install() {
	emake \
		DESTDIR="${ED}" \
		install-gmt install-data install-suppl install-man

	# remove static libs
	find "${ED}/usr/$(get_libdir)" -name '*.a' -exec rm -f {} +

	dodoc README
	use doc && dodoc -r "${S}/share/doc/${PN}/*"

	cat << _EOF_ > "${T}/99gmt"
GMTHOME=${EPREFIX}/usr/share/${P}
GMT_SHAREDIR=${EPREFIX}/usr/share/${P}
_EOF_
	doenvd "${T}/99gmt"
}