[gentoo-commits] gentoo-x86 commit in net-im/gajim: ChangeLog gajim-0.14.1-r3.ebuild gajim-0.14.1-r2.ebuild

[gentoo-commits] gentoo-x86 commit in net-im/gajim: ChangeLog gajim-0.14.1-r3.ebuild gajim-0.14.1-r2.ebuild

[Justin Lecher (jlec)]

jlec        11/04/13 14:05:42

  Modified:             ChangeLog gajim-0.14.1-r2.ebuild
  Added:                gajim-0.14.1-r3.ebuild
  Log:
  Removed uneeded dep on sexy-python, backport clickable link in status message patch, #363289
  
  (Portage version: 2.2.0_alpha29/cvs/Linux x86_64)

Revision  Changes    Path
1.116                net-im/gajim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?rev=1.116&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?rev=1.116&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?r1=1.115&r2=1.116

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v
retrieving revision 1.115
retrieving revision 1.116
diff -u -r1.115 -r1.116
--- ChangeLog	29 Mar 2011 12:43:44 -0000	1.115
+++ ChangeLog	13 Apr 2011 14:05:41 -0000	1.116
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/gajim
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.115 2011/03/29 12:43:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.116 2011/04/13 14:05:41 jlec Exp $
+
+*gajim-0.14.1-r3 (13 Apr 2011)
+
+  13 Apr 2011; Justin Lecher <jlec@gentoo.org> +files/0.14.1-link.patch,
+  gajim-0.14.1-r2.ebuild, +gajim-0.14.1-r3.ebuild:
+  Removed uneeded dep on sexy-python, backport clickable link in status message
+  patch, #363289
 
   29 Mar 2011; Jeroen Roovers <jer@gentoo.org> gajim-0.14.1-r2.ebuild:
   Stable for HPPA (bug #357765).



1.9                  net-im/gajim/gajim-0.14.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.14.1-r2.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.14.1-r2.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.14.1-r2.ebuild?r1=1.8&r2=1.9

Index: gajim-0.14.1-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.14.1-r2.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- gajim-0.14.1-r2.ebuild	29 Mar 2011 12:43:44 -0000	1.8
+++ gajim-0.14.1-r2.ebuild	13 Apr 2011 14:05:41 -0000	1.9
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.14.1-r2.ebuild,v 1.8 2011/03/29 12:43:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.14.1-r2.ebuild,v 1.9 2011/04/13 14:05:41 jlec Exp $
 
 EAPI="2"
 
@@ -27,7 +27,6 @@
 	dev-util/pkgconfig"
 RDEPEND="${COMMON_DEPEND}
 	dev-python/pyopenssl
-	dev-python/sexy-python
 	crypt? (
 		app-crypt/gnupg
 		dev-python/pycrypto



1.1                  net-im/gajim/gajim-0.14.1-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.14.1-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.14.1-r3.ebuild?rev=1.1&content-type=text/plain

Index: gajim-0.14.1-r3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.14.1-r3.ebuild,v 1.1 2011/04/13 14:05:41 jlec Exp $

EAPI="2"

PYTHON_DEPEND="2"
PYTHON_USE_WITH="sqlite xml"

inherit eutils python versionator

DESCRIPTION="Jabber client written in PyGTK"
HOMEPAGE="http://www.gajim.org/"
SRC_URI="http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="avahi crypt dbus gmail gnome idle jingle libnotify networkmanager nls spell srv X xhtml"

COMMON_DEPEND="
	x11-libs/gtk+:2
	dev-python/pygtk:2"
DEPEND="${COMMON_DEPEND}
	>=sys-devel/gettext-0.17-r1
	>=dev-util/intltool-0.40.1
	dev-util/pkgconfig"
RDEPEND="${COMMON_DEPEND}
	dev-python/pyopenssl
	crypt? (
		app-crypt/gnupg
		dev-python/pycrypto
		)
	dbus? (
		dev-python/dbus-python
		dev-libs/dbus-glib
		libnotify? ( dev-python/notify-python )
		avahi? ( net-dns/avahi[dbus,gtk,python] )
		)
	gmail? ( net-dns/bind-tools )
	gnome? (
		dev-python/libgnome-python
		dev-python/gnome-keyring-python
		dev-python/egg-python
		)
	idle? ( x11-libs/libXScrnSaver )
	jingle? ( net-libs/farsight2[python] )
	networkmanager? (
			dev-python/dbus-python
			|| ( >=net-misc/networkmanager-0.7.1 net-misc/networkmanager[gnome] )
		)
	srv? (
		|| (
			dev-python/libasyncns-python
			net-dns/bind-tools )
		)
	spell? ( app-text/gtkspell )
	xhtml? ( dev-python/docutils )"

pkg_setup() {
	if ! use dbus; then
		if use libnotify; then
			eerror "The dbus USE flag is required for libnotify support"
			die "USE=\"dbus\" needed for libnotify support"
		fi
		if use avahi; then
			eerror "The dbus USE flag is required for avahi support"
			die "USE=\"dbus\" needed for avahi support"
		fi
	fi
	python_pkg_setup
	python_set_active_version 2
}

src_prepare() {
	epatch \
		"${FILESDIR}"/0.14-python-version.patch \
		"${FILESDIR}"/0.14.1-testing.patch \
		"${FILESDIR}"/0.14.1-link.patch
	echo '#!/bin/sh' > config/py-compile
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_with X x) \
		--docdir="/usr/share/doc/${PF}" \
		--libdir="$(python_get_sitedir)" \
		--enable-site-packages
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	rm "${D}/usr/share/doc/${PF}/"{README.html,COPYING} || die
	dohtml README.html || die
}

pkg_postinst() {
	python_mod_optimize $(python_get_sitedir)/${PN}
}

pkg_postrm() {
	python_mod_cleanup $(python_get_sitedir)/${PN}
}