[gentoo-commits] gentoo-x86 commit in www-plugins/lightspark: lightspark-0.4.7.1.ebuild ChangeLog lightspark-0.4.6.1.ebuild

[gentoo-commits] gentoo-x86 commit in www-plugins/lightspark: lightspark-0.4.7.1.ebuild ChangeLog lightspark-0.4.6.1.ebuild

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    11/05/16 15:28:21

  Modified:             ChangeLog
  Added:                lightspark-0.4.7.1.ebuild
  Removed:              lightspark-0.4.6.1.ebuild
  Log:
  Version bump, bug #367237
  
  (Portage version: 2.2.0_alpha33/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 www-plugins/lightspark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/lightspark/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	20 Apr 2011 20:50:51 -0000	1.28
+++ ChangeLog	16 May 2011 15:28:20 -0000	1.29
@@ -1,6 +1,14 @@
 # ChangeLog for www-plugins/lightspark
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/lightspark/ChangeLog,v 1.28 2011/04/20 20:50:51 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/lightspark/ChangeLog,v 1.29 2011/05/16 15:28:20 chithanh Exp $
+
+*lightspark-0.4.7.1 (16 May 2011)
+
+  16 May 2011; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  -files/lightspark-0.4.5-allow-disabling-pulseaudio.patch,
+  -lightspark-0.4.6.1.ebuild, +lightspark-0.4.7.1.ebuild,
+  +files/lightspark-0.4.7.1-allow-disabling-pulseaudio.patch:
+  Version bump, bug #367237
 
   20 Apr 2011; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
   -files/lightspark-0.4.5.1-cmakelists.patch, -lightspark-0.4.5.2.ebuild:



1.1                  www-plugins/lightspark/lightspark-0.4.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/lightspark-0.4.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/lightspark-0.4.7.1.ebuild?rev=1.1&content-type=text/plain

Index: lightspark-0.4.7.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/lightspark/lightspark-0.4.7.1.ebuild,v 1.1 2011/05/16 15:28:20 chithanh Exp $

EAPI=3
inherit cmake-utils nsplugins multilib versionator

DESCRIPTION="High performance flash player"
HOMEPAGE="http://lightspark.sourceforge.net/"
SRC_URI="http://launchpad.net/${PN}/trunk/${PN}-$(get_version_component_range 1-3)/+download/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nsplugin pulseaudio"

RDEPEND=">=dev-cpp/libxmlpp-2.33.1:2.6
	>=dev-libs/boost-1.42
	dev-libs/libpcre[cxx]
	media-fonts/liberation-fonts
	virtual/ffmpeg
	media-libs/fontconfig
	media-libs/ftgl
	>=media-libs/glew-1.5.3
	media-libs/libsdl
	pulseaudio? (
		media-sound/pulseaudio
	)
	net-misc/curl
	>=sys-devel/gcc-4.4
	>=sys-devel/llvm-2.8-r2
	virtual/opengl
	nsplugin? (
		dev-libs/nspr
		net-libs/xulrunner
		x11-libs/gtk+:2
		x11-libs/gtkglext
	)
	x11-libs/libX11"
DEPEND="${RDEPEND}
	dev-lang/nasm
	dev-util/pkgconfig"

S=${WORKDIR}/${P/_rc*/}

PATCHES=(
	"${FILESDIR}"/${PN}-0.4.6.1-cmakelists.patch
	"${FILESDIR}"/${PN}-0.4.5-allow-disabling-pulseaudio.patch
)

src_configure() {
	local audiobackends
	use pulseaudio && audiobackends=pulse

	local mycmakeargs=(
		$(cmake-utils_use nsplugin COMPILE_PLUGIN)
		-DAUDIO_BACKEND="${audiobackends}"
		-DPLUGIN_DIRECTORY=/usr/$(get_libdir)/${PN}/plugins
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	use nsplugin && inst_plugin /usr/$(get_libdir)/${PN}/plugins/liblightsparkplugin.so
}

pkg_postinst() {
	if use nsplugin && ! has_version www-plugins/gnash; then
		elog "Lightspark now supports gnash fallback for its browser plugin."
		elog "Install www-plugins/gnash to take advantage of it."
	fi
	if use nsplugin && has_version www-plugins/gnash[nsplugin]; then
		elog "Having two plugins installed for the same MIME type may confuse"
		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
		elog "USE flag for either gnash or lightspark. For details, see"
		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
	fi
}