* [gentoo-commits] gentoo-x86 commit in www-apache/mod_security: ChangeLog mod_security-2.6.0_rc2.ebuild
@ 2011-05-02 17:12 Diego Petteno (flameeyes)
0 siblings, 0 replies; only message in thread
From: Diego Petteno (flameeyes) @ 2011-05-02 17:12 UTC (permalink / raw
To: gentoo-commits
flameeyes 11/05/02 17:12:21
Modified: ChangeLog
Added: mod_security-2.6.0_rc2.ebuild
Log:
Bump to newer release candidate.
(Portage version: 2.2.0_alpha30/cvs/Linux x86_64)
Revision Changes Path
1.54 www-apache/mod_security/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/ChangeLog?r1=1.53&r2=1.54
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apache/mod_security/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog 19 Apr 2011 08:10:34 -0000 1.53
+++ ChangeLog 2 May 2011 17:12:21 -0000 1.54
@@ -1,6 +1,12 @@
# ChangeLog for www-apache/mod_security
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_security/ChangeLog,v 1.53 2011/04/19 08:10:34 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_security/ChangeLog,v 1.54 2011/05/02 17:12:21 flameeyes Exp $
+
+*mod_security-2.6.0_rc2 (02 May 2011)
+
+ 02 May 2011; Diego E. Pettenò <flameeyes@gentoo.org>
+ +mod_security-2.6.0_rc2.ebuild:
+ Bump to newer release candidate.
19 Apr 2011; Diego E. Pettenò <flameeyes@gentoo.org>
mod_security-2.6.0_rc1.ebuild:
1.1 www-apache/mod_security/mod_security-2.6.0_rc2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/mod_security-2.6.0_rc2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/mod_security-2.6.0_rc2.ebuild?rev=1.1&content-type=text/plain
Index: mod_security-2.6.0_rc2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_security/mod_security-2.6.0_rc2.ebuild,v 1.1 2011/05/02 17:12:21 flameeyes Exp $
EAPI=4
inherit apache-module autotools
MY_P=modsecurity-apache_${PV/_rc/-rc}
DESCRIPTION="Web application firewall and Intrusion Detection System for Apache."
HOMEPAGE="http://www.modsecurity.org/"
SRC_URI="http://www.modsecurity.org/download/${MY_P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="geoip curl"
DEPEND=">=dev-libs/libxml2-2.7.8
dev-libs/libpcre
>=dev-lang/lua-5.1
curl? ( >=net-misc/curl-7.15.1 )
www-servers/apache[apache2_modules_unique_id]"
RDEPEND="${DEPEND}
geoip? ( dev-libs/geoip )"
PDEPEND="www-apache/modsecurity-crs"
S="${WORKDIR}/${MY_P}"
APACHE2_MOD_FILE="apache2/.libs/${PN}2.so"
APACHE2_MOD_DEFINE="SECURITY"
# Tests require symbols only defined within the Apache binary.
RESTRICT=test
need_apache2
src_prepare() {
cp "${FILESDIR}"/modsecurity.conf "${T}"/79_modsecurity.conf || die
eautoreconf
}
src_configure() {
econf \
--enable-shared --disable-static \
--with-apxs="${APXS}" \
$(use_enable curl mlogc) \
|| die "econf failed"
}
src_compile() {
if ! use geoip; then
sed -i -e '/SecGeoLookupDb/s:^:#:' \
"${T}"/79_modsecurity.conf || die
fi
emake || die
}
src_test() {
emake check || die
}
src_install() {
apache-module_src_install
# install manually rather than by using the APACHE2_MOD_CONF
# variable since we have to edit it to set things up properly.
insinto "${APACHE_MODULES_CONFDIR}"
doins "${T}"/79_modsecurity.conf
dodoc CHANGES
keepdir /var/cache/modsecurity
fowners apache:apache /var/cache/modsecurity
fperms 0770 /var/cache/modsecurity
}
pkg_postinst() {
if [[ -f "${ROOT}"/etc/apache/modules.d/99_mod_security.conf ]]; then
ewarn "You still have the configuration file 99_mod_security.conf."
ewarn "Please make sure to remove that and keep only 79_modsecurity.conf."
ewarn ""
fi
elog "The base configuration file has been renamed 79_modsecurity.conf"
elog "so that you can put your own configuration as 90_modsecurity_local.conf or"
elog "equivalent."
elog ""
elog "That would be the correct place for site-global security rules."
elog "Note: 80_modsecurity_crs.conf is used by www-apache/modsecurity-crs"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-05-02 17:12 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-05-02 17:12 [gentoo-commits] gentoo-x86 commit in www-apache/mod_security: ChangeLog mod_security-2.6.0_rc2.ebuild Diego Petteno (flameeyes)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox