[gentoo-commits] gentoo-x86 commit in app-text/hunspell: ChangeLog hunspell-1.3.2.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/hunspell: ChangeLog hunspell-1.3.2.ebuild

[Peter Volkov (pva)]

pva         11/05/24 17:42:43

  Modified:             ChangeLog
  Added:                hunspell-1.3.2.ebuild
  Log:
  Version bump, bug 357833, thank teidakankan AT gmail.com and Atman Sense for report
  
  (Portage version: 2.1.9.49/cvs/Linux x86_64)

Revision  Changes    Path
1.82                 app-text/hunspell/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/hunspell/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/hunspell/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/hunspell/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/hunspell/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	24 Nov 2010 08:42:52 -0000	1.81
+++ ChangeLog	24 May 2011 17:42:43 -0000	1.82
@@ -1,6 +1,13 @@
 # ChangeLog for app-text/hunspell
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/hunspell/ChangeLog,v 1.81 2010/11/24 08:42:52 grobian Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/hunspell/ChangeLog,v 1.82 2011/05/24 17:42:43 pva Exp $
+
+*hunspell-1.3.2 (24 May 2011)
+
+  24 May 2011; Peter Volkov <pva@gentoo.org> +hunspell-1.3.2.ebuild,
+  +files/hunspell-1.3-renameexes.patch:
+  Version bump, bug 357833, thank teidakankan AT gmail.com and Atman Sense for
+  report
 
   24 Nov 2010; Fabian Groffen <grobian@gentoo.org>
   hunspell-1.2.12-r1.ebuild:



1.1                  app-text/hunspell/hunspell-1.3.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/hunspell/hunspell-1.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/hunspell/hunspell-1.3.2.ebuild?rev=1.1&content-type=text/plain

Index: hunspell-1.3.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/hunspell/hunspell-1.3.2.ebuild,v 1.1 2011/05/24 17:42:43 pva Exp $

EAPI="4"
inherit eutils multilib autotools flag-o-matic

MY_P=${PN}-${PV/_beta/b}

DESCRIPTION="Hunspell spell checker - an improved replacement for myspell in OOo."
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
HOMEPAGE="http://hunspell.sourceforge.net/"

SLOT="0"
LICENSE="MPL-1.1 GPL-2 LGPL-2.1"
IUSE="ncurses nls readline"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"

DEPEND="readline? ( sys-libs/readline )
	ncurses? ( sys-libs/ncurses )
	sys-devel/gettext"
RDEPEND="${DEPEND}"

#TODO: "ia" "mi" - check what they are and add appropriate desc...
def="app-dicts/myspell-en"
for l in \
"af" "bg" "ca" "cs" "cy" "da" "de" "el" "en" "eo" "es" "et" "fo" "fr" "ga" \
"gl" "he" "hr" "hu" "id" "it" "ku" "lt" "lv" "mk" "ms" "nb" "nl" \
"nn" "pl" "pt" "ro" "ru" "sk" "sl" "sv" "sw" "tn" "uk" "zu" \
; do
	dep="linguas_${l}? ( app-dicts/myspell-${l/pt_BR/pt-br} )"
	[[ ${l} = "de" ]] &&
		dep="linguas_de? ( || ( app-dicts/myspell-de app-dicts/myspell-de-alt ) )"
	[[ -z ${PDEPEND} ]] &&
		PDEPEND="${dep}" ||
		PDEPEND="${PDEPEND}
${dep}"
	def="!linguas_${l}? ( ${def} )"
	IUSE="${IUSE} linguas_${l}"
done
PDEPEND="${PDEPEND}
${def}"

S=${WORKDIR}/${MY_P}

src_prepare() {
	# Upstream package creates some executables which names are too generic
	# to be placed in /usr/bin - this patch prefixes them with 'hunspell-'.
	# It modifies a Makefile.am file, hence eautoreconf.
	epatch "${FILESDIR}"/${PN}-1.3-renameexes.patch
	eautoreconf
}

src_configure() {
	# missing somehow, and I am too lazy to fix it properly
	[[ ${CHOST} == *-darwin* ]] && append-libs -liconv

	# I wanted to put the include files in /usr/include/hunspell
	# but this means the openoffice build won't find them.
	econf \
		$(use_enable nls) \
		$(use_with ncurses ui) \
		$(use_with readline readline)
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog NEWS README THANKS TODO license.hunspell
	# hunspell is derived from myspell
	dodoc AUTHORS.myspell README.myspell license.myspell
}

pkg_postinst() {
	elog "To use this package you will also need a dictionary."
	elog "Hunspell uses myspell format dictionaries; find them"
	elog "in the app-dicts category as myspell-<LANG>."
}