* [gentoo-commits] gentoo-x86 commit in www-client/chromium: chromium-11.0.696.71.ebuild ChangeLog
@ 2011-05-25 6:04 PaweA Hajdan (phajdan.jr)
0 siblings, 0 replies; 3+ messages in thread
From: PaweA Hajdan (phajdan.jr) @ 2011-05-25 6:04 UTC (permalink / raw
To: gentoo-commits
phajdan.jr 11/05/25 06:04:30
Modified: ChangeLog
Added: chromium-11.0.696.71.ebuild
Log:
Version bump for stable channel release.
(Portage version: 2.1.9.42/cvs/Linux i686)
Revision Changes Path
1.368 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.368&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.368&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.367&r2=1.368
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.367
retrieving revision 1.368
diff -u -r1.367 -r1.368
--- ChangeLog 25 May 2011 04:46:50 -0000 1.367
+++ ChangeLog 25 May 2011 06:04:30 -0000 1.368
@@ -1,6 +1,12 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.367 2011/05/25 04:46:50 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.368 2011/05/25 06:04:30 phajdan.jr Exp $
+
+*chromium-11.0.696.71 (25 May 2011)
+
+ 25 May 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+ +chromium-11.0.696.71.ebuild:
+ Version bump for stable channel release.
25 May 2011; Markus Meier <maekke@gentoo.org> chromium-12.0.742.53.ebuild,
chromium-12.0.742.60.ebuild, chromium-13.0.767.1.ebuild,
1.1 www-client/chromium/chromium-11.0.696.71.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?rev=1.1&content-type=text/plain
Index: chromium-11.0.696.71.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v 1.1 2011/05/25 06:04:30 phajdan.jr Exp $
EAPI="3"
PYTHON_DEPEND="2:2.6"
inherit eutils fdo-mime flag-o-matic gnome2-utils linux-info multilib \
pax-utils portability python toolchain-funcs versionator virtualx
DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/official/${P}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="cups gnome gnome-keyring"
RDEPEND="app-arch/bzip2
dev-libs/dbus-glib
>=dev-libs/icu-4.4.1
>=dev-libs/libevent-1.4.13
dev-libs/libxml2[icu]
dev-libs/libxslt
>=dev-libs/nss-3.12.3
gnome? ( >=gnome-base/gconf-2.24.0 )
gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
>=media-libs/alsa-lib-1.0.19
media-libs/flac
virtual/jpeg
media-libs/libpng
>=media-libs/libvpx-0.9.5
media-libs/speex
>=media-video/ffmpeg-0.6_p25767[threads]
cups? ( >=net-print/cups-1.3.11 )
sys-libs/pam
sys-libs/zlib
x11-libs/gtk+:2
x11-libs/libXScrnSaver
x11-libs/libXtst"
DEPEND="${RDEPEND}
dev-lang/perl
>=dev-util/gperf-3.0.3
>=dev-util/pkgconfig-0.23
sys-devel/flex
>=sys-devel/make-3.81-r2"
RDEPEND+="
x11-misc/xdg-utils
virtual/ttf-fonts"
gyp_use() {
if [[ $# -lt 2 ]]; then
echo "!!! usage: gyp_use <USEFLAG> <GYPFLAG>" >&2
return 1
fi
if use "$1"; then echo "-D$2=1"; else echo "-D$2=0"; fi
}
egyp() {
set -- build/gyp_chromium --depth=. "${@}"
echo "${@}" >&2
"${@}"
}
pkg_setup() {
CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
# Make sure the build system will use the right tools, bug #340795.
tc-export AR CC CXX RANLIB
# Make sure the build system will use the right python, bug #344367.
python_set_active_version 2
python_pkg_setup
# Prevent user problems like bug #299777.
if ! grep -q /dev/shm <<< $(get_mounts); then
ewarn "You don't have tmpfs mounted at /dev/shm."
ewarn "${PN} may fail to start in that configuration."
ewarn "Please uncomment the /dev/shm entry in /etc/fstab,"
ewarn "and run 'mount /dev/shm'."
fi
if [ `stat -c %a /dev/shm` -ne 1777 ]; then
ewarn "/dev/shm does not have correct permissions."
ewarn "${PN} may fail to start in that configuration."
ewarn "Please run 'chmod 1777 /dev/shm'."
fi
# Prevent user problems like bug #348235.
eshopts_push -s extglob
if is-flagq '-g?(gdb)?([1-9])'; then
ewarn "You have enabled debug info (probably have -g or -ggdb in your \$C{,XX}FLAGS)."
ewarn "You may experience really long compilation times and/or increased memory usage."
ewarn "If compilation fails, please try removing -g{,gdb} before reporting a bug."
fi
eshopts_pop
# Warn if the kernel doesn't support features useful for sandboxing,
# bug #363907.
CONFIG_CHECK="~PID_NS ~NET_NS"
PID_NS_WARNING="PID (process id) namespaces are needed for sandboxing."
NET_NS_WARNING="Network namespaces are needed for sandboxing."
check_extra_config
}
src_prepare() {
# Make sure we don't use bundled libvpx headers.
epatch "${FILESDIR}/${PN}-system-vpx-r3.patch"
# Backport FFmpeg compatibility patch, bug #355405.
epatch "${FILESDIR}/${PN}-ffmpeg-build-r0.patch"
# Remove most bundled libraries. Some are still needed.
find third_party -type f \! -iname '*.gyp*' \
\! -path 'third_party/WebKit/*' \
\! -path 'third_party/angle/*' \
\! -path 'third_party/cacheinvalidation/*' \
\! -path 'third_party/cld/*' \
\! -path 'third_party/expat/*' \
\! -path 'third_party/ffmpeg/*' \
\! -path 'third_party/flac/flac.h' \
\! -path 'third_party/gpsd/*' \
\! -path 'third_party/harfbuzz/*' \
\! -path 'third_party/hunspell/*' \
\! -path 'third_party/iccjpeg/*' \
\! -path 'third_party/launchpad_translations/*' \
\! -path 'third_party/libjingle/*' \
\! -path 'third_party/libsrtp/*' \
\! -path 'third_party/libvpx/libvpx.h' \
\! -path 'third_party/libwebp/*' \
\! -path 'third_party/mesa/*' \
\! -path 'third_party/modp_b64/*' \
\! -path 'third_party/npapi/*' \
\! -path 'third_party/openmax/*' \
\! -path 'third_party/ots/*' \
\! -path 'third_party/protobuf/*' \
\! -path 'third_party/skia/*' \
\! -path 'third_party/speex/speex.h' \
\! -path 'third_party/sqlite/*' \
\! -path 'third_party/tcmalloc/*' \
\! -path 'third_party/undoview/*' \
\! -path 'third_party/zlib/contrib/minizip/*' \
-delete || die
# Make sure the build system will use the right python, bug #344367.
# Only convert directories that need it, to save time.
python_convert_shebangs -q -r 2 build tools
}
src_configure() {
local myconf=""
# Never tell the build system to "enable" SSE2, it has a few unexpected
# additions, bug #336871.
myconf+=" -Ddisable_sse2=1"
# Use system-provided libraries.
# TODO: use_system_hunspell (upstream changes needed).
# TODO: use_system_ssl (http://crbug.com/58087).
# TODO: use_system_sqlite (http://crbug.com/22208).
myconf+="
-Duse_system_bzip2=1
-Duse_system_flac=1
-Duse_system_ffmpeg=1
-Duse_system_icu=1
-Duse_system_libevent=1
-Duse_system_libjpeg=1
-Duse_system_libpng=1
-Duse_system_libxml=1
-Duse_system_speex=1
-Duse_system_vpx=1
-Duse_system_xdg_utils=1
-Duse_system_zlib=1"
# Optional dependencies.
myconf+="
$(gyp_use cups use_cups)
$(gyp_use gnome use_gconf)
$(gyp_use gnome-keyring use_gnome_keyring)
$(gyp_use gnome-keyring linux_link_gnome_keyring)"
# Enable sandbox.
myconf+="
-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
if host-is-pax; then
# Prevent the build from failing (bug #301880). The performance
# difference is very small.
myconf+=" -Dv8_use_snapshot=0"
fi
# Our system ffmpeg should support more codecs than the bundled one
# for Chromium.
myconf+=" -Dproprietary_codecs=1"
# Use target arch detection logic from bug #296917.
local myarch="$ABI"
[[ $myarch = "" ]] && myarch="$ARCH"
if [[ $myarch = amd64 ]] ; then
myconf+=" -Dtarget_arch=x64"
elif [[ $myarch = x86 ]] ; then
myconf+=" -Dtarget_arch=ia32"
elif [[ $myarch = arm ]] ; then
# TODO: check this again after
# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
append-flags -fno-tree-sink
myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
else
die "Failed to determine target arch, got '$myarch'."
fi
# Make sure that -Werror doesn't get added to CFLAGS by the build system.
# Depending on GCC version the warnings are different and we don't want
# the build to fail because of that.
myconf+=" -Dwerror="
# Avoid a build error with -Os, bug #352457.
replace-flags "-Os" "-O2"
egyp ${myconf} || die
}
src_compile() {
emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
pax-mark m out/Release/chrome
if use test; then
emake base_unittests BUILDTYPE=Release V=1 || die
pax-mark m out/Release/base_unittests
fi
}
src_test() {
# For more info see bug #350349.
local mylocale='en_US.utf8'
if ! locale -a | grep -q "$mylocale"; then
eerror "${PN} requires ${mylocale} locale for tests"
eerror "Please read the following guides for more information:"
eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
eerror " http://www.gentoo.org/doc/en/utf-8.xml"
die "locale ${mylocale} is not supported"
fi
# For more info see bug #350347.
LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/base_unittests virtualmake \
'--gtest_filter=-ICUStringConversionsTest.*'
}
src_install() {
exeinto "${CHROMIUM_HOME}"
doexe out/Release/chrome
doexe out/Release/chrome_sandbox || die
fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
newexe "${FILESDIR}"/chromium-launcher-r1.sh chromium-launcher.sh || die
# It is important that we name the target "chromium-browser",
# xdg-utils expect it; bug #355517.
dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser || die
# keep the old symlink around for consistency
dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
insinto "${CHROMIUM_HOME}"
doins out/Release/chrome.pak || die
doins out/Release/resources.pak || die
doins -r out/Release/locales || die
doins -r out/Release/resources || die
newman out/Release/chrome.1 chromium.1 || die
newman out/Release/chrome.1 chromium-browser.1 || die
# Chromium looks for these in its folder
# See media_posix.cc and base_paths_linux.cc
dosym /usr/$(get_libdir)/libavcodec.so.52 "${CHROMIUM_HOME}" || die
dosym /usr/$(get_libdir)/libavformat.so.52 "${CHROMIUM_HOME}" || die
dosym /usr/$(get_libdir)/libavutil.so.50 "${CHROMIUM_HOME}" || die
# Install icons and desktop entry.
for SIZE in 16 22 24 32 48 64 128 256 ; do
insinto /usr/share/icons/hicolor/${SIZE}x${SIZE}/apps
newins chrome/app/theme/chromium/product_logo_${SIZE}.png \
chromium-browser.png || die
done
local mime_types="text/html;text/xml;application/xhtml+xml;"
mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
make_desktop_entry chromium-browser "Chromium" chromium-browser \
"Network;WebBrowser" "MimeType=${mime_types}"
sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
# Install GNOME default application entry (bug #303100).
if use gnome; then
dodir /usr/share/gnome-control-center/default-apps || die
insinto /usr/share/gnome-control-center/default-apps
doins "${FILESDIR}"/chromium-browser.xml || die
fi
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
# For more info see bug #292201, bug #352263, bug #361859.
elog
elog "Depending on your desktop environment, you may need"
elog "to install additional packages to get icons on the Downloads page."
elog
elog "For KDE, the required package is kde-base/oxygen-icons."
elog
elog "For other desktop environments, try one of the following:"
elog " - x11-themes/gnome-icon-theme"
elog " - x11-themes/tango-icon-theme"
# For more info see bug #359153.
elog
elog "Some web pages may require additional fonts to display properly."
elog "Try installing some of the following packages if some characters"
elog "are not displayed properly:"
elog " - media-fonts/arphicfonts"
elog " - media-fonts/bitstream-cyberbit"
elog " - media-fonts/droid"
elog " - media-fonts/ipamonafont"
elog " - media-fonts/ja-ipafonts"
elog " - media-fonts/takao-fonts"
elog " - media-fonts/wqy-microhei"
elog " - media-fonts/wqy-zenhei"
}
pkg_postrm() {
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in www-client/chromium: chromium-11.0.696.71.ebuild ChangeLog
@ 2011-05-25 19:01 Thomas Kahle (tomka)
0 siblings, 0 replies; 3+ messages in thread
From: Thomas Kahle (tomka) @ 2011-05-25 19:01 UTC (permalink / raw
To: gentoo-commits
tomka 11/05/25 19:01:23
Modified: chromium-11.0.696.71.ebuild ChangeLog
Log:
x86 stable per bug 368649
(Portage version: 2.1.9.49/cvs/Linux i686)
Revision Changes Path
1.2 www-client/chromium/chromium-11.0.696.71.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?r1=1.1&r2=1.2
Index: chromium-11.0.696.71.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- chromium-11.0.696.71.ebuild 25 May 2011 06:04:30 -0000 1.1
+++ chromium-11.0.696.71.ebuild 25 May 2011 19:01:23 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v 1.1 2011/05/25 06:04:30 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v 1.2 2011/05/25 19:01:23 tomka Exp $
EAPI="3"
PYTHON_DEPEND="2:2.6"
@@ -14,7 +14,7 @@
LICENSE="BSD"
SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="~amd64 ~arm x86"
IUSE="cups gnome gnome-keyring"
RDEPEND="app-arch/bzip2
1.369 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.369&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.369&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.368&r2=1.369
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.368
retrieving revision 1.369
diff -u -r1.368 -r1.369
--- ChangeLog 25 May 2011 06:04:30 -0000 1.368
+++ ChangeLog 25 May 2011 19:01:23 -0000 1.369
@@ -1,6 +1,9 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.368 2011/05/25 06:04:30 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.369 2011/05/25 19:01:23 tomka Exp $
+
+ 25 May 2011; Thomas Kahle <tomka@gentoo.org> chromium-11.0.696.71.ebuild:
+ x86 stable per bug 368649
*chromium-11.0.696.71 (25 May 2011)
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in www-client/chromium: chromium-11.0.696.71.ebuild ChangeLog
@ 2011-05-27 10:00 Markos Chandras (hwoarang)
0 siblings, 0 replies; 3+ messages in thread
From: Markos Chandras (hwoarang) @ 2011-05-27 10:00 UTC (permalink / raw
To: gentoo-commits
hwoarang 11/05/27 10:00:13
Modified: chromium-11.0.696.71.ebuild ChangeLog
Log:
Stable on amd64 wrt bug #
(Portage version: 2.1.9.49/cvs/Linux x86_64)
Revision Changes Path
1.3 www-client/chromium/chromium-11.0.696.71.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild?r1=1.2&r2=1.3
Index: chromium-11.0.696.71.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- chromium-11.0.696.71.ebuild 25 May 2011 19:01:23 -0000 1.2
+++ chromium-11.0.696.71.ebuild 27 May 2011 10:00:13 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v 1.2 2011/05/25 19:01:23 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-11.0.696.71.ebuild,v 1.3 2011/05/27 10:00:13 hwoarang Exp $
EAPI="3"
PYTHON_DEPEND="2:2.6"
@@ -14,7 +14,7 @@
LICENSE="BSD"
SLOT="0"
-KEYWORDS="~amd64 ~arm x86"
+KEYWORDS="amd64 ~arm x86"
IUSE="cups gnome gnome-keyring"
RDEPEND="app-arch/bzip2
1.372 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.372&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.372&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.371&r2=1.372
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.371
retrieving revision 1.372
diff -u -r1.371 -r1.372
--- ChangeLog 26 May 2011 11:09:13 -0000 1.371
+++ ChangeLog 27 May 2011 10:00:13 -0000 1.372
@@ -1,6 +1,10 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.371 2011/05/26 11:09:13 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.372 2011/05/27 10:00:13 hwoarang Exp $
+
+ 27 May 2011; Markos Chandras <hwoarang@gentoo.org>
+ chromium-11.0.696.71.ebuild:
+ Stable on amd64 wrt bug #
*chromium-13.0.772.0-r1 (26 May 2011)
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2011-05-27 10:00 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-05-27 10:00 [gentoo-commits] gentoo-x86 commit in www-client/chromium: chromium-11.0.696.71.ebuild ChangeLog Markos Chandras (hwoarang)
-- strict thread matches above, loose matches on Subject: below --
2011-05-25 19:01 Thomas Kahle (tomka)
2011-05-25 6:04 PaweA Hajdan (phajdan.jr)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox