[gentoo-commits] gentoo-x86 commit in games-engines/scummvm: ChangeLog scummvm-1.3.0.ebuild

[gentoo-commits] gentoo-x86 commit in games-engines/scummvm: ChangeLog scummvm-1.3.0.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    11/05/31 17:47:22

  Modified:             ChangeLog
  Added:                scummvm-1.3.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.9.42/cvs/Linux i686)

Revision  Changes    Path
1.104                games-engines/scummvm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	13 Feb 2011 12:30:01 -0000	1.103
+++ ChangeLog	31 May 2011 17:47:22 -0000	1.104
@@ -1,6 +1,11 @@
 # ChangeLog for games-engines/scummvm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.103 2011/02/13 12:30:01 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.104 2011/05/31 17:47:22 mr_bones_ Exp $
+
+*scummvm-1.3.0 (31 May 2011)
+
+  31 May 2011; Michael Sterrett <mr_bones_@gentoo.org> +scummvm-1.3.0.ebuild:
+  version bump
 
   13 Feb 2011; Raúl Porcel <armin76@gentoo.org> scummvm-1.2.0-r1.ebuild,
   scummvm-1.2.1.ebuild:



1.1                  games-engines/scummvm/scummvm-1.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm/scummvm-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/scummvm/scummvm-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: scummvm-1.3.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/scummvm-1.3.0.ebuild,v 1.1 2011/05/31 17:47:22 mr_bones_ Exp $

EAPI=2
inherit eutils flag-o-matic games

DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
HOMEPAGE="http://scummvm.sourceforge.net/"
SRC_URI="mirror://sourceforge/scummvm/${P/_/}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="alsa debug flac fluidsynth mp3 ogg vorbis"
RESTRICT="test"  # it only looks like there's a test there #77507

RDEPEND=">=media-libs/libsdl-1.2.2[audio,joystick,video]
	>media-libs/libmpeg2-0.3.1
	sys-libs/zlib
	ogg? ( media-libs/libogg media-libs/libvorbis )
	vorbis? ( media-libs/libogg media-libs/libvorbis )
	alsa? ( media-libs/alsa-lib )
	mp3? ( media-libs/libmad )
	flac? ( media-libs/flac )
	fluidsynth? ( media-sound/fluidsynth )"
DEPEND="${RDEPEND}
	x86? ( dev-lang/nasm )"

S=${WORKDIR}/${P/_/}

src_prepare() {
	# -g isn't needed for nasm here
	sed -i \
		-e '/NASMFLAGS/ s/-g//' \
		configure || die
	sed -i \
		-e '/INSTALL.*doc/d' \
		-e '/INSTALL.*\/pixmaps/d' \
		-e 's/-s //' \
		ports.mk || die
}

src_configure() {
	local myconf

	if use vorbis || use ogg ; then
		myconf="${myconf} --enable-vorbis"
	else
		myconf="${myconf} --disable-vorbis"
	fi

	# bug #137547
	use fluidsynth || myconf="${myconf} --disable-fluidsynth"

	use x86 && append-ldflags -Wl,-z,noexecstack

	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
	# mpeg2 support needs vorbis (bug #79149) so turn it off if -oggvorbis
	./configure \
		--backend=sdl \
		--host=$CHOST \
		--enable-verbose-build \
		--prefix=/usr \
		--bindir="${GAMES_BINDIR}" \
		--datadir="${GAMES_DATADIR}"/${PN} \
		--libdir="${GAMES_LIBDIR}" \
		--enable-zlib \
		$(use_enable debug) \
		$(use_enable alsa) \
		$(use_enable mp3 mad) \
		$(use_enable flac) \
		$(use_enable x86 nasm) \
		${myconf} || die
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS NEWS README TODO
	doicon icons/scummvm.svg
	make_desktop_entry scummvm ScummVM scummvm "Game;AdventureGame"
	prepgamesdirs
}