[gentoo-commits] gentoo-x86 commit in games-board/xboard: ChangeLog xboard-4.5.2a.ebuild

[gentoo-commits] gentoo-x86 commit in games-board/xboard: ChangeLog xboard-4.5.2a.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    11/05/22 21:35:02

  Modified:             ChangeLog
  Added:                xboard-4.5.2a.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.9.42/cvs/Linux i686)

Revision  Changes    Path
1.40                 games-board/xboard/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/xboard/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/xboard/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/xboard/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-board/xboard/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	2 May 2011 15:27:21 -0000	1.39
+++ ChangeLog	22 May 2011 21:35:01 -0000	1.40
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/xboard
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/xboard/ChangeLog,v 1.39 2011/05/02 15:27:21 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/xboard/ChangeLog,v 1.40 2011/05/22 21:35:01 mr_bones_ Exp $
+
+*xboard-4.5.2a (22 May 2011)
+
+  22 May 2011; Michael Sterrett <mr_bones_@gentoo.org> +xboard-4.5.2a.ebuild,
+  +files/xboard-4.5.2a-gentoo.patch:
+  version bump
 
 *xboard-4.5.1 (01 Mar 2011)
 



1.1                  games-board/xboard/xboard-4.5.2a.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/xboard/xboard-4.5.2a.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/xboard/xboard-4.5.2a.ebuild?rev=1.1&content-type=text/plain

Index: xboard-4.5.2a.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/xboard/xboard-4.5.2a.ebuild,v 1.1 2011/05/22 21:35:02 mr_bones_ Exp $

EAPI=2
inherit autotools eutils games

DESCRIPTION="GUI for gnuchess and for internet chess servers"
HOMEPAGE="http://www.gnu.org/software/xboard/"
SRC_URI="mirror://gnu/xboard/${P}.tar.gz
	mirror://gentoo/${PN}.png"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="Xaw3d +default-font zippy"
RESTRICT="test" #124112

RDEPEND="Xaw3d? ( x11-libs/Xaw3d )
	x11-libs/libXpm
	x11-libs/libXaw
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXt
	x11-libs/libXmu
	x11-libs/libXext
	x11-libs/libICE
	default-font? ( media-fonts/font-adobe-100dpi )"
DEPEND="${RDEPEND}
	x11-proto/xproto"

src_unpack() {
	unpack ${P}.tar.gz
}

src_prepare() {
	epatch "${FILESDIR}"/${P}*
	eautoreconf
}

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		--datadir="${GAMES_DATADIR}"/${PN} \
		$(use_with Xaw3d) \
		$(use_enable zippy)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS COPYRIGHT ChangeLog NEWS README TODO ics-parsing.txt
	use zippy && dodoc zippy.README
	dohtml FAQ.html
	doicon "${DISTDIR}"/xboard.png
	make_desktop_entry ${PN} "Xboard (Chess)"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "No chess engines are emerged by default! If you want a chess engine"
	elog "to play with, you can emerge gnuchess or crafty."
	elog "Read xboard FAQ for information."
	if ! use default-font ; then
		ewarn "Read the xboard(6) man page for specifying the font for xboard to use."
	fi
}