* [gentoo-commits] gentoo-x86 commit in net-im/emesene: emesene-9999.ebuild emesene-2.11.5.ebuild ChangeLog emesene-2.11.4.ebuild
@ 2011-05-30 17:56 Markos Chandras (hwoarang)
0 siblings, 0 replies; only message in thread
From: Markos Chandras (hwoarang) @ 2011-05-30 17:56 UTC (permalink / raw
To: gentoo-commits
hwoarang 11/05/30 17:56:47
Modified: ChangeLog
Added: emesene-9999.ebuild emesene-2.11.5.ebuild
Removed: emesene-2.11.4.ebuild
Log:
Version bump and initial commit of live ebuild. Add missing || die and minor fix on src_prepare as well
(Portage version: 2.1.9.49/cvs/Linux x86_64)
Revision Changes Path
1.2 net-im/emesene/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/ChangeLog?r1=1.1&r2=1.2
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/emesene/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog 29 May 2011 12:06:54 -0000 1.1
+++ ChangeLog 30 May 2011 17:56:47 -0000 1.2
@@ -1,6 +1,15 @@
# ChangeLog for net-im/emesene
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/ChangeLog,v 1.1 2011/05/29 12:06:54 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/ChangeLog,v 1.2 2011/05/30 17:56:47 hwoarang Exp $
+
+*emesene-9999 (30 May 2011)
+*emesene-2.11.5 (30 May 2011)
+
+ 30 May 2011; Markos Chandras <hwoarang@gentoo.org> -emesene-2.11.4.ebuild,
+ +emesene-2.11.5.ebuild, +files/emesene-2.11.5-svgfix.patch,
+ +emesene-9999.ebuild:
+ Version bump and initial commit of live ebuild. Add missing || die and minor
+ fix on src_prepare as well
*emesene-2.11.4 (29 May 2011)
*emesene-1.6.3 (29 May 2011)
1.1 net-im/emesene/emesene-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-9999.ebuild?rev=1.1&content-type=text/plain
Index: emesene-9999.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/emesene-9999.ebuild,v 1.1 2011/05/30 17:56:47 hwoarang Exp $
EAPI="3"
PYTHON_DEPEND="2"
PYTHON_USE_WITH="sqlite"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
EGIT_REPO_URI="git://github.com/emesene/emesene.git"
inherit distutils eutils git
DESCRIPTION="Platform independent MSN Messenger client written in Python+GTK"
HOMEPAGE="http://www.emesene.org"
LICENSE="|| ( GPL-2 GPL-3 LGPL-3 )"
SLOT="2"
KEYWORDS=""
IUSE="jabber"
RDEPEND="dev-python/pygtk:2
dev-python/papyon
dev-python/notify-python
jabber? ( dev-python/xmpppy )"
src_prepare() {
# do not import dummy session
sed -i -e "/import e3dummy/d" ${PN}/${PN}.py || die
# fix .desktop icon to look for emesene-2 executable
sed -i -e "s:${PN}:${PN}-2:g" \
${PN}/data/share/applications/${PN}.desktop || die
# Use a better meny entry
sed -i -e "/^Name/s:${PN}-2:Emesene v2:" \
${PN}/data/share/applications/${PN}.desktop || die
distutils_src_prepare
}
src_install() {
mysymlink(){
dosym $(python_get_sitedir)/${PN}/${PN} /usr/bin/${PN}-2 || die
}
distutils_src_install
# fix names
mv "${D}"/usr/share/applications/${PN}.desktop \
"${D}"/usr/share/applications/${PN}-2.desktop
mv "${D}"/usr/share/pixmaps/${PN}.png \
"${D}"/usr/share/pixmaps/${PN}-2.png
mv "${D}"/usr/share/pixmaps/${PN}.xpm \
"${D}"/usr/share/pixmaps/${PN}-2.xpm
mv "${D}"/usr/share/man/man1/${PN}.1 \
"${D}"/usr/share/man/man1/${PN}-2.1
python_execute_function -q mysymlink
}
pkg_postinst() {
ewarn
ewarn "${PN}-2 is on early stages of development."
ewarn "Please do not file bugs on Gentoo buzilla"
ewarn "unless you have problems with the ebuild."
ewarn "Use the upstram bug tracker to report bugs:"
ewarn
ewarn "https://github.com/emesene/emesene/issues"
}
1.1 net-im/emesene/emesene-2.11.5.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-2.11.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/emesene/emesene-2.11.5.ebuild?rev=1.1&content-type=text/plain
Index: emesene-2.11.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/emesene/emesene-2.11.5.ebuild,v 1.1 2011/05/30 17:56:47 hwoarang Exp $
EAPI="3"
PYTHON_DEPEND="2"
PYTHON_USE_WITH="sqlite"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
EMESENE_COMMIT="5cf77b3"
GIT_COMMIT="5c6aad"
MY_P="${PN}-${PN}-v${PV}-0-gb${GIT_COMMIT}"
inherit distutils eutils
DESCRIPTION="Platform independent MSN Messenger client written in Python+GTK"
HOMEPAGE="http://www.emesene.org"
SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${MY_P}.tar.gz"
LICENSE="|| ( GPL-2 GPL-3 LGPL-3 )"
SLOT="2"
KEYWORDS="~amd64 ~x86"
IUSE="jabber"
RDEPEND="dev-python/pygtk:2
dev-python/papyon
dev-python/notify-python
jabber? ( dev-python/xmpppy )"
S="${WORKDIR}/${PN}-${PN}-${EMESENE_COMMIT}"
src_prepare() {
# do not import dummy session
sed -i -e "/import e3dummy/d" ${PN}/${PN}.py || die
# fix .desktop icon to look for emesene-2 executable
sed -i -e "s:${PN}:${PN}-2:g" \
${PN}/data/share/applications/${PN}.desktop || die
# Use a better meny entry
sed -i -e "/^Name/s:${PN}-2:Emesene v2:" \
${PN}/data/share/applications/${PN}.desktop || die
epatch "${FILESDIR}"/${P}-svgfix.patch
distutils_src_prepare
}
src_install() {
mysymlink(){
dosym $(python_get_sitedir)/${PN}/${PN} /usr/bin/${PN}-2 || die
}
distutils_src_install
# fix names
mv "${D}"/usr/share/applications/${PN}.desktop \
"${D}"/usr/share/applications/${PN}-2.desktop
mv "${D}"/usr/share/pixmaps/${PN}.png \
"${D}"/usr/share/pixmaps/${PN}-2.png
mv "${D}"/usr/share/pixmaps/${PN}.xpm \
"${D}"/usr/share/pixmaps/${PN}-2.xpm
mv "${D}"/usr/share/man/man1/${PN}.1 \
"${D}"/usr/share/man/man1/${PN}-2.1
python_execute_function -q mysymlink
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-05-30 17:56 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-05-30 17:56 [gentoo-commits] gentoo-x86 commit in net-im/emesene: emesene-9999.ebuild emesene-2.11.5.ebuild ChangeLog emesene-2.11.4.ebuild Markos Chandras (hwoarang)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox