* [gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: plasma-workspace-4.6.2-r1.ebuild ChangeLog plasma-workspace-4.6.2.ebuild
@ 2011-04-18 19:29 Andreas HAttel (dilfridge)
0 siblings, 0 replies; only message in thread
From: Andreas HAttel (dilfridge) @ 2011-04-18 19:29 UTC (permalink / raw
To: gentoo-commits
dilfridge 11/04/18 19:29:32
Modified: ChangeLog
Added: plasma-workspace-4.6.2-r1.ebuild
Removed: plasma-workspace-4.6.2.ebuild
Log:
Add workaround patch for plasma crash with kdepim-4.4, bug 364015
(Portage version: 2.1.9.46/cvs/Linux x86_64)
Revision Changes Path
1.98 kde-base/plasma-workspace/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/ChangeLog?r1=1.97&r2=1.98
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog 12 Apr 2011 00:40:36 -0000 1.97
+++ ChangeLog 18 Apr 2011 19:29:32 -0000 1.98
@@ -1,6 +1,13 @@
# ChangeLog for kde-base/plasma-workspace
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.97 2011/04/12 00:40:36 tampakrap Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/ChangeLog,v 1.98 2011/04/18 19:29:32 dilfridge Exp $
+
+*plasma-workspace-4.6.2-r1 (18 Apr 2011)
+
+ 18 Apr 2011; Andreas K. Huettel <dilfridge@gentoo.org>
+ -plasma-workspace-4.6.2.ebuild, +plasma-workspace-4.6.2-r1.ebuild,
+ +files/plasma-workspace-4.6.2-oldpimcrash.patch:
+ Add workaround patch for plasma crash with kdepim-4.4, bug 364015
12 Apr 2011; Theo Chatzimichos <tampakrap@gentoo.org>
plasma-workspace-4.6.2.ebuild:
1.1 kde-base/plasma-workspace/plasma-workspace-4.6.2-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.6.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.6.2-r1.ebuild?rev=1.1&content-type=text/plain
Index: plasma-workspace-4.6.2-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/plasma-workspace/plasma-workspace-4.6.2-r1.ebuild,v 1.1 2011/04/18 19:29:32 dilfridge Exp $
EAPI=3
KDE_HANDBOOK="optional"
KMNAME="kdebase-workspace"
KMMODULE="plasma"
PYTHON_DEPEND="python? 2"
inherit python kde4-meta
DESCRIPTION="Plasma: KDE desktop framework"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug google-gadgets gps python qalculate +rss semantic-desktop xinerama"
COMMONDEPEND="
$(add_kdebase_dep kdelibs 'semantic-desktop?')
$(add_kdebase_dep kephal)
$(add_kdebase_dep ksysguard)
$(add_kdebase_dep libkworkspace)
$(add_kdebase_dep libplasmagenericshell)
$(add_kdebase_dep libtaskmanager)
$(add_kdebase_dep solid)
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXfixes
x11-libs/libXrender
google-gadgets? ( >=x11-misc/google-gadgets-0.11.0[qt4] )
gps? ( >=sci-geosciences/gpsd-2.37 )
python? (
>=dev-python/PyQt4-4.4.0[X]
>=dev-python/sip-4.7.1
$(add_kdebase_dep pykde4)
)
qalculate? ( sci-libs/libqalculate )
rss? (
$(add_kdebase_dep kdepimlibs 'semantic-desktop?')
$(add_kdebase_dep libplasmaclock 'holidays')
)
!rss? ( $(add_kdebase_dep libplasmaclock '-holidays') )
xinerama? ( x11-libs/libXinerama )
"
DEPEND="${COMMONDEPEND}
x11-proto/compositeproto
x11-proto/damageproto
x11-proto/fixesproto
x11-proto/renderproto
xinerama? ( x11-proto/xineramaproto )
"
RDEPEND="${COMMONDEPEND}
$(add_kdebase_dep activitymanager)
$(add_kdebase_dep plasma-runtime)
"
KMEXTRA="
statusnotifierwatcher/
"
KMEXTRACTONLY="
krunner/dbus/org.freedesktop.ScreenSaver.xml
krunner/dbus/org.kde.krunner.App.xml
ksmserver/org.kde.KSMServerInterface.xml
libs/kephal/
libs/kworkspace/
libs/taskmanager/
libs/plasmagenericshell/
libs/ksysguard/
ksysguard/
"
KMLOADLIBS="libkworkspace libplasmaclock libplasmagenericshell libtaskmanager"
PATCHES=(
"${FILESDIR}/${PN}-4.4.2-xinerama_cmake_automagic.patch"
"${FILESDIR}/${PN}-4.6.2-optional_akonadi-server.patch"
"${FILESDIR}/${PN}-4.6.2-oldpimcrash.patch"
)
pkg_setup() {
python_set_active_version 2
kde4-meta_pkg_setup
}
src_unpack() {
if use handbook; then
KMEXTRA+=" doc/plasma-desktop"
fi
kde4-meta_src_unpack
}
src_prepare() {
sed -i -e '1ifind_package(KdepimLibs)' plasma/CMakeLists.txt || die
kde4-meta_src_prepare
}
src_configure() {
mycmakeargs=(
$(cmake-utils_use_with google-gadgets Googlegadgets)
$(cmake-utils_use_with gps libgps)
$(cmake-utils_use_with python SIP)
$(cmake-utils_use_with python PyQt4)
$(cmake-utils_use_with python PyKDE4)
$(cmake-utils_use_with qalculate)
$(cmake-utils_use_with rss KdepimLibs)
$(cmake-utils_use_with semantic-desktop Akonadi)
$(cmake-utils_use_with semantic-desktop Nepomuk)
$(cmake-utils_use_with semantic-desktop Soprano)
$(cmake-utils_use_with xinerama X11_Xinerama)
-DWITH_Xmms=OFF
)
kde4-meta_src_configure
}
src_install() {
kde4-meta_src_install
rm -f \
"${ED}$(python_get_sitedir)"/PyKDE4/*.py[co] \
"${ED}${KDEDIR}"/share/apps/plasma_scriptengine_python/*.py[co]
}
pkg_postinst() {
kde4-meta_pkg_postinst
if use python; then
python_mod_optimize \
PyKDE4 \
"${KDEDIR}"/share/apps/plasma_scriptengine_python
fi
}
pkg_postrm() {
kde4-meta_pkg_postrm
if [[ -d ${EKDEDIR}/share/apps/plasma_scriptengine_python ]]; then
python_mod_cleanup \
PyKDE4 \
"${KDEDIR}"/share/apps/plasma_scriptengine_python
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-04-18 19:30 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-04-18 19:29 [gentoo-commits] gentoo-x86 commit in kde-base/plasma-workspace: plasma-workspace-4.6.2-r1.ebuild ChangeLog plasma-workspace-4.6.2.ebuild Andreas HAttel (dilfridge)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox