[gentoo-commits] gentoo-x86 commit in net-libs/telepathy-glib: ChangeLog telepathy-glib-0.14.5.ebuild telepathy-glib-0.14.3.ebuild

[gentoo-commits] gentoo-x86 commit in net-libs/telepathy-glib: ChangeLog telepathy-glib-0.14.5.ebuild telepathy-glib-0.14.3.ebuild

[Pacho Ramos (pacho)]

pacho       11/05/04 16:18:19

  Modified:             ChangeLog
  Added:                telepathy-glib-0.14.5.ebuild
  Removed:              telepathy-glib-0.14.3.ebuild
  Log:
  Version bump, remove old.
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.76                 net-libs/telepathy-glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	15 Apr 2011 16:49:16 -0000	1.75
+++ ChangeLog	4 May 2011 16:18:19 -0000	1.76
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/telepathy-glib
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v 1.75 2011/04/15 16:49:16 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v 1.76 2011/05/04 16:18:19 pacho Exp $
+
+*telepathy-glib-0.14.5 (04 May 2011)
+
+  04 May 2011; Pacho Ramos <pacho@gentoo.org> -telepathy-glib-0.14.3.ebuild,
+  +telepathy-glib-0.14.5.ebuild:
+  Version bump, remove old.
 
 *telepathy-glib-0.14.4 (15 Apr 2011)
 



1.1                  net-libs/telepathy-glib/telepathy-glib-0.14.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.14.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.14.5.ebuild?rev=1.1&content-type=text/plain

Index: telepathy-glib-0.14.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.14.5.ebuild,v 1.1 2011/05/04 16:18:19 pacho Exp $

EAPI="3"
PYTHON_DEPEND="2:2.5"

inherit python virtualx

DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol."
HOMEPAGE="http://telepathy.freedesktop.org"
SRC_URI="http://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug +introspection +vala"

# Tests fail in /stream-tube/creation
RESTRICT="test"
RDEPEND=">=dev-libs/glib-2.25.16:2
	>=dev-libs/dbus-glib-0.82
	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
	vala? (
		dev-lang/vala:0.12[vapigen]
		>=dev-libs/gobject-introspection-0.9.6 )"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	>=dev-util/pkgconfig-0.21"

src_prepare() {
	python_convert_shebangs -r 2 examples tests tools
	default_src_prepare
}

src_configure() {
	local myconf

	if use vala; then
		myconf="--enable-introspection
			VALAC=$(type -p valac-0.12)
			VAPIGEN=$(type -p vapigen-0.12)"
	fi

	econf --disable-static \
		PYTHON=$(PYTHON -2 -a) \
		$(use_enable debug backtrace) \
		$(use_enable debug handle-leak-debug) \
		$(use_enable debug debug-cache) \
		$(use_enable introspection) \
		$(use_enable vala vala-bindings) \
		${myconf}
}

src_test() {
	# Needs dbus for tests (auto-launched)
	Xemake -j1 check || die
}

src_install() {
	emake install DESTDIR="${D}" || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"

	find "${ED}" -name '*.la' -exec rm -f '{}' + || die
}