[gentoo-commits] gentoo-x86 commit in media-video/gnome-mplayer: ChangeLog gnome-mplayer-1.0.3-r2.ebuild gnome-mplayer-1.0.3-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/gnome-mplayer: ChangeLog gnome-mplayer-1.0.3-r2.ebuild gnome-mplayer-1.0.3-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/04/23 14:07:34

  Modified:             ChangeLog
  Added:                gnome-mplayer-1.0.3-r2.ebuild
  Removed:              gnome-mplayer-1.0.3-r1.ebuild
  Log:
  Revision bump for last change.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.57                 media-video/gnome-mplayer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	23 Apr 2011 14:05:09 -0000	1.56
+++ ChangeLog	23 Apr 2011 14:07:34 -0000	1.57
@@ -1,16 +1,18 @@
 # ChangeLog for media-video/gnome-mplayer
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.56 2011/04/23 14:05:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.57 2011/04/23 14:07:34 ssuominen Exp $
+
+*gnome-mplayer-1.0.3-r2 (23 Apr 2011)
 
   23 Apr 2011; Samuli Suominen <ssuominen@gentoo.org>
-  gnome-mplayer-1.0.3-r1.ebuild:
-  Inherit fdo-mime and gnome2-utils to run some cache updating.
+  +gnome-mplayer-1.0.3-r2.ebuild:
+  Inherit fdo-mime and gnome2-utils to run some cache updating wrt #364513.
 
 *gnome-mplayer-1.0.3-r1 (23 Apr 2011)
 
   23 Apr 2011; Samuli Suominen <ssuominen@gentoo.org>
   +gnome-mplayer-1.0.3-r1.ebuild:
-  Stop using gnome2.eclass and remove support for gnome-base/gconf wrt #364513.
+  Stop inheriting gnome2 and remove support for gnome-base/gconf wrt #364513.
 
 *gnome-mplayer-1.0.3 (22 Apr 2011)
 



1.1                  media-video/gnome-mplayer/gnome-mplayer-1.0.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-mplayer-1.0.3-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.3-r2.ebuild,v 1.1 2011/04/23 14:07:34 ssuominen Exp $

EAPI=4
inherit eutils fdo-mime gnome2-utils

DESCRIPTION="A GTK+ interface to MPlayer"
HOMEPAGE="http://code.google.com/p/gnome-mplayer/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="alsa dbus gnome ipod libnotify musicbrainz pulseaudio"

RDEPEND=">=dev-libs/glib-2.26:2
	>=media-video/mplayer-1.0_rc4_p20091026-r1[ass]
	>=x11-libs/gtk+-2.22:2
	x11-libs/libX11
	x11-libs/libXScrnSaver
	alsa? ( media-libs/alsa-lib )
	dbus? ( >=dev-libs/dbus-glib-0.92 )
	gnome? ( gnome-base/gvfs
		gnome-base/nautilus )
	ipod? ( >=media-libs/libgpod-0.7 )
	libnotify? ( x11-libs/libnotify )
	musicbrainz? ( net-misc/curl
		>=media-libs/musicbrainz-3 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

DOCS="ChangeLog README DOCS/keyboard_shortcuts.txt DOCS/tech/dbus.txt DOCS/tech/plugin-interaction.txt"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.0.2-implicit_declaration.patch
}

src_configure() {
	# FIXME: The only reason why --without-gpm-new-method is passed is lack of testing.
	econf \
		$(use_enable gnome nautilus) \
		--enable-panscan \
		--disable-gseal \
		--without-gconf \
		--with-gio \
		$(use_with dbus) \
		$(use_with alsa) \
		$(use_with pulseaudio) \
		$(use_with libnotify) \
		$(use_with ipod libgpod) \
		$(use_with musicbrainz libmusicbrainz3) \
		--without-gpm-new-method \
		--without-gpm-old-method
}

src_install() {
	default
	rm -rf "${ED}"/usr/share/doc/${PN}
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update --uninstall
}